56a6c242d8f83962cfabe432bfc8262c8cb29f4f
[ffmpeg.git] / libavfilter / x86 / vf_threshold.asm
1 ;*****************************************************************************
2 ;* x86-optimized functions for threshold filter
3 ;*
4 ;* Copyright (C) 2017 Paul B Mahol
5 ;*
6 ;* This file is part of FFmpeg.
7 ;*
8 ;* FFmpeg is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* FFmpeg is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with FFmpeg; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;*****************************************************************************
22
23 %include "libavutil/x86/x86util.asm"
24
25 SECTION_RODATA
26
27 pb_128: times 16 db 128
28
29 SECTION .text
30
31 %macro THRESHOLD_8 0
32 %if ARCH_X86_64
33 cglobal threshold8, 10, 13, 5, in, threshold, min, max, out, ilinesize, tlinesize, flinesize, slinesize, olinesize, w, h, x
34     mov             wd, dword wm
35     mov             hd, dword hm
36 %else
37 cglobal threshold8, 5, 7, 5, in, threshold, min, max, out, w, x
38     mov             wd, r10m
39 %define     ilinesizeq  r5mp
40 %define     tlinesizeq  r6mp
41 %define     flinesizeq  r7mp
42 %define     slinesizeq  r8mp
43 %define     olinesizeq  r9mp
44 %define             hd  r11mp
45 %endif
46     VBROADCASTI128  m4, [pb_128]
47     add            inq, wq
48     add     thresholdq, wq
49     add           minq, wq
50     add           maxq, wq
51     add           outq, wq
52     neg             wq
53 .nextrow:
54     mov         xq, wq
55
56     .loop:
57         movu            m1, [inq + xq]
58         movu            m0, [thresholdq + xq]
59         movu            m2, [minq + xq]
60         movu            m3, [maxq + xq]
61         pxor            m0, m4
62         pxor            m1, m4
63         pcmpgtb         m0, m1
64         PBLENDVB        m3, m2, m0
65         movu   [outq + xq], m3
66         add             xq, mmsize
67     jl .loop
68
69     add          inq, ilinesizeq
70     add   thresholdq, tlinesizeq
71     add         minq, flinesizeq
72     add         maxq, slinesizeq
73     add         outq, olinesizeq
74     sub         hd, 1
75     jg .nextrow
76 RET
77 %endmacro
78
79 INIT_XMM sse4
80 THRESHOLD_8
81
82 %if HAVE_AVX2_EXTERNAL
83 INIT_YMM avx2
84 THRESHOLD_8
85 %endif