Merge commit '8114c101607843a86960bd3e0e9c40487dc2a961'
[ffmpeg.git] / libavcodec / alpha / dsputil_alpha_asm.S
1 /*
2  * Alpha optimized DSP utils
3  * Copyright (c) 2002 Falk Hueffner <falk@debian.org>
4  *
5  * This file is part of FFmpeg.
6  *
7  * FFmpeg is free software; you can redistribute it and/or
8  * modify it under the terms of the GNU Lesser General Public
9  * License as published by the Free Software Foundation; either
10  * version 2.1 of the License, or (at your option) any later version.
11  *
12  * FFmpeg is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15  * Lesser General Public License for more details.
16  *
17  * You should have received a copy of the GNU Lesser General Public
18  * License along with FFmpeg; if not, write to the Free Software
19  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
20  */
21
22 /*
23  * These functions are scheduled for pca56. They should work
24  * reasonably on ev6, though.
25  */
26
27 #include "regdef.h"
28
29 /* Some nicer register names.  */
30 #define ta t10
31 #define tb t11
32 #define tc t12
33 #define td AT
34 /* Danger: these overlap with the argument list and the return value */
35 #define te a5
36 #define tf a4
37 #define tg a3
38 #define th v0
39
40         .set noat
41         .set noreorder
42         .arch pca56
43         .text
44
45 /************************************************************************
46  * void put_pixels_clamped_mvi_asm(const int16_t *block, uint8_t *pixels,
47  *                                 int line_size)
48  */
49         .align 6
50         .globl put_pixels_clamped_mvi_asm
51         .ent put_pixels_clamped_mvi_asm
52 put_pixels_clamped_mvi_asm:
53         .frame sp, 0, ra
54         .prologue 0
55
56         lda     t8, -1
57         lda     t9, 8           # loop counter
58         zap     t8, 0xaa, t8    # 00ff00ff00ff00ff
59
60         .align 4
61 1:      ldq     t0,  0(a0)
62         ldq     t1,  8(a0)
63         ldq     t2, 16(a0)
64         ldq     t3, 24(a0)
65
66         maxsw4  t0, zero, t0
67         subq    t9, 2, t9
68         maxsw4  t1, zero, t1
69         lda     a0, 32(a0)
70
71         maxsw4  t2, zero, t2
72         addq    a1, a2, ta
73         maxsw4  t3, zero, t3
74         minsw4  t0, t8, t0
75
76         minsw4  t1, t8, t1
77         minsw4  t2, t8, t2
78         minsw4  t3, t8, t3
79         pkwb    t0, t0
80
81         pkwb    t1, t1
82         pkwb    t2, t2
83         pkwb    t3, t3
84         stl     t0, 0(a1)
85
86         stl     t1, 4(a1)
87         addq    ta, a2, a1
88         stl     t2, 0(ta)
89         stl     t3, 4(ta)
90
91         bne     t9, 1b
92         ret
93         .end put_pixels_clamped_mvi_asm
94
95 /************************************************************************
96  * void add_pixels_clamped_mvi_asm(const int16_t *block, uint8_t *pixels,
97  *                                 int line_size)
98  */
99         .align 6
100         .globl add_pixels_clamped_mvi_asm
101         .ent add_pixels_clamped_mvi_asm
102 add_pixels_clamped_mvi_asm:
103         .frame sp, 0, ra
104         .prologue 0
105
106         lda     t1, -1
107         lda     th, 8
108         zap     t1, 0x33, tg
109         nop
110
111         srl     tg, 1, t0
112         xor     tg, t0, tg      # 0x8000800080008000
113         zap     t1, 0xaa, tf    # 0x00ff00ff00ff00ff
114
115         .align 4
116 1:      ldl     t1, 0(a1)       # pix0 (try to hit cache line soon)
117         ldl     t4, 4(a1)       # pix1
118         addq    a1, a2, te      # pixels += line_size
119         ldq     t0, 0(a0)       # shorts0
120
121         ldl     t7, 0(te)       # pix2 (try to hit cache line soon)
122         ldl     ta, 4(te)       # pix3
123         ldq     t3, 8(a0)       # shorts1
124         ldq     t6, 16(a0)      # shorts2
125
126         ldq     t9, 24(a0)      # shorts3
127         unpkbw  t1, t1          # 0 0 (quarter/op no.)
128         and     t0, tg, t2      # 0 1
129         unpkbw  t4, t4          # 1 0
130
131         bic     t0, tg, t0      # 0 2
132         unpkbw  t7, t7          # 2 0
133         and     t3, tg, t5      # 1 1
134         addq    t0, t1, t0      # 0 3
135
136         xor     t0, t2, t0      # 0 4
137         unpkbw  ta, ta          # 3 0
138         and     t6, tg, t8      # 2 1
139         maxsw4  t0, zero, t0    # 0 5
140
141         bic     t3, tg, t3      # 1 2
142         bic     t6, tg, t6      # 2 2
143         minsw4  t0, tf, t0      # 0 6
144         addq    t3, t4, t3      # 1 3
145
146         pkwb    t0, t0          # 0 7
147         xor     t3, t5, t3      # 1 4
148         maxsw4  t3, zero, t3    # 1 5
149         addq    t6, t7, t6      # 2 3
150
151         xor     t6, t8, t6      # 2 4
152         and     t9, tg, tb      # 3 1
153         minsw4  t3, tf, t3      # 1 6
154         bic     t9, tg, t9      # 3 2
155
156         maxsw4  t6, zero, t6    # 2 5
157         addq    t9, ta, t9      # 3 3
158         stl     t0, 0(a1)       # 0 8
159         minsw4  t6, tf, t6      # 2 6
160
161         xor     t9, tb, t9      # 3 4
162         maxsw4  t9, zero, t9    # 3 5
163         lda     a0, 32(a0)      # block += 16;
164         pkwb    t3, t3          # 1 7
165
166         minsw4  t9, tf, t9      # 3 6
167         subq    th, 2, th
168         pkwb    t6, t6          # 2 7
169         pkwb    t9, t9          # 3 7
170
171         stl     t3, 4(a1)       # 1 8
172         addq    te, a2, a1      # pixels += line_size
173         stl     t6, 0(te)       # 2 8
174         stl     t9, 4(te)       # 3 8
175
176         bne     th, 1b
177         ret
178         .end add_pixels_clamped_mvi_asm