arm: Check for support for the .fpu directive
[ffmpeg.git] / libavutil / arm / asm.S
1 /*
2  * Copyright (c) 2008 Mans Rullgard <mans@mansr.com>
3  *
4  * This file is part of Libav.
5  *
6  * Libav is free software; you can redistribute it and/or
7  * modify it under the terms of the GNU Lesser General Public
8  * License as published by the Free Software Foundation; either
9  * version 2.1 of the License, or (at your option) any later version.
10  *
11  * Libav is distributed in the hope that it will be useful,
12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14  * Lesser General Public License for more details.
15  *
16  * You should have received a copy of the GNU Lesser General Public
17  * License along with Libav; if not, write to the Free Software
18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
19  */
20
21 #include "config.h"
22
23 #ifdef __ELF__
24 #   define ELF
25 #else
26 #   define ELF @
27 #endif
28
29 #if CONFIG_THUMB
30 #   define A @
31 #   define T
32 #else
33 #   define A
34 #   define T @
35 #endif
36
37 #if HAVE_AS_FUNC
38 #   define FUNC
39 #else
40 #   define FUNC @
41 #endif
42
43 #if HAVE_AS_FPU_DIRECTIVE
44 #   define FPU
45 #else
46 #   define FPU @
47 #endif
48
49 #if   HAVE_NEON
50         .arch           armv7-a
51 #elif HAVE_ARMV6T2
52         .arch           armv6t2
53 #elif HAVE_ARMV6
54         .arch           armv6
55 #elif HAVE_ARMV5TE
56         .arch           armv5te
57 #endif
58 #if   HAVE_AS_OBJECT_ARCH
59 ELF     .object_arch    armv4
60 #endif
61
62 #if   HAVE_NEON
63 FPU     .fpu            neon
64 ELF     .eabi_attribute 10, 0           @ suppress Tag_FP_arch
65 ELF     .eabi_attribute 12, 0           @ suppress Tag_Advanced_SIMD_arch
66 #elif HAVE_VFP
67 FPU     .fpu            vfp
68 ELF     .eabi_attribute 10, 0           @ suppress Tag_FP_arch
69 #endif
70
71         .syntax unified
72 T       .thumb
73 ELF     .eabi_attribute 25, 1           @ Tag_ABI_align_preserved
74 ELF     .section .note.GNU-stack,"",%progbits @ Mark stack as non-executable
75
76 .macro  function name, export=0, align=2
77         .set            .Lpic_idx, 0
78         .set            .Lpic_gp, 0
79     .macro endfunc
80       .if .Lpic_idx
81         .align          2
82         .altmacro
83         put_pic         %(.Lpic_idx - 1)
84         .noaltmacro
85       .endif
86 ELF     .size   \name, . - \name
87 FUNC    .endfunc
88         .purgem endfunc
89     .endm
90         .text
91         .align          \align
92     .if \export
93         .global EXTERN_ASM\name
94 ELF     .type   EXTERN_ASM\name, %function
95 FUNC    .func   EXTERN_ASM\name
96 EXTERN_ASM\name:
97     .else
98 ELF     .type   \name, %function
99 FUNC    .func   \name
100 \name:
101     .endif
102 .endm
103
104 .macro  const   name, align=2, relocate=0
105     .macro endconst
106 ELF     .size   \name, . - \name
107         .purgem endconst
108     .endm
109 .if HAVE_SECTION_DATA_REL_RO && \relocate
110         .section        .data.rel.ro
111 .else
112         .section        .rodata
113 .endif
114         .align          \align
115 \name:
116 .endm
117
118 #if !HAVE_ARMV6T2_EXTERNAL
119 .macro  movw    rd, val
120         mov     \rd, \val &  255
121         orr     \rd, \val & ~255
122 .endm
123 #endif
124
125 .macro  mov32   rd, val
126 #if HAVE_ARMV6T2_EXTERNAL
127         movw            \rd, #(\val) & 0xffff
128     .if (\val) >> 16
129         movt            \rd, #(\val) >> 16
130     .endif
131 #else
132         ldr             \rd, =\val
133 #endif
134 .endm
135
136 .macro  put_pic         num
137         put_pic_\num
138 .endm
139
140 .macro  do_def_pic      num, val, label
141     .macro put_pic_\num
142       .if \num
143         .altmacro
144         put_pic         %(\num - 1)
145         .noaltmacro
146       .endif
147 \label: .word           \val
148         .purgem         put_pic_\num
149     .endm
150 .endm
151
152 .macro  def_pic         val, label
153         .altmacro
154         do_def_pic      %.Lpic_idx, \val, \label
155         .noaltmacro
156         .set            .Lpic_idx, .Lpic_idx + 1
157 .endm
158
159 .macro  ldpic           rd,  val, indir=0
160         ldr             \rd, .Lpicoff\@
161 .Lpic\@:
162     .if \indir
163 A       ldr             \rd, [pc, \rd]
164 T       add             \rd, pc
165 T       ldr             \rd, [\rd]
166     .else
167         add             \rd, pc
168     .endif
169         def_pic         \val - (.Lpic\@ + (8 >> CONFIG_THUMB)), .Lpicoff\@
170 .endm
171
172 .macro  movrel rd, val
173 #if CONFIG_PIC
174         ldpic           \rd, \val
175 #elif HAVE_ARMV6T2_EXTERNAL && !defined(__APPLE__)
176         movw            \rd, #:lower16:\val
177         movt            \rd, #:upper16:\val
178 #else
179         ldr             \rd, =\val
180 #endif
181 .endm
182
183 .macro  movrelx         rd,  val, gp
184 #if CONFIG_PIC && defined(__ELF__)
185     .ifnb \gp
186       .if .Lpic_gp
187         .unreq          gp
188       .endif
189         gp      .req    \gp
190         ldpic           gp,  _GLOBAL_OFFSET_TABLE_
191     .elseif !.Lpic_gp
192         gp      .req    r12
193         ldpic           gp,  _GLOBAL_OFFSET_TABLE_
194     .endif
195         .set            .Lpic_gp, 1
196         ldr             \rd, .Lpicoff\@
197         ldr             \rd, [gp, \rd]
198         def_pic         \val(GOT), .Lpicoff\@
199 #elif CONFIG_PIC && defined(__APPLE__)
200         ldpic           \rd, .Lpic\@, indir=1
201         .non_lazy_symbol_pointer
202 .Lpic\@:
203         .indirect_symbol \val
204         .word           0
205         .text
206 #else
207         movrel          \rd, \val
208 #endif
209 .endm
210
211 .macro  add_sh          rd,  rn,  rm,  sh:vararg
212 A       add             \rd, \rn, \rm, \sh
213 T       mov             \rm, \rm, \sh
214 T       add             \rd, \rn, \rm
215 .endm
216
217 .macro  ldr_pre         rt,  rn,  rm:vararg
218 A       ldr             \rt, [\rn, \rm]!
219 T       add             \rn, \rn, \rm
220 T       ldr             \rt, [\rn]
221 .endm
222
223 .macro  ldr_dpre        rt,  rn,  rm:vararg
224 A       ldr             \rt, [\rn, -\rm]!
225 T       sub             \rn, \rn, \rm
226 T       ldr             \rt, [\rn]
227 .endm
228
229 .macro  ldr_nreg        rt,  rn,  rm:vararg
230 A       ldr             \rt, [\rn, -\rm]
231 T       sub             \rt, \rn, \rm
232 T       ldr             \rt, [\rt]
233 .endm
234
235 .macro  ldr_post        rt,  rn,  rm:vararg
236 A       ldr             \rt, [\rn], \rm
237 T       ldr             \rt, [\rn]
238 T       add             \rn, \rn, \rm
239 .endm
240
241 .macro  ldrc_pre        cc,  rt,  rn,  rm:vararg
242 A       ldr\cc          \rt, [\rn, \rm]!
243 T       itt             \cc
244 T       add\cc          \rn, \rn, \rm
245 T       ldr\cc          \rt, [\rn]
246 .endm
247
248 .macro  ldrd_reg        rt,  rt2, rn,  rm
249 A       ldrd            \rt, \rt2, [\rn, \rm]
250 T       add             \rt, \rn, \rm
251 T       ldrd            \rt, \rt2, [\rt]
252 .endm
253
254 .macro  ldrd_post       rt,  rt2, rn,  rm
255 A       ldrd            \rt, \rt2, [\rn], \rm
256 T       ldrd            \rt, \rt2, [\rn]
257 T       add             \rn, \rn, \rm
258 .endm
259
260 .macro  ldrh_pre        rt,  rn,  rm
261 A       ldrh            \rt, [\rn, \rm]!
262 T       add             \rn, \rn, \rm
263 T       ldrh            \rt, [\rn]
264 .endm
265
266 .macro  ldrh_dpre       rt,  rn,  rm
267 A       ldrh            \rt, [\rn, -\rm]!
268 T       sub             \rn, \rn, \rm
269 T       ldrh            \rt, [\rn]
270 .endm
271
272 .macro  ldrh_post       rt,  rn,  rm
273 A       ldrh            \rt, [\rn], \rm
274 T       ldrh            \rt, [\rn]
275 T       add             \rn, \rn, \rm
276 .endm
277
278 .macro  ldrb_post       rt,  rn,  rm
279 A       ldrb            \rt, [\rn], \rm
280 T       ldrb            \rt, [\rn]
281 T       add             \rn, \rn, \rm
282 .endm
283
284 .macro  str_post       rt,  rn,  rm:vararg
285 A       str             \rt, [\rn], \rm
286 T       str             \rt, [\rn]
287 T       add             \rn, \rn, \rm
288 .endm
289
290 .macro  strb_post       rt,  rn,  rm:vararg
291 A       strb            \rt, [\rn], \rm
292 T       strb            \rt, [\rn]
293 T       add             \rn, \rn, \rm
294 .endm
295
296 .macro  strd_post       rt,  rt2, rn,  rm
297 A       strd            \rt, \rt2, [\rn], \rm
298 T       strd            \rt, \rt2, [\rn]
299 T       add             \rn, \rn, \rm
300 .endm
301
302 .macro  strh_pre        rt,  rn,  rm
303 A       strh            \rt, [\rn, \rm]!
304 T       add             \rn, \rn, \rm
305 T       strh            \rt, [\rn]
306 .endm
307
308 .macro  strh_dpre       rt,  rn,  rm
309 A       strh            \rt, [\rn, -\rm]!
310 T       sub             \rn, \rn, \rm
311 T       strh            \rt, [\rn]
312 .endm
313
314 .macro  strh_post       rt,  rn,  rm
315 A       strh            \rt, [\rn], \rm
316 T       strh            \rt, [\rn]
317 T       add             \rn, \rn, \rm
318 .endm
319
320 .macro  strh_dpost       rt,  rn,  rm
321 A       strh            \rt, [\rn], -\rm
322 T       strh            \rt, [\rn]
323 T       sub             \rn, \rn, \rm
324 .endm
325
326 #if HAVE_VFP_ARGS
327 ELF     .eabi_attribute 28, 1
328 #   define VFP
329 #   define NOVFP @
330 #else
331 #   define VFP   @
332 #   define NOVFP
333 #endif
334
335 #define GLUE(a, b) a ## b
336 #define JOIN(a, b) GLUE(a, b)
337 #define X(s) JOIN(EXTERN_ASM, s)