x86inc: Support arbitrary stack alignments
[ffmpeg.git] / libavutil / x86 / x86inc.asm
1 ;*****************************************************************************
2 ;* x86inc.asm: x264asm abstraction layer
3 ;*****************************************************************************
4 ;* Copyright (C) 2005-2015 x264 project
5 ;*
6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
8 ;*          Fiona Glaser <fiona@x264.com>
9 ;*          Henrik Gramner <henrik@gramner.com>
10 ;*
11 ;* Permission to use, copy, modify, and/or distribute this software for any
12 ;* purpose with or without fee is hereby granted, provided that the above
13 ;* copyright notice and this permission notice appear in all copies.
14 ;*
15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
22 ;*****************************************************************************
23
24 ; This is a header file for the x264ASM assembly language, which uses
25 ; NASM/YASM syntax combined with a large number of macros to provide easy
26 ; abstraction between different calling conventions (x86_32, win64, linux64).
27 ; It also has various other useful features to simplify writing the kind of
28 ; DSP functions that are most often used in x264.
29
30 ; Unlike the rest of x264, this file is available under an ISC license, as it
31 ; has significant usefulness outside of x264 and we want it to be available
32 ; to the largest audience possible.  Of course, if you modify it for your own
33 ; purposes to add a new feature, we strongly encourage contributing a patch
34 ; as this feature might be useful for others as well.  Send patches or ideas
35 ; to x264-devel@videolan.org .
36
37 %ifndef private_prefix
38     %define private_prefix x264
39 %endif
40
41 %ifndef public_prefix
42     %define public_prefix private_prefix
43 %endif
44
45 %if HAVE_ALIGNED_STACK
46     %define STACK_ALIGNMENT 16
47 %endif
48 %ifndef STACK_ALIGNMENT
49     %if ARCH_X86_64
50         %define STACK_ALIGNMENT 16
51     %else
52         %define STACK_ALIGNMENT 4
53     %endif
54 %endif
55
56 %define WIN64  0
57 %define UNIX64 0
58 %if ARCH_X86_64
59     %ifidn __OUTPUT_FORMAT__,win32
60         %define WIN64  1
61     %elifidn __OUTPUT_FORMAT__,win64
62         %define WIN64  1
63     %elifidn __OUTPUT_FORMAT__,x64
64         %define WIN64  1
65     %else
66         %define UNIX64 1
67     %endif
68 %endif
69
70 %define FORMAT_ELF 0
71 %ifidn __OUTPUT_FORMAT__,elf
72     %define FORMAT_ELF 1
73 %elifidn __OUTPUT_FORMAT__,elf32
74     %define FORMAT_ELF 1
75 %elifidn __OUTPUT_FORMAT__,elf64
76     %define FORMAT_ELF 1
77 %endif
78
79 %ifdef PREFIX
80     %define mangle(x) _ %+ x
81 %else
82     %define mangle(x) x
83 %endif
84
85 ; aout does not support align=
86 ; NOTE: This section is out of sync with x264, in order to
87 ; keep supporting OS/2.
88 %macro SECTION_RODATA 0-1 16
89     %ifidn __OUTPUT_FORMAT__,aout
90         section .text
91     %else
92         SECTION .rodata align=%1
93     %endif
94 %endmacro
95
96 %macro SECTION_TEXT 0-1 16
97     %ifidn __OUTPUT_FORMAT__,aout
98         SECTION .text
99     %else
100         SECTION .text align=%1
101     %endif
102 %endmacro
103
104 %if WIN64
105     %define PIC
106 %elif ARCH_X86_64 == 0
107 ; x86_32 doesn't require PIC.
108 ; Some distros prefer shared objects to be PIC, but nothing breaks if
109 ; the code contains a few textrels, so we'll skip that complexity.
110     %undef PIC
111 %endif
112 %ifdef PIC
113     default rel
114 %endif
115
116 %macro CPUNOP 1
117     %if HAVE_CPUNOP
118         CPU %1
119     %endif
120 %endmacro
121
122 ; Macros to eliminate most code duplication between x86_32 and x86_64:
123 ; Currently this works only for leaf functions which load all their arguments
124 ; into registers at the start, and make no other use of the stack. Luckily that
125 ; covers most of x264's asm.
126
127 ; PROLOGUE:
128 ; %1 = number of arguments. loads them from stack if needed.
129 ; %2 = number of registers used. pushes callee-saved regs if needed.
130 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
131 ; %4 = (optional) stack size to be allocated. The stack will be aligned before
132 ;      allocating the specified stack size. If the required stack alignment is
133 ;      larger than the known stack alignment the stack will be manually aligned
134 ;      and an extra register will be allocated to hold the original stack
135 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
136 ;      register as stack pointer, request a negative stack size.
137 ; %4+/%5+ = list of names to define to registers
138 ; PROLOGUE can also be invoked by adding the same options to cglobal
139
140 ; e.g.
141 ; cglobal foo, 2,3,7,0x40, dst, src, tmp
142 ; declares a function (foo) that automatically loads two arguments (dst and
143 ; src) into registers, uses one additional register (tmp) plus 7 vector
144 ; registers (m0-m6) and allocates 0x40 bytes of stack space.
145
146 ; TODO Some functions can use some args directly from the stack. If they're the
147 ; last args then you can just not declare them, but if they're in the middle
148 ; we need more flexible macro.
149
150 ; RET:
151 ; Pops anything that was pushed by PROLOGUE, and returns.
152
153 ; REP_RET:
154 ; Use this instead of RET if it's a branch target.
155
156 ; registers:
157 ; rN and rNq are the native-size register holding function argument N
158 ; rNd, rNw, rNb are dword, word, and byte size
159 ; rNh is the high 8 bits of the word size
160 ; rNm is the original location of arg N (a register or on the stack), dword
161 ; rNmp is native size
162
163 %macro DECLARE_REG 2-3
164     %define r%1q %2
165     %define r%1d %2d
166     %define r%1w %2w
167     %define r%1b %2b
168     %define r%1h %2h
169     %define %2q %2
170     %if %0 == 2
171         %define r%1m  %2d
172         %define r%1mp %2
173     %elif ARCH_X86_64 ; memory
174         %define r%1m [rstk + stack_offset + %3]
175         %define r%1mp qword r %+ %1 %+ m
176     %else
177         %define r%1m [rstk + stack_offset + %3]
178         %define r%1mp dword r %+ %1 %+ m
179     %endif
180     %define r%1  %2
181 %endmacro
182
183 %macro DECLARE_REG_SIZE 3
184     %define r%1q r%1
185     %define e%1q r%1
186     %define r%1d e%1
187     %define e%1d e%1
188     %define r%1w %1
189     %define e%1w %1
190     %define r%1h %3
191     %define e%1h %3
192     %define r%1b %2
193     %define e%1b %2
194 %if ARCH_X86_64 == 0
195     %define r%1  e%1
196 %endif
197 %endmacro
198
199 DECLARE_REG_SIZE ax, al, ah
200 DECLARE_REG_SIZE bx, bl, bh
201 DECLARE_REG_SIZE cx, cl, ch
202 DECLARE_REG_SIZE dx, dl, dh
203 DECLARE_REG_SIZE si, sil, null
204 DECLARE_REG_SIZE di, dil, null
205 DECLARE_REG_SIZE bp, bpl, null
206
207 ; t# defines for when per-arch register allocation is more complex than just function arguments
208
209 %macro DECLARE_REG_TMP 1-*
210     %assign %%i 0
211     %rep %0
212         CAT_XDEFINE t, %%i, r%1
213         %assign %%i %%i+1
214         %rotate 1
215     %endrep
216 %endmacro
217
218 %macro DECLARE_REG_TMP_SIZE 0-*
219     %rep %0
220         %define t%1q t%1 %+ q
221         %define t%1d t%1 %+ d
222         %define t%1w t%1 %+ w
223         %define t%1h t%1 %+ h
224         %define t%1b t%1 %+ b
225         %rotate 1
226     %endrep
227 %endmacro
228
229 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
230
231 %if ARCH_X86_64
232     %define gprsize 8
233 %else
234     %define gprsize 4
235 %endif
236
237 %macro PUSH 1
238     push %1
239     %ifidn rstk, rsp
240         %assign stack_offset stack_offset+gprsize
241     %endif
242 %endmacro
243
244 %macro POP 1
245     pop %1
246     %ifidn rstk, rsp
247         %assign stack_offset stack_offset-gprsize
248     %endif
249 %endmacro
250
251 %macro PUSH_IF_USED 1-*
252     %rep %0
253         %if %1 < regs_used
254             PUSH r%1
255         %endif
256         %rotate 1
257     %endrep
258 %endmacro
259
260 %macro POP_IF_USED 1-*
261     %rep %0
262         %if %1 < regs_used
263             pop r%1
264         %endif
265         %rotate 1
266     %endrep
267 %endmacro
268
269 %macro LOAD_IF_USED 1-*
270     %rep %0
271         %if %1 < num_args
272             mov r%1, r %+ %1 %+ mp
273         %endif
274         %rotate 1
275     %endrep
276 %endmacro
277
278 %macro SUB 2
279     sub %1, %2
280     %ifidn %1, rstk
281         %assign stack_offset stack_offset+(%2)
282     %endif
283 %endmacro
284
285 %macro ADD 2
286     add %1, %2
287     %ifidn %1, rstk
288         %assign stack_offset stack_offset-(%2)
289     %endif
290 %endmacro
291
292 %macro movifnidn 2
293     %ifnidn %1, %2
294         mov %1, %2
295     %endif
296 %endmacro
297
298 %macro movsxdifnidn 2
299     %ifnidn %1, %2
300         movsxd %1, %2
301     %endif
302 %endmacro
303
304 %macro ASSERT 1
305     %if (%1) == 0
306         %error assert failed
307     %endif
308 %endmacro
309
310 %macro DEFINE_ARGS 0-*
311     %ifdef n_arg_names
312         %assign %%i 0
313         %rep n_arg_names
314             CAT_UNDEF arg_name %+ %%i, q
315             CAT_UNDEF arg_name %+ %%i, d
316             CAT_UNDEF arg_name %+ %%i, w
317             CAT_UNDEF arg_name %+ %%i, h
318             CAT_UNDEF arg_name %+ %%i, b
319             CAT_UNDEF arg_name %+ %%i, m
320             CAT_UNDEF arg_name %+ %%i, mp
321             CAT_UNDEF arg_name, %%i
322             %assign %%i %%i+1
323         %endrep
324     %endif
325
326     %xdefine %%stack_offset stack_offset
327     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
328     %assign %%i 0
329     %rep %0
330         %xdefine %1q r %+ %%i %+ q
331         %xdefine %1d r %+ %%i %+ d
332         %xdefine %1w r %+ %%i %+ w
333         %xdefine %1h r %+ %%i %+ h
334         %xdefine %1b r %+ %%i %+ b
335         %xdefine %1m r %+ %%i %+ m
336         %xdefine %1mp r %+ %%i %+ mp
337         CAT_XDEFINE arg_name, %%i, %1
338         %assign %%i %%i+1
339         %rotate 1
340     %endrep
341     %xdefine stack_offset %%stack_offset
342     %assign n_arg_names %0
343 %endmacro
344
345 %define required_stack_alignment ((mmsize + 15) & ~15)
346
347 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
348     %ifnum %1
349         %if %1 != 0
350             %assign %%pad 0
351             %assign stack_size %1
352             %if stack_size < 0
353                 %assign stack_size -stack_size
354             %endif
355             %if WIN64
356                 %assign %%pad %%pad + 32 ; shadow space
357                 %if mmsize != 8
358                     %assign xmm_regs_used %2
359                     %if xmm_regs_used > 8
360                         %assign %%pad %%pad + (xmm_regs_used-8)*16 ; callee-saved xmm registers
361                     %endif
362                 %endif
363             %endif
364             %if required_stack_alignment <= STACK_ALIGNMENT
365                 ; maintain the current stack alignment
366                 %assign stack_size_padded stack_size + %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
367                 SUB rsp, stack_size_padded
368             %else
369                 %assign %%reg_num (regs_used - 1)
370                 %xdefine rstk r %+ %%reg_num
371                 ; align stack, and save original stack location directly above
372                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
373                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
374                 ; rsp, [rsp+stack_size_padded])
375                 %if %1 < 0 ; need to store rsp on stack
376                     %xdefine rstkm [rsp + stack_size + %%pad]
377                     %assign %%pad %%pad + gprsize
378                 %else ; can keep rsp in rstk during whole function
379                     %xdefine rstkm rstk
380                 %endif
381                 %assign stack_size_padded stack_size + ((%%pad + required_stack_alignment-1) & ~(required_stack_alignment-1))
382                 mov rstk, rsp
383                 and rsp, ~(required_stack_alignment-1)
384                 sub rsp, stack_size_padded
385                 movifnidn rstkm, rstk
386             %endif
387             WIN64_PUSH_XMM
388         %endif
389     %endif
390 %endmacro
391
392 %macro SETUP_STACK_POINTER 1
393     %ifnum %1
394         %if %1 != 0 && required_stack_alignment > STACK_ALIGNMENT
395             %if %1 > 0
396                 %assign regs_used (regs_used + 1)
397             %elif ARCH_X86_64 && regs_used == num_args && num_args <= 4 + UNIX64 * 2
398                 %warning "Stack pointer will overwrite register argument"
399             %endif
400         %endif
401     %endif
402 %endmacro
403
404 %macro DEFINE_ARGS_INTERNAL 3+
405     %ifnum %2
406         DEFINE_ARGS %3
407     %elif %1 == 4
408         DEFINE_ARGS %2
409     %elif %1 > 4
410         DEFINE_ARGS %2, %3
411     %endif
412 %endmacro
413
414 %if WIN64 ; Windows x64 ;=================================================
415
416 DECLARE_REG 0,  rcx
417 DECLARE_REG 1,  rdx
418 DECLARE_REG 2,  R8
419 DECLARE_REG 3,  R9
420 DECLARE_REG 4,  R10, 40
421 DECLARE_REG 5,  R11, 48
422 DECLARE_REG 6,  rax, 56
423 DECLARE_REG 7,  rdi, 64
424 DECLARE_REG 8,  rsi, 72
425 DECLARE_REG 9,  rbx, 80
426 DECLARE_REG 10, rbp, 88
427 DECLARE_REG 11, R12, 96
428 DECLARE_REG 12, R13, 104
429 DECLARE_REG 13, R14, 112
430 DECLARE_REG 14, R15, 120
431
432 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
433     %assign num_args %1
434     %assign regs_used %2
435     ASSERT regs_used >= num_args
436     SETUP_STACK_POINTER %4
437     ASSERT regs_used <= 15
438     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
439     ALLOC_STACK %4, %3
440     %if mmsize != 8 && stack_size == 0
441         WIN64_SPILL_XMM %3
442     %endif
443     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
444     DEFINE_ARGS_INTERNAL %0, %4, %5
445 %endmacro
446
447 %macro WIN64_PUSH_XMM 0
448     ; Use the shadow space to store XMM6 and XMM7, the rest needs stack space allocated.
449     %if xmm_regs_used > 6
450         movaps [rstk + stack_offset +  8], xmm6
451     %endif
452     %if xmm_regs_used > 7
453         movaps [rstk + stack_offset + 24], xmm7
454     %endif
455     %if xmm_regs_used > 8
456         %assign %%i 8
457         %rep xmm_regs_used-8
458             movaps [rsp + (%%i-8)*16 + stack_size + 32], xmm %+ %%i
459             %assign %%i %%i+1
460         %endrep
461     %endif
462 %endmacro
463
464 %macro WIN64_SPILL_XMM 1
465     %assign xmm_regs_used %1
466     ASSERT xmm_regs_used <= 16
467     %if xmm_regs_used > 8
468         ; Allocate stack space for callee-saved xmm registers plus shadow space and align the stack.
469         %assign %%pad (xmm_regs_used-8)*16 + 32
470         %assign stack_size_padded %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
471         SUB rsp, stack_size_padded
472     %endif
473     WIN64_PUSH_XMM
474 %endmacro
475
476 %macro WIN64_RESTORE_XMM_INTERNAL 1
477     %assign %%pad_size 0
478     %if xmm_regs_used > 8
479         %assign %%i xmm_regs_used
480         %rep xmm_regs_used-8
481             %assign %%i %%i-1
482             movaps xmm %+ %%i, [%1 + (%%i-8)*16 + stack_size + 32]
483         %endrep
484     %endif
485     %if stack_size_padded > 0
486         %if stack_size > 0 && required_stack_alignment > STACK_ALIGNMENT
487             mov rsp, rstkm
488         %else
489             add %1, stack_size_padded
490             %assign %%pad_size stack_size_padded
491         %endif
492     %endif
493     %if xmm_regs_used > 7
494         movaps xmm7, [%1 + stack_offset - %%pad_size + 24]
495     %endif
496     %if xmm_regs_used > 6
497         movaps xmm6, [%1 + stack_offset - %%pad_size +  8]
498     %endif
499 %endmacro
500
501 %macro WIN64_RESTORE_XMM 1
502     WIN64_RESTORE_XMM_INTERNAL %1
503     %assign stack_offset (stack_offset-stack_size_padded)
504     %assign xmm_regs_used 0
505 %endmacro
506
507 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
508
509 %macro RET 0
510     WIN64_RESTORE_XMM_INTERNAL rsp
511     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
512 %if mmsize == 32
513     vzeroupper
514 %endif
515     AUTO_REP_RET
516 %endmacro
517
518 %elif ARCH_X86_64 ; *nix x64 ;=============================================
519
520 DECLARE_REG 0,  rdi
521 DECLARE_REG 1,  rsi
522 DECLARE_REG 2,  rdx
523 DECLARE_REG 3,  rcx
524 DECLARE_REG 4,  R8
525 DECLARE_REG 5,  R9
526 DECLARE_REG 6,  rax, 8
527 DECLARE_REG 7,  R10, 16
528 DECLARE_REG 8,  R11, 24
529 DECLARE_REG 9,  rbx, 32
530 DECLARE_REG 10, rbp, 40
531 DECLARE_REG 11, R12, 48
532 DECLARE_REG 12, R13, 56
533 DECLARE_REG 13, R14, 64
534 DECLARE_REG 14, R15, 72
535
536 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
537     %assign num_args %1
538     %assign regs_used %2
539     ASSERT regs_used >= num_args
540     SETUP_STACK_POINTER %4
541     ASSERT regs_used <= 15
542     PUSH_IF_USED 9, 10, 11, 12, 13, 14
543     ALLOC_STACK %4
544     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
545     DEFINE_ARGS_INTERNAL %0, %4, %5
546 %endmacro
547
548 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
549
550 %macro RET 0
551 %if stack_size_padded > 0
552 %if required_stack_alignment > STACK_ALIGNMENT
553     mov rsp, rstkm
554 %else
555     add rsp, stack_size_padded
556 %endif
557 %endif
558     POP_IF_USED 14, 13, 12, 11, 10, 9
559 %if mmsize == 32
560     vzeroupper
561 %endif
562     AUTO_REP_RET
563 %endmacro
564
565 %else ; X86_32 ;==============================================================
566
567 DECLARE_REG 0, eax, 4
568 DECLARE_REG 1, ecx, 8
569 DECLARE_REG 2, edx, 12
570 DECLARE_REG 3, ebx, 16
571 DECLARE_REG 4, esi, 20
572 DECLARE_REG 5, edi, 24
573 DECLARE_REG 6, ebp, 28
574 %define rsp esp
575
576 %macro DECLARE_ARG 1-*
577     %rep %0
578         %define r%1m [rstk + stack_offset + 4*%1 + 4]
579         %define r%1mp dword r%1m
580         %rotate 1
581     %endrep
582 %endmacro
583
584 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
585
586 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
587     %assign num_args %1
588     %assign regs_used %2
589     ASSERT regs_used >= num_args
590     %if num_args > 7
591         %assign num_args 7
592     %endif
593     %if regs_used > 7
594         %assign regs_used 7
595     %endif
596     SETUP_STACK_POINTER %4
597     ASSERT regs_used <= 7
598     PUSH_IF_USED 3, 4, 5, 6
599     ALLOC_STACK %4
600     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
601     DEFINE_ARGS_INTERNAL %0, %4, %5
602 %endmacro
603
604 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
605
606 %macro RET 0
607 %if stack_size_padded > 0
608 %if required_stack_alignment > STACK_ALIGNMENT
609     mov rsp, rstkm
610 %else
611     add rsp, stack_size_padded
612 %endif
613 %endif
614     POP_IF_USED 6, 5, 4, 3
615 %if mmsize == 32
616     vzeroupper
617 %endif
618     AUTO_REP_RET
619 %endmacro
620
621 %endif ;======================================================================
622
623 %if WIN64 == 0
624 %macro WIN64_SPILL_XMM 1
625 %endmacro
626 %macro WIN64_RESTORE_XMM 1
627 %endmacro
628 %macro WIN64_PUSH_XMM 0
629 %endmacro
630 %endif
631
632 ; On AMD cpus <=K10, an ordinary ret is slow if it immediately follows either
633 ; a branch or a branch target. So switch to a 2-byte form of ret in that case.
634 ; We can automatically detect "follows a branch", but not a branch target.
635 ; (SSSE3 is a sufficient condition to know that your cpu doesn't have this problem.)
636 %macro REP_RET 0
637     %if has_epilogue
638         RET
639     %else
640         rep ret
641     %endif
642 %endmacro
643
644 %define last_branch_adr $$
645 %macro AUTO_REP_RET 0
646     %ifndef cpuflags
647         times ((last_branch_adr-$)>>31)+1 rep ; times 1 iff $ != last_branch_adr.
648     %elif notcpuflag(ssse3)
649         times ((last_branch_adr-$)>>31)+1 rep
650     %endif
651     ret
652 %endmacro
653
654 %macro BRANCH_INSTR 0-*
655     %rep %0
656         %macro %1 1-2 %1
657             %2 %1
658             %%branch_instr:
659             %xdefine last_branch_adr %%branch_instr
660         %endmacro
661         %rotate 1
662     %endrep
663 %endmacro
664
665 BRANCH_INSTR jz, je, jnz, jne, jl, jle, jnl, jnle, jg, jge, jng, jnge, ja, jae, jna, jnae, jb, jbe, jnb, jnbe, jc, jnc, js, jns, jo, jno, jp, jnp
666
667 %macro TAIL_CALL 2 ; callee, is_nonadjacent
668     %if has_epilogue
669         call %1
670         RET
671     %elif %2
672         jmp %1
673     %endif
674 %endmacro
675
676 ;=============================================================================
677 ; arch-independent part
678 ;=============================================================================
679
680 %assign function_align 16
681
682 ; Begin a function.
683 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
684 ; subsequent uses of the function name automatically refer to the mangled version.
685 ; Appends cpuflags to the function name if cpuflags has been specified.
686 ; The "" empty default parameter is a workaround for nasm, which fails if SUFFIX
687 ; is empty and we call cglobal_internal with just %1 %+ SUFFIX (without %2).
688 %macro cglobal 1-2+ "" ; name, [PROLOGUE args]
689     cglobal_internal 1, %1 %+ SUFFIX, %2
690 %endmacro
691 %macro cvisible 1-2+ "" ; name, [PROLOGUE args]
692     cglobal_internal 0, %1 %+ SUFFIX, %2
693 %endmacro
694 %macro cglobal_internal 2-3+
695     %if %1
696         %xdefine %%FUNCTION_PREFIX private_prefix
697         %xdefine %%VISIBILITY hidden
698     %else
699         %xdefine %%FUNCTION_PREFIX public_prefix
700         %xdefine %%VISIBILITY
701     %endif
702     %ifndef cglobaled_%2
703         %xdefine %2 mangle(%%FUNCTION_PREFIX %+ _ %+ %2)
704         %xdefine %2.skip_prologue %2 %+ .skip_prologue
705         CAT_XDEFINE cglobaled_, %2, 1
706     %endif
707     %xdefine current_function %2
708     %if FORMAT_ELF
709         global %2:function %%VISIBILITY
710     %else
711         global %2
712     %endif
713     align function_align
714     %2:
715     RESET_MM_PERMUTATION        ; needed for x86-64, also makes disassembly somewhat nicer
716     %xdefine rstk rsp           ; copy of the original stack pointer, used when greater alignment than the known stack alignment is required
717     %assign stack_offset 0      ; stack pointer offset relative to the return address
718     %assign stack_size 0        ; amount of stack space that can be freely used inside a function
719     %assign stack_size_padded 0 ; total amount of allocated stack space, including space for callee-saved xmm registers on WIN64 and alignment padding
720     %assign xmm_regs_used 0     ; number of XMM registers requested, used for dealing with callee-saved registers on WIN64
721     %ifnidn %3, ""
722         PROLOGUE %3
723     %endif
724 %endmacro
725
726 %macro cextern 1
727     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
728     CAT_XDEFINE cglobaled_, %1, 1
729     extern %1
730 %endmacro
731
732 ; like cextern, but without the prefix
733 %macro cextern_naked 1
734     %ifdef PREFIX
735         %xdefine %1 mangle(%1)
736     %endif
737     CAT_XDEFINE cglobaled_, %1, 1
738     extern %1
739 %endmacro
740
741 %macro const 1-2+
742     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
743     %if FORMAT_ELF
744         global %1:data hidden
745     %else
746         global %1
747     %endif
748     %1: %2
749 %endmacro
750
751 ; This is needed for ELF, otherwise the GNU linker assumes the stack is executable by default.
752 %if FORMAT_ELF
753     [SECTION .note.GNU-stack noalloc noexec nowrite progbits]
754 %endif
755
756 ; Overrides the default .text section.
757 ; Silences warnings when defining structures.
758 %define __SECT__
759
760 ; cpuflags
761
762 %assign cpuflags_mmx      (1<<0)
763 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
764 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
765 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
766 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
767 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
768 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
769 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
770 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
771 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
772 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
773 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
774 %assign cpuflags_xop      (1<<12)| cpuflags_avx
775 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
776 %assign cpuflags_fma3     (1<<14)| cpuflags_avx
777 %assign cpuflags_avx2     (1<<15)| cpuflags_fma3
778
779 %assign cpuflags_cache32  (1<<16)
780 %assign cpuflags_cache64  (1<<17)
781 %assign cpuflags_slowctz  (1<<18)
782 %assign cpuflags_lzcnt    (1<<19)
783 %assign cpuflags_aligned  (1<<20) ; not a cpu feature, but a function variant
784 %assign cpuflags_atom     (1<<21)
785 %assign cpuflags_bmi1     (1<<22)|cpuflags_lzcnt
786 %assign cpuflags_bmi2     (1<<23)|cpuflags_bmi1
787
788 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
789 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
790
791 ; Takes an arbitrary number of cpuflags from the above list.
792 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
793 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
794 %macro INIT_CPUFLAGS 0-*
795     %xdefine SUFFIX
796     %undef cpuname
797     %assign cpuflags 0
798
799     %if %0 >= 1
800         %rep %0
801             %ifdef cpuname
802                 %xdefine cpuname cpuname %+ _%1
803             %else
804                 %xdefine cpuname %1
805             %endif
806             %assign cpuflags cpuflags | cpuflags_%1
807             %rotate 1
808         %endrep
809         %xdefine SUFFIX _ %+ cpuname
810
811         %if cpuflag(avx)
812             %assign avx_enabled 1
813         %endif
814         %if (mmsize == 16 && notcpuflag(sse2)) || (mmsize == 32 && notcpuflag(avx2))
815             %define mova movaps
816             %define movu movups
817             %define movnta movntps
818         %endif
819         %if cpuflag(aligned)
820             %define movu mova
821         %elif cpuflag(sse3) && notcpuflag(ssse3)
822             %define movu lddqu
823         %endif
824     %endif
825
826     %if ARCH_X86_64 || cpuflag(sse2)
827         CPUNOP amdnop
828     %else
829         CPUNOP basicnop
830     %endif
831 %endmacro
832
833 ; Merge mmx and sse*
834 ; m# is a simd register of the currently selected size
835 ; xm# is the corresponding xmm register if mmsize >= 16, otherwise the same as m#
836 ; ym# is the corresponding ymm register if mmsize >= 32, otherwise the same as m#
837 ; (All 3 remain in sync through SWAP.)
838
839 %macro CAT_XDEFINE 3
840     %xdefine %1%2 %3
841 %endmacro
842
843 %macro CAT_UNDEF 2
844     %undef %1%2
845 %endmacro
846
847 %macro INIT_MMX 0-1+
848     %assign avx_enabled 0
849     %define RESET_MM_PERMUTATION INIT_MMX %1
850     %define mmsize 8
851     %define num_mmregs 8
852     %define mova movq
853     %define movu movq
854     %define movh movd
855     %define movnta movntq
856     %assign %%i 0
857     %rep 8
858     CAT_XDEFINE m, %%i, mm %+ %%i
859     CAT_XDEFINE nnmm, %%i, %%i
860     %assign %%i %%i+1
861     %endrep
862     %rep 8
863     CAT_UNDEF m, %%i
864     CAT_UNDEF nnmm, %%i
865     %assign %%i %%i+1
866     %endrep
867     INIT_CPUFLAGS %1
868 %endmacro
869
870 %macro INIT_XMM 0-1+
871     %assign avx_enabled 0
872     %define RESET_MM_PERMUTATION INIT_XMM %1
873     %define mmsize 16
874     %define num_mmregs 8
875     %if ARCH_X86_64
876     %define num_mmregs 16
877     %endif
878     %define mova movdqa
879     %define movu movdqu
880     %define movh movq
881     %define movnta movntdq
882     %assign %%i 0
883     %rep num_mmregs
884     CAT_XDEFINE m, %%i, xmm %+ %%i
885     CAT_XDEFINE nnxmm, %%i, %%i
886     %assign %%i %%i+1
887     %endrep
888     INIT_CPUFLAGS %1
889 %endmacro
890
891 %macro INIT_YMM 0-1+
892     %assign avx_enabled 1
893     %define RESET_MM_PERMUTATION INIT_YMM %1
894     %define mmsize 32
895     %define num_mmregs 8
896     %if ARCH_X86_64
897     %define num_mmregs 16
898     %endif
899     %define mova movdqa
900     %define movu movdqu
901     %undef movh
902     %define movnta movntdq
903     %assign %%i 0
904     %rep num_mmregs
905     CAT_XDEFINE m, %%i, ymm %+ %%i
906     CAT_XDEFINE nnymm, %%i, %%i
907     %assign %%i %%i+1
908     %endrep
909     INIT_CPUFLAGS %1
910 %endmacro
911
912 INIT_XMM
913
914 %macro DECLARE_MMCAST 1
915     %define  mmmm%1   mm%1
916     %define  mmxmm%1  mm%1
917     %define  mmymm%1  mm%1
918     %define xmmmm%1   mm%1
919     %define xmmxmm%1 xmm%1
920     %define xmmymm%1 xmm%1
921     %define ymmmm%1   mm%1
922     %define ymmxmm%1 xmm%1
923     %define ymmymm%1 ymm%1
924     %define xm%1 xmm %+ m%1
925     %define ym%1 ymm %+ m%1
926 %endmacro
927
928 %assign i 0
929 %rep 16
930     DECLARE_MMCAST i
931 %assign i i+1
932 %endrep
933
934 ; I often want to use macros that permute their arguments. e.g. there's no
935 ; efficient way to implement butterfly or transpose or dct without swapping some
936 ; arguments.
937 ;
938 ; I would like to not have to manually keep track of the permutations:
939 ; If I insert a permutation in the middle of a function, it should automatically
940 ; change everything that follows. For more complex macros I may also have multiple
941 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
942 ;
943 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
944 ; permutes its arguments. It's equivalent to exchanging the contents of the
945 ; registers, except that this way you exchange the register names instead, so it
946 ; doesn't cost any cycles.
947
948 %macro PERMUTE 2-* ; takes a list of pairs to swap
949 %rep %0/2
950     %xdefine %%tmp%2 m%2
951     %rotate 2
952 %endrep
953 %rep %0/2
954     %xdefine m%1 %%tmp%2
955     CAT_XDEFINE nn, m%1, %1
956     %rotate 2
957 %endrep
958 %endmacro
959
960 %macro SWAP 2+ ; swaps a single chain (sometimes more concise than pairs)
961 %ifnum %1 ; SWAP 0, 1, ...
962     SWAP_INTERNAL_NUM %1, %2
963 %else ; SWAP m0, m1, ...
964     SWAP_INTERNAL_NAME %1, %2
965 %endif
966 %endmacro
967
968 %macro SWAP_INTERNAL_NUM 2-*
969     %rep %0-1
970         %xdefine %%tmp m%1
971         %xdefine m%1 m%2
972         %xdefine m%2 %%tmp
973         CAT_XDEFINE nn, m%1, %1
974         CAT_XDEFINE nn, m%2, %2
975     %rotate 1
976     %endrep
977 %endmacro
978
979 %macro SWAP_INTERNAL_NAME 2-*
980     %xdefine %%args nn %+ %1
981     %rep %0-1
982         %xdefine %%args %%args, nn %+ %2
983     %rotate 1
984     %endrep
985     SWAP_INTERNAL_NUM %%args
986 %endmacro
987
988 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
989 ; calls to that function will automatically load the permutation, so values can
990 ; be returned in mmregs.
991 %macro SAVE_MM_PERMUTATION 0-1
992     %if %0
993         %xdefine %%f %1_m
994     %else
995         %xdefine %%f current_function %+ _m
996     %endif
997     %assign %%i 0
998     %rep num_mmregs
999         CAT_XDEFINE %%f, %%i, m %+ %%i
1000     %assign %%i %%i+1
1001     %endrep
1002 %endmacro
1003
1004 %macro LOAD_MM_PERMUTATION 1 ; name to load from
1005     %ifdef %1_m0
1006         %assign %%i 0
1007         %rep num_mmregs
1008             CAT_XDEFINE m, %%i, %1_m %+ %%i
1009             CAT_XDEFINE nn, m %+ %%i, %%i
1010         %assign %%i %%i+1
1011         %endrep
1012     %endif
1013 %endmacro
1014
1015 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
1016 %macro call 1
1017     call_internal %1 %+ SUFFIX, %1
1018 %endmacro
1019 %macro call_internal 2
1020     %xdefine %%i %2
1021     %ifndef cglobaled_%2
1022         %ifdef cglobaled_%1
1023             %xdefine %%i %1
1024         %endif
1025     %endif
1026     call %%i
1027     LOAD_MM_PERMUTATION %%i
1028 %endmacro
1029
1030 ; Substitutions that reduce instruction size but are functionally equivalent
1031 %macro add 2
1032     %ifnum %2
1033         %if %2==128
1034             sub %1, -128
1035         %else
1036             add %1, %2
1037         %endif
1038     %else
1039         add %1, %2
1040     %endif
1041 %endmacro
1042
1043 %macro sub 2
1044     %ifnum %2
1045         %if %2==128
1046             add %1, -128
1047         %else
1048             sub %1, %2
1049         %endif
1050     %else
1051         sub %1, %2
1052     %endif
1053 %endmacro
1054
1055 ;=============================================================================
1056 ; AVX abstraction layer
1057 ;=============================================================================
1058
1059 %assign i 0
1060 %rep 16
1061     %if i < 8
1062         CAT_XDEFINE sizeofmm, i, 8
1063     %endif
1064     CAT_XDEFINE sizeofxmm, i, 16
1065     CAT_XDEFINE sizeofymm, i, 32
1066 %assign i i+1
1067 %endrep
1068 %undef i
1069
1070 %macro CHECK_AVX_INSTR_EMU 3-*
1071     %xdefine %%opcode %1
1072     %xdefine %%dst %2
1073     %rep %0-2
1074         %ifidn %%dst, %3
1075             %error non-avx emulation of ``%%opcode'' is not supported
1076         %endif
1077         %rotate 1
1078     %endrep
1079 %endmacro
1080
1081 ;%1 == instruction
1082 ;%2 == minimal instruction set
1083 ;%3 == 1 if float, 0 if int
1084 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1085 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1086 ;%6+: operands
1087 %macro RUN_AVX_INSTR 6-9+
1088     %ifnum sizeof%7
1089         %assign __sizeofreg sizeof%7
1090     %elifnum sizeof%6
1091         %assign __sizeofreg sizeof%6
1092     %else
1093         %assign __sizeofreg mmsize
1094     %endif
1095     %assign __emulate_avx 0
1096     %if avx_enabled && __sizeofreg >= 16
1097         %xdefine __instr v%1
1098     %else
1099         %xdefine __instr %1
1100         %if %0 >= 8+%4
1101             %assign __emulate_avx 1
1102         %endif
1103     %endif
1104     %ifnidn %2, fnord
1105         %ifdef cpuname
1106             %if notcpuflag(%2)
1107                 %error use of ``%1'' %2 instruction in cpuname function: current_function
1108             %elif cpuflags_%2 < cpuflags_sse && notcpuflag(sse2) && __sizeofreg > 8
1109                 %error use of ``%1'' sse2 instruction in cpuname function: current_function
1110             %endif
1111         %endif
1112     %endif
1113
1114     %if __emulate_avx
1115         %xdefine __src1 %7
1116         %xdefine __src2 %8
1117         %ifnidn %6, %7
1118             %if %0 >= 9
1119                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8, %9}, %6, %8, %9
1120             %else
1121                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8}, %6, %8
1122             %endif
1123             %if %5 && %4 == 0
1124                 %ifnid %8
1125                     ; 3-operand AVX instructions with a memory arg can only have it in src2,
1126                     ; whereas SSE emulation prefers to have it in src1 (i.e. the mov).
1127                     ; So, if the instruction is commutative with a memory arg, swap them.
1128                     %xdefine __src1 %8
1129                     %xdefine __src2 %7
1130                 %endif
1131             %endif
1132             %if __sizeofreg == 8
1133                 MOVQ %6, __src1
1134             %elif %3
1135                 MOVAPS %6, __src1
1136             %else
1137                 MOVDQA %6, __src1
1138             %endif
1139         %endif
1140         %if %0 >= 9
1141             %1 %6, __src2, %9
1142         %else
1143             %1 %6, __src2
1144         %endif
1145     %elif %0 >= 9
1146         __instr %6, %7, %8, %9
1147     %elif %0 == 8
1148         __instr %6, %7, %8
1149     %elif %0 == 7
1150         __instr %6, %7
1151     %else
1152         __instr %6
1153     %endif
1154 %endmacro
1155
1156 ;%1 == instruction
1157 ;%2 == minimal instruction set
1158 ;%3 == 1 if float, 0 if int
1159 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1160 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1161 %macro AVX_INSTR 1-5 fnord, 0, 1, 0
1162     %macro %1 1-10 fnord, fnord, fnord, fnord, %1, %2, %3, %4, %5
1163         %ifidn %2, fnord
1164             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1
1165         %elifidn %3, fnord
1166             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2
1167         %elifidn %4, fnord
1168             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3
1169         %elifidn %5, fnord
1170             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4
1171         %else
1172             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4, %5
1173         %endif
1174     %endmacro
1175 %endmacro
1176
1177 ; Instructions with both VEX and non-VEX encodings
1178 ; Non-destructive instructions are written without parameters
1179 AVX_INSTR addpd, sse2, 1, 0, 1
1180 AVX_INSTR addps, sse, 1, 0, 1
1181 AVX_INSTR addsd, sse2, 1, 0, 1
1182 AVX_INSTR addss, sse, 1, 0, 1
1183 AVX_INSTR addsubpd, sse3, 1, 0, 0
1184 AVX_INSTR addsubps, sse3, 1, 0, 0
1185 AVX_INSTR aesdec, fnord, 0, 0, 0
1186 AVX_INSTR aesdeclast, fnord, 0, 0, 0
1187 AVX_INSTR aesenc, fnord, 0, 0, 0
1188 AVX_INSTR aesenclast, fnord, 0, 0, 0
1189 AVX_INSTR aesimc
1190 AVX_INSTR aeskeygenassist
1191 AVX_INSTR andnpd, sse2, 1, 0, 0
1192 AVX_INSTR andnps, sse, 1, 0, 0
1193 AVX_INSTR andpd, sse2, 1, 0, 1
1194 AVX_INSTR andps, sse, 1, 0, 1
1195 AVX_INSTR blendpd, sse4, 1, 0, 0
1196 AVX_INSTR blendps, sse4, 1, 0, 0
1197 AVX_INSTR blendvpd, sse4, 1, 0, 0
1198 AVX_INSTR blendvps, sse4, 1, 0, 0
1199 AVX_INSTR cmppd, sse2, 1, 1, 0
1200 AVX_INSTR cmpps, sse, 1, 1, 0
1201 AVX_INSTR cmpsd, sse2, 1, 1, 0
1202 AVX_INSTR cmpss, sse, 1, 1, 0
1203 AVX_INSTR comisd, sse2
1204 AVX_INSTR comiss, sse
1205 AVX_INSTR cvtdq2pd, sse2
1206 AVX_INSTR cvtdq2ps, sse2
1207 AVX_INSTR cvtpd2dq, sse2
1208 AVX_INSTR cvtpd2ps, sse2
1209 AVX_INSTR cvtps2dq, sse2
1210 AVX_INSTR cvtps2pd, sse2
1211 AVX_INSTR cvtsd2si, sse2
1212 AVX_INSTR cvtsd2ss, sse2
1213 AVX_INSTR cvtsi2sd, sse2
1214 AVX_INSTR cvtsi2ss, sse
1215 AVX_INSTR cvtss2sd, sse2
1216 AVX_INSTR cvtss2si, sse
1217 AVX_INSTR cvttpd2dq, sse2
1218 AVX_INSTR cvttps2dq, sse2
1219 AVX_INSTR cvttsd2si, sse2
1220 AVX_INSTR cvttss2si, sse
1221 AVX_INSTR divpd, sse2, 1, 0, 0
1222 AVX_INSTR divps, sse, 1, 0, 0
1223 AVX_INSTR divsd, sse2, 1, 0, 0
1224 AVX_INSTR divss, sse, 1, 0, 0
1225 AVX_INSTR dppd, sse4, 1, 1, 0
1226 AVX_INSTR dpps, sse4, 1, 1, 0
1227 AVX_INSTR extractps, sse4
1228 AVX_INSTR haddpd, sse3, 1, 0, 0
1229 AVX_INSTR haddps, sse3, 1, 0, 0
1230 AVX_INSTR hsubpd, sse3, 1, 0, 0
1231 AVX_INSTR hsubps, sse3, 1, 0, 0
1232 AVX_INSTR insertps, sse4, 1, 1, 0
1233 AVX_INSTR lddqu, sse3
1234 AVX_INSTR ldmxcsr, sse
1235 AVX_INSTR maskmovdqu, sse2
1236 AVX_INSTR maxpd, sse2, 1, 0, 1
1237 AVX_INSTR maxps, sse, 1, 0, 1
1238 AVX_INSTR maxsd, sse2, 1, 0, 1
1239 AVX_INSTR maxss, sse, 1, 0, 1
1240 AVX_INSTR minpd, sse2, 1, 0, 1
1241 AVX_INSTR minps, sse, 1, 0, 1
1242 AVX_INSTR minsd, sse2, 1, 0, 1
1243 AVX_INSTR minss, sse, 1, 0, 1
1244 AVX_INSTR movapd, sse2
1245 AVX_INSTR movaps, sse
1246 AVX_INSTR movd, mmx
1247 AVX_INSTR movddup, sse3
1248 AVX_INSTR movdqa, sse2
1249 AVX_INSTR movdqu, sse2
1250 AVX_INSTR movhlps, sse, 1, 0, 0
1251 AVX_INSTR movhpd, sse2, 1, 0, 0
1252 AVX_INSTR movhps, sse, 1, 0, 0
1253 AVX_INSTR movlhps, sse, 1, 0, 0
1254 AVX_INSTR movlpd, sse2, 1, 0, 0
1255 AVX_INSTR movlps, sse, 1, 0, 0
1256 AVX_INSTR movmskpd, sse2
1257 AVX_INSTR movmskps, sse
1258 AVX_INSTR movntdq, sse2
1259 AVX_INSTR movntdqa, sse4
1260 AVX_INSTR movntpd, sse2
1261 AVX_INSTR movntps, sse
1262 AVX_INSTR movq, mmx
1263 AVX_INSTR movsd, sse2, 1, 0, 0
1264 AVX_INSTR movshdup, sse3
1265 AVX_INSTR movsldup, sse3
1266 AVX_INSTR movss, sse, 1, 0, 0
1267 AVX_INSTR movupd, sse2
1268 AVX_INSTR movups, sse
1269 AVX_INSTR mpsadbw, sse4
1270 AVX_INSTR mulpd, sse2, 1, 0, 1
1271 AVX_INSTR mulps, sse, 1, 0, 1
1272 AVX_INSTR mulsd, sse2, 1, 0, 1
1273 AVX_INSTR mulss, sse, 1, 0, 1
1274 AVX_INSTR orpd, sse2, 1, 0, 1
1275 AVX_INSTR orps, sse, 1, 0, 1
1276 AVX_INSTR pabsb, ssse3
1277 AVX_INSTR pabsd, ssse3
1278 AVX_INSTR pabsw, ssse3
1279 AVX_INSTR packsswb, mmx, 0, 0, 0
1280 AVX_INSTR packssdw, mmx, 0, 0, 0
1281 AVX_INSTR packuswb, mmx, 0, 0, 0
1282 AVX_INSTR packusdw, sse4, 0, 0, 0
1283 AVX_INSTR paddb, mmx, 0, 0, 1
1284 AVX_INSTR paddw, mmx, 0, 0, 1
1285 AVX_INSTR paddd, mmx, 0, 0, 1
1286 AVX_INSTR paddq, sse2, 0, 0, 1
1287 AVX_INSTR paddsb, mmx, 0, 0, 1
1288 AVX_INSTR paddsw, mmx, 0, 0, 1
1289 AVX_INSTR paddusb, mmx, 0, 0, 1
1290 AVX_INSTR paddusw, mmx, 0, 0, 1
1291 AVX_INSTR palignr, ssse3
1292 AVX_INSTR pand, mmx, 0, 0, 1
1293 AVX_INSTR pandn, mmx, 0, 0, 0
1294 AVX_INSTR pavgb, mmx2, 0, 0, 1
1295 AVX_INSTR pavgw, mmx2, 0, 0, 1
1296 AVX_INSTR pblendvb, sse4, 0, 0, 0
1297 AVX_INSTR pblendw, sse4
1298 AVX_INSTR pclmulqdq
1299 AVX_INSTR pcmpestri, sse42
1300 AVX_INSTR pcmpestrm, sse42
1301 AVX_INSTR pcmpistri, sse42
1302 AVX_INSTR pcmpistrm, sse42
1303 AVX_INSTR pcmpeqb, mmx, 0, 0, 1
1304 AVX_INSTR pcmpeqw, mmx, 0, 0, 1
1305 AVX_INSTR pcmpeqd, mmx, 0, 0, 1
1306 AVX_INSTR pcmpeqq, sse4, 0, 0, 1
1307 AVX_INSTR pcmpgtb, mmx, 0, 0, 0
1308 AVX_INSTR pcmpgtw, mmx, 0, 0, 0
1309 AVX_INSTR pcmpgtd, mmx, 0, 0, 0
1310 AVX_INSTR pcmpgtq, sse42, 0, 0, 0
1311 AVX_INSTR pextrb, sse4
1312 AVX_INSTR pextrd, sse4
1313 AVX_INSTR pextrq, sse4
1314 AVX_INSTR pextrw, mmx2
1315 AVX_INSTR phaddw, ssse3, 0, 0, 0
1316 AVX_INSTR phaddd, ssse3, 0, 0, 0
1317 AVX_INSTR phaddsw, ssse3, 0, 0, 0
1318 AVX_INSTR phminposuw, sse4
1319 AVX_INSTR phsubw, ssse3, 0, 0, 0
1320 AVX_INSTR phsubd, ssse3, 0, 0, 0
1321 AVX_INSTR phsubsw, ssse3, 0, 0, 0
1322 AVX_INSTR pinsrb, sse4
1323 AVX_INSTR pinsrd, sse4
1324 AVX_INSTR pinsrq, sse4
1325 AVX_INSTR pinsrw, mmx2
1326 AVX_INSTR pmaddwd, mmx, 0, 0, 1
1327 AVX_INSTR pmaddubsw, ssse3, 0, 0, 0
1328 AVX_INSTR pmaxsb, sse4, 0, 0, 1
1329 AVX_INSTR pmaxsw, mmx2, 0, 0, 1
1330 AVX_INSTR pmaxsd, sse4, 0, 0, 1
1331 AVX_INSTR pmaxub, mmx2, 0, 0, 1
1332 AVX_INSTR pmaxuw, sse4, 0, 0, 1
1333 AVX_INSTR pmaxud, sse4, 0, 0, 1
1334 AVX_INSTR pminsb, sse4, 0, 0, 1
1335 AVX_INSTR pminsw, mmx2, 0, 0, 1
1336 AVX_INSTR pminsd, sse4, 0, 0, 1
1337 AVX_INSTR pminub, mmx2, 0, 0, 1
1338 AVX_INSTR pminuw, sse4, 0, 0, 1
1339 AVX_INSTR pminud, sse4, 0, 0, 1
1340 AVX_INSTR pmovmskb, mmx2
1341 AVX_INSTR pmovsxbw, sse4
1342 AVX_INSTR pmovsxbd, sse4
1343 AVX_INSTR pmovsxbq, sse4
1344 AVX_INSTR pmovsxwd, sse4
1345 AVX_INSTR pmovsxwq, sse4
1346 AVX_INSTR pmovsxdq, sse4
1347 AVX_INSTR pmovzxbw, sse4
1348 AVX_INSTR pmovzxbd, sse4
1349 AVX_INSTR pmovzxbq, sse4
1350 AVX_INSTR pmovzxwd, sse4
1351 AVX_INSTR pmovzxwq, sse4
1352 AVX_INSTR pmovzxdq, sse4
1353 AVX_INSTR pmuldq, sse4, 0, 0, 1
1354 AVX_INSTR pmulhrsw, ssse3, 0, 0, 1
1355 AVX_INSTR pmulhuw, mmx2, 0, 0, 1
1356 AVX_INSTR pmulhw, mmx, 0, 0, 1
1357 AVX_INSTR pmullw, mmx, 0, 0, 1
1358 AVX_INSTR pmulld, sse4, 0, 0, 1
1359 AVX_INSTR pmuludq, sse2, 0, 0, 1
1360 AVX_INSTR por, mmx, 0, 0, 1
1361 AVX_INSTR psadbw, mmx2, 0, 0, 1
1362 AVX_INSTR pshufb, ssse3, 0, 0, 0
1363 AVX_INSTR pshufd, sse2
1364 AVX_INSTR pshufhw, sse2
1365 AVX_INSTR pshuflw, sse2
1366 AVX_INSTR psignb, ssse3, 0, 0, 0
1367 AVX_INSTR psignw, ssse3, 0, 0, 0
1368 AVX_INSTR psignd, ssse3, 0, 0, 0
1369 AVX_INSTR psllw, mmx, 0, 0, 0
1370 AVX_INSTR pslld, mmx, 0, 0, 0
1371 AVX_INSTR psllq, mmx, 0, 0, 0
1372 AVX_INSTR pslldq, sse2, 0, 0, 0
1373 AVX_INSTR psraw, mmx, 0, 0, 0
1374 AVX_INSTR psrad, mmx, 0, 0, 0
1375 AVX_INSTR psrlw, mmx, 0, 0, 0
1376 AVX_INSTR psrld, mmx, 0, 0, 0
1377 AVX_INSTR psrlq, mmx, 0, 0, 0
1378 AVX_INSTR psrldq, sse2, 0, 0, 0
1379 AVX_INSTR psubb, mmx, 0, 0, 0
1380 AVX_INSTR psubw, mmx, 0, 0, 0
1381 AVX_INSTR psubd, mmx, 0, 0, 0
1382 AVX_INSTR psubq, sse2, 0, 0, 0
1383 AVX_INSTR psubsb, mmx, 0, 0, 0
1384 AVX_INSTR psubsw, mmx, 0, 0, 0
1385 AVX_INSTR psubusb, mmx, 0, 0, 0
1386 AVX_INSTR psubusw, mmx, 0, 0, 0
1387 AVX_INSTR ptest, sse4
1388 AVX_INSTR punpckhbw, mmx, 0, 0, 0
1389 AVX_INSTR punpckhwd, mmx, 0, 0, 0
1390 AVX_INSTR punpckhdq, mmx, 0, 0, 0
1391 AVX_INSTR punpckhqdq, sse2, 0, 0, 0
1392 AVX_INSTR punpcklbw, mmx, 0, 0, 0
1393 AVX_INSTR punpcklwd, mmx, 0, 0, 0
1394 AVX_INSTR punpckldq, mmx, 0, 0, 0
1395 AVX_INSTR punpcklqdq, sse2, 0, 0, 0
1396 AVX_INSTR pxor, mmx, 0, 0, 1
1397 AVX_INSTR rcpps, sse, 1, 0, 0
1398 AVX_INSTR rcpss, sse, 1, 0, 0
1399 AVX_INSTR roundpd, sse4
1400 AVX_INSTR roundps, sse4
1401 AVX_INSTR roundsd, sse4
1402 AVX_INSTR roundss, sse4
1403 AVX_INSTR rsqrtps, sse, 1, 0, 0
1404 AVX_INSTR rsqrtss, sse, 1, 0, 0
1405 AVX_INSTR shufpd, sse2, 1, 1, 0
1406 AVX_INSTR shufps, sse, 1, 1, 0
1407 AVX_INSTR sqrtpd, sse2, 1, 0, 0
1408 AVX_INSTR sqrtps, sse, 1, 0, 0
1409 AVX_INSTR sqrtsd, sse2, 1, 0, 0
1410 AVX_INSTR sqrtss, sse, 1, 0, 0
1411 AVX_INSTR stmxcsr, sse
1412 AVX_INSTR subpd, sse2, 1, 0, 0
1413 AVX_INSTR subps, sse, 1, 0, 0
1414 AVX_INSTR subsd, sse2, 1, 0, 0
1415 AVX_INSTR subss, sse, 1, 0, 0
1416 AVX_INSTR ucomisd, sse2
1417 AVX_INSTR ucomiss, sse
1418 AVX_INSTR unpckhpd, sse2, 1, 0, 0
1419 AVX_INSTR unpckhps, sse, 1, 0, 0
1420 AVX_INSTR unpcklpd, sse2, 1, 0, 0
1421 AVX_INSTR unpcklps, sse, 1, 0, 0
1422 AVX_INSTR xorpd, sse2, 1, 0, 1
1423 AVX_INSTR xorps, sse, 1, 0, 1
1424
1425 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1426 AVX_INSTR pfadd, 3dnow, 1, 0, 1
1427 AVX_INSTR pfsub, 3dnow, 1, 0, 0
1428 AVX_INSTR pfmul, 3dnow, 1, 0, 1
1429
1430 ; base-4 constants for shuffles
1431 %assign i 0
1432 %rep 256
1433     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1434     %if j < 10
1435         CAT_XDEFINE q000, j, i
1436     %elif j < 100
1437         CAT_XDEFINE q00, j, i
1438     %elif j < 1000
1439         CAT_XDEFINE q0, j, i
1440     %else
1441         CAT_XDEFINE q, j, i
1442     %endif
1443 %assign i i+1
1444 %endrep
1445 %undef i
1446 %undef j
1447
1448 %macro FMA_INSTR 3
1449     %macro %1 4-7 %1, %2, %3
1450         %if cpuflag(xop)
1451             v%5 %1, %2, %3, %4
1452         %else
1453             %6 %1, %2, %3
1454             %7 %1, %4
1455         %endif
1456     %endmacro
1457 %endmacro
1458
1459 FMA_INSTR  pmacsww,  pmullw, paddw
1460 FMA_INSTR  pmacsdd,  pmulld, paddd ; sse4 emulation
1461 FMA_INSTR pmacsdql,  pmuldq, paddq ; sse4 emulation
1462 FMA_INSTR pmadcswd, pmaddwd, paddd
1463
1464 ; tzcnt is equivalent to "rep bsf" and is backwards-compatible with bsf.
1465 ; This lets us use tzcnt without bumping the yasm version requirement yet.
1466 %define tzcnt rep bsf
1467
1468 ; convert FMA4 to FMA3 if possible
1469 %macro FMA4_INSTR 4
1470     %macro %1 4-8 %1, %2, %3, %4
1471         %if cpuflag(fma4)
1472             v%5 %1, %2, %3, %4
1473         %elifidn %1, %2
1474             v%6 %1, %4, %3 ; %1 = %1 * %3 + %4
1475         %elifidn %1, %3
1476             v%7 %1, %2, %4 ; %1 = %2 * %1 + %4
1477         %elifidn %1, %4
1478             v%8 %1, %2, %3 ; %1 = %2 * %3 + %1
1479         %else
1480             %error fma3 emulation of ``%5 %1, %2, %3, %4'' is not supported
1481         %endif
1482     %endmacro
1483 %endmacro
1484
1485 FMA4_INSTR fmaddpd, fmadd132pd, fmadd213pd, fmadd231pd
1486 FMA4_INSTR fmaddps, fmadd132ps, fmadd213ps, fmadd231ps
1487 FMA4_INSTR fmaddsd, fmadd132sd, fmadd213sd, fmadd231sd
1488 FMA4_INSTR fmaddss, fmadd132ss, fmadd213ss, fmadd231ss
1489
1490 FMA4_INSTR fmaddsubpd, fmaddsub132pd, fmaddsub213pd, fmaddsub231pd
1491 FMA4_INSTR fmaddsubps, fmaddsub132ps, fmaddsub213ps, fmaddsub231ps
1492 FMA4_INSTR fmsubaddpd, fmsubadd132pd, fmsubadd213pd, fmsubadd231pd
1493 FMA4_INSTR fmsubaddps, fmsubadd132ps, fmsubadd213ps, fmsubadd231ps
1494
1495 FMA4_INSTR fmsubpd, fmsub132pd, fmsub213pd, fmsub231pd
1496 FMA4_INSTR fmsubps, fmsub132ps, fmsub213ps, fmsub231ps
1497 FMA4_INSTR fmsubsd, fmsub132sd, fmsub213sd, fmsub231sd
1498 FMA4_INSTR fmsubss, fmsub132ss, fmsub213ss, fmsub231ss
1499
1500 FMA4_INSTR fnmaddpd, fnmadd132pd, fnmadd213pd, fnmadd231pd
1501 FMA4_INSTR fnmaddps, fnmadd132ps, fnmadd213ps, fnmadd231ps
1502 FMA4_INSTR fnmaddsd, fnmadd132sd, fnmadd213sd, fnmadd231sd
1503 FMA4_INSTR fnmaddss, fnmadd132ss, fnmadd213ss, fnmadd231ss
1504
1505 FMA4_INSTR fnmsubpd, fnmsub132pd, fnmsub213pd, fnmsub231pd
1506 FMA4_INSTR fnmsubps, fnmsub132ps, fnmsub213ps, fnmsub231ps
1507 FMA4_INSTR fnmsubsd, fnmsub132sd, fnmsub213sd, fnmsub231sd
1508 FMA4_INSTR fnmsubss, fnmsub132ss, fnmsub213ss, fnmsub231ss
1509
1510 ; workaround: vpbroadcastq is broken in x86_32 due to a yasm bug (fixed in 1.3.0)
1511 %ifdef __YASM_VER__
1512     %if __YASM_VERSION_ID__ < 0x01030000 && ARCH_X86_64 == 0
1513         %macro vpbroadcastq 2
1514             %if sizeof%1 == 16
1515                 movddup %1, %2
1516             %else
1517                 vbroadcastsd %1, %2
1518             %endif
1519         %endmacro
1520     %endif
1521 %endif