Merge remote-tracking branch 'qatar/master'
[ffmpeg.git] / libavutil / x86 / float_dsp.asm
1 ;*****************************************************************************
2 ;* x86-optimized Float DSP functions
3 ;*
4 ;* Copyright 2006 Loren Merritt
5 ;*
6 ;* This file is part of FFmpeg.
7 ;*
8 ;* FFmpeg is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* FFmpeg is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with FFmpeg; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23 %include "x86inc.asm"
24 %include "x86util.asm"
25
26 SECTION .text
27
28 ;-----------------------------------------------------------------------------
29 ; void vector_fmul(float *dst, const float *src0, const float *src1, int len)
30 ;-----------------------------------------------------------------------------
31 %macro VECTOR_FMUL 0
32 cglobal vector_fmul, 4,4,2, dst, src0, src1, len
33     lea       lenq, [lend*4 - 2*mmsize]
34 ALIGN 16
35 .loop:
36     mova      m0,   [src0q + lenq]
37     mova      m1,   [src0q + lenq + mmsize]
38     mulps     m0, m0, [src1q + lenq]
39     mulps     m1, m1, [src1q + lenq + mmsize]
40     mova      [dstq + lenq], m0
41     mova      [dstq + lenq + mmsize], m1
42
43     sub       lenq, 2*mmsize
44     jge       .loop
45     REP_RET
46 %endmacro
47
48 INIT_XMM sse
49 VECTOR_FMUL
50 %if HAVE_AVX
51 INIT_YMM avx
52 VECTOR_FMUL
53 %endif
54
55 ;------------------------------------------------------------------------------
56 ; void ff_vector_fmac_scalar(float *dst, const float *src, float mul, int len)
57 ;------------------------------------------------------------------------------
58
59 %macro VECTOR_FMAC_SCALAR 0
60 %if UNIX64
61 cglobal vector_fmac_scalar, 3,3,3, dst, src, len
62 %else
63 cglobal vector_fmac_scalar, 4,4,3, dst, src, mul, len
64 %endif
65 %if WIN64
66     SWAP 0, 2
67 %endif
68 %if ARCH_X86_32
69     VBROADCASTSS m0, mulm
70 %else
71     shufps     xmm0, xmm0, 0
72 %if cpuflag(avx)
73     vinsertf128  m0, m0, xmm0, 1
74 %endif
75 %endif
76     lea    lenq, [lend*4-2*mmsize]
77 .loop:
78     mulps    m1, m0, [srcq+lenq       ]
79     mulps    m2, m0, [srcq+lenq+mmsize]
80     addps    m1, m1, [dstq+lenq       ]
81     addps    m2, m2, [dstq+lenq+mmsize]
82     mova  [dstq+lenq       ], m1
83     mova  [dstq+lenq+mmsize], m2
84     sub    lenq, 2*mmsize
85     jge .loop
86     REP_RET
87 %endmacro
88
89 INIT_XMM sse
90 VECTOR_FMAC_SCALAR
91 %if HAVE_AVX
92 INIT_YMM avx
93 VECTOR_FMAC_SCALAR
94 %endif