vp9/x86: 8x8 iadst SIMD (ssse3/avx) variants.
[ffmpeg.git] / libavcodec / x86 / vp9itxfm.asm
1 ;******************************************************************************
2 ;* VP9 IDCT SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013 Clément Bœsch <u pkh me>
5 ;* Copyright (C) 2013 Ronald S. Bultje <rsbultje gmail com>
6 ;*
7 ;* This file is part of FFmpeg.
8 ;*
9 ;* FFmpeg is free software; you can redistribute it and/or
10 ;* modify it under the terms of the GNU Lesser General Public
11 ;* License as published by the Free Software Foundation; either
12 ;* version 2.1 of the License, or (at your option) any later version.
13 ;*
14 ;* FFmpeg is distributed in the hope that it will be useful,
15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;* Lesser General Public License for more details.
18 ;*
19 ;* You should have received a copy of the GNU Lesser General Public
20 ;* License along with FFmpeg; if not, write to the Free Software
21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
22 ;******************************************************************************
23
24 %include "libavutil/x86/x86util.asm"
25
26 SECTION_RODATA
27
28 pw_11585x2:  times 8 dw 23170
29 pw_m11585x2: times 8 dw -23170
30
31 %macro VP9_IDCT_COEFFS 2-3 0
32 pw_%1x2:    times 8 dw  %1*2
33 pw_m%1x2:   times 8 dw -%1*2
34 pw_%2x2:    times 8 dw  %2*2
35 pw_m%2x2:   times 8 dw -%2*2
36 pw_m%1_%2:  times 4 dw -%1,  %2
37 pw_%2_%1:   times 4 dw  %2,  %1
38 pw_m%2_m%1: times 4 dw -%2, -%1
39 %if %3 == 1
40 pw_m%2_%1:  times 4 dw -%2,  %1
41 pw_%1_%2:   times 4 dw  %1,  %2
42 %endif
43 %endmacro
44
45 VP9_IDCT_COEFFS 15137,  6270, 1
46 VP9_IDCT_COEFFS 16069,  3196, 1
47 VP9_IDCT_COEFFS  9102, 13623, 1
48 VP9_IDCT_COEFFS 16305,  1606
49 VP9_IDCT_COEFFS 10394, 12665
50 VP9_IDCT_COEFFS 14449,  7723
51 VP9_IDCT_COEFFS  4756, 15679
52 VP9_IDCT_COEFFS 16364,   804
53 VP9_IDCT_COEFFS 11003, 12140
54 VP9_IDCT_COEFFS 14811,  7005
55 VP9_IDCT_COEFFS  5520, 15426
56 VP9_IDCT_COEFFS 15893,  3981
57 VP9_IDCT_COEFFS  8423, 14053
58 VP9_IDCT_COEFFS 13160,  9760
59 VP9_IDCT_COEFFS  2404, 16207
60
61 pd_8192: times 4 dd 8192
62 pw_2048: times 8 dw 2048
63 pw_1024: times 8 dw 1024
64 pw_512:  times 8 dw 512
65 pw_m1:   times 8 dw -1
66
67 SECTION .text
68
69 ; (a*x + b*y + round) >> shift
70 %macro VP9_MULSUB_2W_2X 5 ; dst1, dst2/src, round, coefs1, coefs2
71     pmaddwd            m%1, m%2, %4
72     pmaddwd            m%2,  %5
73     paddd              m%1,  %3
74     paddd              m%2,  %3
75     psrad              m%1,  14
76     psrad              m%2,  14
77 %endmacro
78
79 %macro VP9_MULSUB_2W_4X 7 ; dst1, dst2, coef1, coef2, rnd, tmp1/src, tmp2
80     VP9_MULSUB_2W_2X    %7,  %6,  %5, [pw_m%3_%4], [pw_%4_%3]
81     VP9_MULSUB_2W_2X    %1,  %2,  %5, [pw_m%3_%4], [pw_%4_%3]
82     packssdw           m%1, m%7
83     packssdw           m%2, m%6
84 %endmacro
85
86 %macro VP9_UNPACK_MULSUB_2W_4X 7-9 ; dst1, dst2, (src1, src2,) coef1, coef2, rnd, tmp1, tmp2
87 %if %0 == 7
88     punpckhwd          m%6, m%2, m%1
89     punpcklwd          m%2, m%1
90     VP9_MULSUB_2W_4X   %1, %2, %3, %4, %5, %6, %7
91 %else
92     punpckhwd          m%8, m%4, m%3
93     punpcklwd          m%2, m%4, m%3
94     VP9_MULSUB_2W_4X   %1, %2, %5, %6, %7, %8, %9
95 %endif
96 %endmacro
97
98 %macro VP9_UNPACK_MULSUB_2D_4X 6 ; dst1 [src1], dst2 [src2], dst3, dst4, mul1, mul2
99     punpckhwd          m%4, m%2, m%1
100     punpcklwd          m%2, m%1
101     pmaddwd            m%3, m%4, [pw_m%5_%6]
102     pmaddwd            m%4, [pw_%6_%5]
103     pmaddwd            m%1, m%2, [pw_m%5_%6]
104     pmaddwd            m%2, [pw_%6_%5]
105 %endmacro
106
107 %macro VP9_RND_SH_SUMSUB_BA 6 ; dst1 [src1], dst2 [src2], src3, src4, tmp, round
108     SUMSUB_BA            d, %1, %2, %5
109     SUMSUB_BA            d, %3, %4, %5
110     paddd              m%1, %6
111     paddd              m%2, %6
112     paddd              m%3, %6
113     paddd              m%4, %6
114     psrad              m%1, 14
115     psrad              m%2, 14
116     psrad              m%3, 14
117     psrad              m%4, 14
118     packssdw           m%1, m%3
119     packssdw           m%2, m%4
120 %endmacro
121
122 %macro VP9_STORE_2X 5-6 dstq ; reg1, reg2, tmp1, tmp2, zero, dst
123     movh               m%3, [%6]
124     movh               m%4, [%6+strideq]
125     punpcklbw          m%3, m%5
126     punpcklbw          m%4, m%5
127     paddw              m%3, m%1
128     paddw              m%4, m%2
129     packuswb           m%3, m%5
130     packuswb           m%4, m%5
131     movh              [%6], m%3
132     movh      [%6+strideq], m%4
133 %endmacro
134
135 %macro ZERO_BLOCK 4 ; mem, stride, nnzcpl, zero_reg
136 %assign %%y 0
137 %rep %3
138 %assign %%x 0
139 %rep %3*2/mmsize
140     mova      [%1+%%y+%%x], %4
141 %assign %%x (%%x+mmsize)
142 %endrep
143 %assign %%y (%%y+%2)
144 %endrep
145 %endmacro
146
147 ;-------------------------------------------------------------------------------------------
148 ; void vp9_idct_idct_4x4_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
149 ;-------------------------------------------------------------------------------------------
150
151 %macro VP9_IDCT4_1D_FINALIZE 0
152     SUMSUB_BA            w, 3, 2, 4                         ; m3=t3+t0, m2=-t3+t0
153     SUMSUB_BA            w, 1, 0, 4                         ; m1=t2+t1, m0=-t2+t1
154     SWAP                 0, 3, 2                            ; 3102 -> 0123
155 %endmacro
156
157 %macro VP9_IDCT4_1D 0
158     SUMSUB_BA            w, 2, 0, 4                         ; m2=IN(0)+IN(2) m0=IN(0)-IN(2)
159     pmulhrsw            m2, m6                              ; m2=t0
160     pmulhrsw            m0, m6                              ; m0=t1
161     VP9_UNPACK_MULSUB_2W_4X 1, 3, 15137, 6270, m7, 4, 5     ; m1=t2, m3=t3
162     VP9_IDCT4_1D_FINALIZE
163 %endmacro
164
165 ; 2x2 top left corner
166 %macro VP9_IDCT4_2x2_1D 0
167     pmulhrsw            m0, m5                              ; m0=t1
168     mova                m2, m0                              ; m2=t0
169     mova                m3, m1
170     pmulhrsw            m1, m6                              ; m1=t2
171     pmulhrsw            m3, m7                              ; m3=t3
172     VP9_IDCT4_1D_FINALIZE
173 %endmacro
174
175 %macro VP9_IDCT4_WRITEOUT 0
176     mova                m5, [pw_2048]
177     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
178     pmulhrsw            m1, m5
179     VP9_STORE_2X         0,  1,  6,  7,  4
180     lea               dstq, [dstq+2*strideq]
181     pmulhrsw            m2, m5
182     pmulhrsw            m3, m5
183     VP9_STORE_2X         2,  3,  6,  7,  4
184 %endmacro
185
186 INIT_MMX ssse3
187 cglobal vp9_idct_idct_4x4_add, 4,4,0, dst, stride, block, eob
188
189     cmp eobd, 4 ; 2x2 or smaller
190     jg .idctfull
191
192     cmp eobd, 1 ; faster path for when only DC is set
193     jne .idct2x2
194
195     movd                m0, [blockq]
196     mova                m5, [pw_11585x2]
197     pmulhrsw            m0, m5
198     pmulhrsw            m0, m5
199     pshufw              m0, m0, 0
200     pxor                m4, m4
201     movh          [blockq], m4
202     pmulhrsw            m0, [pw_2048]       ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
203     VP9_STORE_2X         0,  0,  6,  7,  4
204     lea               dstq, [dstq+2*strideq]
205     VP9_STORE_2X         0,  0,  6,  7,  4
206     RET
207
208 ; faster path for when only top left 2x2 block is set
209 .idct2x2:
210     movd                m0, [blockq+0]
211     movd                m1, [blockq+8]
212     mova                m5, [pw_11585x2]
213     mova                m6, [pw_6270x2]
214     mova                m7, [pw_15137x2]
215     VP9_IDCT4_2x2_1D
216     TRANSPOSE4x4W  0, 1, 2, 3, 4
217     VP9_IDCT4_2x2_1D
218     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
219     movh       [blockq+ 0], m4
220     movh       [blockq+ 8], m4
221     VP9_IDCT4_WRITEOUT
222     RET
223
224 .idctfull: ; generic full 4x4 idct/idct
225     mova                m0, [blockq+ 0]
226     mova                m1, [blockq+ 8]
227     mova                m2, [blockq+16]
228     mova                m3, [blockq+24]
229     mova                m6, [pw_11585x2]
230     mova                m7, [pd_8192]       ; rounding
231     VP9_IDCT4_1D
232     TRANSPOSE4x4W  0, 1, 2, 3, 4
233     VP9_IDCT4_1D
234     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
235     mova       [blockq+ 0], m4
236     mova       [blockq+ 8], m4
237     mova       [blockq+16], m4
238     mova       [blockq+24], m4
239     VP9_IDCT4_WRITEOUT
240     RET
241
242 %if ARCH_X86_64 ; TODO: 32-bit? (32-bit limited to 8 xmm reg, we use more)
243
244 ;-------------------------------------------------------------------------------------------
245 ; void vp9_idct_idct_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
246 ;-------------------------------------------------------------------------------------------
247
248 %macro VP9_IDCT8_1D_FINALIZE 0
249     SUMSUB_BA            w,  3, 10, 4                       ;  m3=t0+t7, m10=t0-t7
250     SUMSUB_BA            w,  1,  2, 4                       ;  m1=t1+t6,  m2=t1-t6
251     SUMSUB_BA            w, 11,  0, 4                       ; m11=t2+t5,  m0=t2-t5
252     SUMSUB_BA            w,  9,  8, 4                       ;  m9=t3+t4,  m8=t3-t4
253     SWAP                11, 10, 2
254     SWAP                 3,  9, 0
255 %endmacro
256
257 %macro VP9_IDCT8_1D 0
258     SUMSUB_BA            w, 8, 0, 4                         ; m8=IN(0)+IN(4) m0=IN(0)-IN(4)
259     pmulhrsw            m8, m12                             ; m8=t0a
260     pmulhrsw            m0, m12                             ; m0=t1a
261     VP9_UNPACK_MULSUB_2W_4X 2, 10, 15137,  6270, m7, 4, 5   ; m2=t2a, m10=t3a
262     VP9_UNPACK_MULSUB_2W_4X 1, 11, 16069,  3196, m7, 4, 5   ; m1=t4a, m11=t7a
263     VP9_UNPACK_MULSUB_2W_4X 9,  3,  9102, 13623, m7, 4, 5   ; m9=t5a,  m3=t6a
264     SUMSUB_BA            w, 10,  8, 4                       ; m10=t0a+t3a (t0),  m8=t0a-t3a (t3)
265     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
266     SUMSUB_BA            w,  9,  1, 4                       ;  m9=t4a+t5a (t4),  m1=t4a-t5a (t5a)
267     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
268     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
269     pmulhrsw            m1, m12                             ; m1=t6
270     pmulhrsw           m11, m12                             ; m11=t5
271     VP9_IDCT8_1D_FINALIZE
272 %endmacro
273
274 %macro VP9_IDCT8_4x4_1D 0
275     pmulhrsw            m0, m12                             ; m0=t1a/t0a
276     pmulhrsw           m10, m2, [pw_15137x2]                ; m10=t3a
277     pmulhrsw            m2, [pw_6270x2]                     ; m2=t2a
278     pmulhrsw           m11, m1, [pw_16069x2]                ; m11=t7a
279     pmulhrsw            m1, [pw_3196x2]                     ; m1=t4a
280     pmulhrsw            m9, m3, [pw_9102x2]                 ; m9=-t5a
281     pmulhrsw            m3, [pw_13623x2]                    ; m3=t6a
282     psubw               m8, m0, m10                         ; m8=t0a-t3a (t3)
283     paddw              m10, m0                              ; m10=t0a+t3a (t0)
284     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
285     SUMSUB_BA            w,  9,  1, 4                       ;  m1=t4a+t5a (t4),  m9=t4a-t5a (t5a)
286     SWAP                 1,  9
287     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
288     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
289     pmulhrsw            m1, m12                             ; m1=t6
290     pmulhrsw           m11, m12                             ; m11=t5
291     VP9_IDCT8_1D_FINALIZE
292 %endmacro
293
294 ; TODO: a lot of t* copies can probably be removed and merged with
295 ; following SUMSUBs from VP9_IDCT8_1D_FINALIZE with AVX
296 %macro VP9_IDCT8_2x2_1D 0
297     pmulhrsw            m0, m12                             ;  m0=t0
298     mova                m3, m1
299     pmulhrsw            m1, m6                              ;  m1=t4
300     pmulhrsw            m3, m7                              ;  m3=t7
301     mova                m2, m0                              ;  m2=t1
302     mova               m10, m0                              ; m10=t2
303     mova                m8, m0                              ;  m8=t3
304     mova               m11, m3                              ; t5 = t7a ...
305     mova                m9, m3                              ; t6 = t7a ...
306     psubw              m11, m1                              ; t5 = t7a - t4a
307     paddw               m9, m1                              ; t6 = t7a + t4a
308     pmulhrsw           m11, m12                             ; m11=t5
309     pmulhrsw            m9, m12                             ;  m9=t6
310     SWAP                 0, 10
311     SWAP                 9,  1
312     VP9_IDCT8_1D_FINALIZE
313 %endmacro
314
315 %macro VP9_IDCT8_WRITEOUT 0
316     mova                m5, [pw_1024]
317     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
318     pmulhrsw            m1, m5
319     VP9_STORE_2X         0,  1,  6,  7,  4
320     lea               dstq, [dstq+2*strideq]
321     pmulhrsw            m2, m5
322     pmulhrsw            m3, m5
323     VP9_STORE_2X         2,  3,  6,  7,  4
324     lea               dstq, [dstq+2*strideq]
325     pmulhrsw            m8, m5
326     pmulhrsw            m9, m5
327     VP9_STORE_2X         8,  9,  6,  7,  4
328     lea               dstq, [dstq+2*strideq]
329     pmulhrsw           m10, m5
330     pmulhrsw           m11, m5
331     VP9_STORE_2X        10, 11,  6,  7,  4
332 %endmacro
333
334 %macro VP9_IDCT_IDCT_8x8_ADD_XMM 1
335 INIT_XMM %1
336 cglobal vp9_idct_idct_8x8_add, 4,4,13, dst, stride, block, eob
337
338     mova               m12, [pw_11585x2]    ; often used
339
340     cmp eobd, 12 ; top left half or less
341     jg .idctfull
342
343     cmp eobd, 3  ; top left corner or less
344     jg .idcthalf
345
346     cmp eobd, 1 ; faster path for when only DC is set
347     jne .idcttopleftcorner
348
349     movd                m0, [blockq]
350     pmulhrsw            m0, m12
351     pmulhrsw            m0, m12
352     SPLATW              m0, m0, 0
353     pxor                m4, m4
354     movd          [blockq], m4
355     mova                m5, [pw_1024]
356     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
357     VP9_STORE_2X         0,  0,  6,  7,  4
358     lea               dstq, [dstq+2*strideq]
359     VP9_STORE_2X         0,  0,  6,  7,  4
360     lea               dstq, [dstq+2*strideq]
361     VP9_STORE_2X         0,  0,  6,  7,  4
362     lea               dstq, [dstq+2*strideq]
363     VP9_STORE_2X         0,  0,  6,  7,  4
364     RET
365
366 ; faster path for when only left corner is set (3 input: DC, right to DC, below
367 ; to DC). Note: also working with a 2x2 block
368 .idcttopleftcorner:
369     movd                m0, [blockq+0]
370     movd                m1, [blockq+16]
371     mova                m6, [pw_3196x2]
372     mova                m7, [pw_16069x2]
373     VP9_IDCT8_2x2_1D
374     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
375     VP9_IDCT8_2x2_1D
376     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
377     movd       [blockq+ 0], m4
378     movd       [blockq+16], m4
379     VP9_IDCT8_WRITEOUT
380     RET
381
382 .idcthalf:
383     movh                m0, [blockq + 0]
384     movh                m1, [blockq +16]
385     movh                m2, [blockq +32]
386     movh                m3, [blockq +48]
387     VP9_IDCT8_4x4_1D
388     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
389     VP9_IDCT8_4x4_1D
390     pxor                m4, m4
391     movh       [blockq+ 0], m4
392     movh       [blockq+16], m4
393     movh       [blockq+32], m4
394     movh       [blockq+48], m4
395     VP9_IDCT8_WRITEOUT
396     RET
397
398 .idctfull: ; generic full 8x8 idct/idct
399     mova                m0, [blockq+  0]    ; IN(0)
400     mova                m1, [blockq+ 16]    ; IN(1)
401     mova                m2, [blockq+ 32]    ; IN(2)
402     mova                m3, [blockq+ 48]    ; IN(3)
403     mova                m8, [blockq+ 64]    ; IN(4)
404     mova                m9, [blockq+ 80]    ; IN(5)
405     mova               m10, [blockq+ 96]    ; IN(6)
406     mova               m11, [blockq+112]    ; IN(7)
407     mova                m7, [pd_8192]       ; rounding
408     VP9_IDCT8_1D
409     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
410     VP9_IDCT8_1D
411
412     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
413     ZERO_BLOCK      blockq, 16, 8, m4
414     VP9_IDCT8_WRITEOUT
415     RET
416 %endmacro
417
418 VP9_IDCT_IDCT_8x8_ADD_XMM ssse3
419 VP9_IDCT_IDCT_8x8_ADD_XMM avx
420
421 ;---------------------------------------------------------------------------------------------
422 ; void vp9_iadst_iadst_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
423 ;---------------------------------------------------------------------------------------------
424
425 %macro VP9_IADST8_1D 0 ; input/output=m0/1/2/3/8/9/10/11
426     VP9_UNPACK_MULSUB_2D_4X 11,  0,  4,  5, 16305,  1606    ; m11/4=t1[d], m0/5=t0[d]
427     VP9_UNPACK_MULSUB_2D_4X  3,  8,  6, 13, 10394, 12665    ; m3/6=t5[d], m8/13=t4[d]
428     VP9_RND_SH_SUMSUB_BA     8,  0, 13,  5, 14, m7          ; m8=t0[w], m0=t4[w]
429     VP9_RND_SH_SUMSUB_BA     3, 11,  6,  4, 14, m7          ; m3=t1[w], m11=t5[w]
430
431     VP9_UNPACK_MULSUB_2D_4X  9,  2,  4,  5, 14449,  7723    ; m9/4=t3[d], m2/5=t2[d]
432     VP9_UNPACK_MULSUB_2D_4X  1, 10,  6, 13,  4756, 15679    ; m1/6=t7[d], m10/13=t6[d]
433     VP9_RND_SH_SUMSUB_BA    10,  2, 13,  5, 14, m7          ; m10=t2[w], m2=t6[w]
434     VP9_RND_SH_SUMSUB_BA     1,  9,  6,  4, 14, m7          ; m1=t3[w], m9=t7[w]
435
436     ; m8=t0, m3=t1, m10=t2, m1=t3, m0=t4, m11=t5, m2=t6, m9=t7
437
438     VP9_UNPACK_MULSUB_2D_4X  0, 11,  4,  5, 15137,  6270    ; m0/4=t5[d], m11/5=t4[d]
439     VP9_UNPACK_MULSUB_2D_4X  9,  2,  6, 13,  6270, 15137    ; m9/6=t6[d], m2/13=t7[d]
440     VP9_RND_SH_SUMSUB_BA     9, 11,  6,  5, 14, m7
441     psignw                  m9, [pw_m1]                     ; m9=out1[w], m11=t6[w]
442     VP9_RND_SH_SUMSUB_BA     2,  0, 13,  4, 14, m7          ; m2=out6[w], m0=t7[w]
443
444     SUMSUB_BA                w, 10,  8, 14                  ; m10=out0[w], m8=t2[w]
445     SUMSUB_BA                w,  1,  3, 14
446     psignw                  m1, [pw_m1]                     ; m1=out7[w], m3=t3[w]
447
448     ; m10=out0, m9=out1, m8=t2, m3=t3, m11=t6, m0=t7, m2=out6, m1=out7
449
450     SUMSUB_BA                w,  3,  8,  4
451     SUMSUB_BA                w,  0, 11,  5
452     pmulhrsw                m3, m12
453     pmulhrsw               m11, m12
454     pmulhrsw                m8, m12                         ; out4
455     pmulhrsw                m0, m12                         ; out2
456     psignw                  m3, [pw_m1]                     ; out3
457     psignw                 m11, [pw_m1]                     ; out5
458
459     ; m10=out0, m9=out1, m0=out2, m3=out3, m8=out4, m11=out5, m2=out6, m1=out7
460
461     SWAP                     0, 10, 2
462     SWAP                    11,  1, 9
463 %endmacro
464
465 %macro IADST8_FN 5
466 INIT_XMM %5
467 cglobal vp9_%1_%3_8x8_add, 3, 3, 15, dst, stride, block, eob
468     mova                m0, [blockq+  0]    ; IN(0)
469     mova                m1, [blockq+ 16]    ; IN(1)
470     mova                m2, [blockq+ 32]    ; IN(2)
471     mova                m3, [blockq+ 48]    ; IN(3)
472     mova                m8, [blockq+ 64]    ; IN(4)
473     mova                m9, [blockq+ 80]    ; IN(5)
474     mova               m10, [blockq+ 96]    ; IN(6)
475     mova               m11, [blockq+112]    ; IN(7)
476
477     mova               m12, [pw_11585x2]    ; often used
478     mova                m7, [pd_8192]       ; rounding
479     VP9_%2_1D
480     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
481     VP9_%4_1D
482
483     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
484     ZERO_BLOCK      blockq, 16, 8, m4
485     VP9_IDCT8_WRITEOUT
486     RET
487 %endmacro
488
489 IADST8_FN idct,  IDCT8,  iadst, IADST8, ssse3
490 IADST8_FN idct,  IDCT8,  iadst, IADST8, avx
491 IADST8_FN iadst, IADST8, idct,  IDCT8,  ssse3
492 IADST8_FN iadst, IADST8, idct,  IDCT8,  avx
493 IADST8_FN iadst, IADST8, iadst, IADST8, ssse3
494 IADST8_FN iadst, IADST8, iadst, IADST8, avx
495
496 ;---------------------------------------------------------------------------------------------
497 ; void vp9_idct_idct_16x16_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
498 ;---------------------------------------------------------------------------------------------
499
500 ; at the end of this macro, m7 is stored in stack_scratch
501 ; everything else (t0-6 and t8-15) is stored in m0-6 and m8-15
502 ; the following sumsubs have not been done yet:
503 ;    SUMSUB_BA            w,  6,  9, 15      ; t6, t9
504 ;    SUMSUB_BA            w,  7,  8, 15      ; t7, t8
505 %macro VP9_IDCT16_1D_START 4 ; src, nnzc, stride, stack_scratch
506 %if %2 <= 4
507     mova                m3, [%1+ 1*%3]      ; IN(1)
508     mova               m12, [%1+ 2*%3]      ; IN(2)
509     mova                m0, [%1+ 3*%3]      ; IN(3)
510
511     pmulhrsw           m15, m12, [pw_16069x2]       ; t6-7
512     pmulhrsw           m12, [pw_3196x2]             ; t4-5
513     pmulhrsw            m4, m3,  [pw_16305x2]       ; t14-15
514     pmulhrsw            m3, [pw_1606x2]             ; t8-9
515     pmulhrsw            m7, m0,  [pw_m4756x2]       ; t10-11
516     pmulhrsw            m0, [pw_15679x2]            ; t12-13
517
518     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
519     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
520
521     paddw              m14, m15, m12
522     psubw              m13, m15, m12
523     pmulhrsw           m13, [pw_11585x2]            ; t5
524     pmulhrsw           m14, [pw_11585x2]            ; t6
525
526     VP9_UNPACK_MULSUB_2W_4X 2, 5, 4, 3, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
527     VP9_UNPACK_MULSUB_2W_4X 6, 1, 0, 7, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
528
529     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
530     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
531 %else
532     mova                m5, [%1+ 1*%3]     ; IN(1)
533     mova               m14, [%1+ 2*%3]     ; IN(2)
534     mova                m6, [%1+ 3*%3]     ; IN(3)
535     mova                m9, [%1+ 4*%3]     ; IN(4)
536     mova                m7, [%1+ 5*%3]     ; IN(5)
537     mova               m15, [%1+ 6*%3]     ; IN(6)
538     mova                m4, [%1+ 7*%3]     ; IN(7)
539 %if %2 <= 8
540     pmulhrsw            m8, m9,  [pw_15137x2]       ; t3
541     pmulhrsw            m9, [pw_6270x2]             ; t2
542     pmulhrsw           m13, m14, [pw_16069x2]       ; t7
543     pmulhrsw           m14, [pw_3196x2]             ; t4
544     pmulhrsw           m12, m15, [pw_m9102x2]       ; t5
545     pmulhrsw           m15, [pw_13623x2]            ; t6
546     pmulhrsw            m2, m5,  [pw_16305x2]       ; t15
547     pmulhrsw            m5, [pw_1606x2]             ; t8
548     pmulhrsw            m3, m4,  [pw_m10394x2]      ; t9
549     pmulhrsw            m4, [pw_12665x2]            ; t14
550     pmulhrsw            m0, m7,  [pw_14449x2]       ; t13
551     pmulhrsw            m7, [pw_7723x2]             ; t10
552     pmulhrsw            m1, m6,  [pw_m4756x2]       ; t11
553     pmulhrsw            m6, [pw_15679x2]            ; t12
554 %else
555     mova                m3, [%1+ 9*%3]     ; IN(9)
556     mova               m12, [%1+10*%3]     ; IN(10)
557     mova                m0, [%1+11*%3]     ; IN(11)
558     mova                m8, [%1+12*%3]     ; IN(12)
559     mova                m1, [%1+13*%3]     ; IN(13)
560     mova               m13, [%1+14*%3]     ; IN(14)
561     mova                m2, [%1+15*%3]     ; IN(15)
562
563     ; m10=in0, m5=in1, m14=in2, m6=in3, m9=in4, m7=in5, m15=in6, m4=in7
564     ; m11=in8, m3=in9, m12=in10 m0=in11, m8=in12, m1=in13, m13=in14, m2=in15
565
566     VP9_UNPACK_MULSUB_2W_4X   9,   8, 15137,  6270, [pd_8192], 10, 11 ; t2,  t3
567     VP9_UNPACK_MULSUB_2W_4X  14,  13, 16069,  3196, [pd_8192], 10, 11 ; t4,  t7
568     VP9_UNPACK_MULSUB_2W_4X  12,  15,  9102, 13623, [pd_8192], 10, 11 ; t5,  t6
569     VP9_UNPACK_MULSUB_2W_4X   5,   2, 16305,  1606, [pd_8192], 10, 11 ; t8,  t15
570     VP9_UNPACK_MULSUB_2W_4X   3,   4, 10394, 12665, [pd_8192], 10, 11 ; t9,  t14
571     VP9_UNPACK_MULSUB_2W_4X   7,   0, 14449,  7723, [pd_8192], 10, 11 ; t10, t13
572     VP9_UNPACK_MULSUB_2W_4X   1,   6,  4756, 15679, [pd_8192], 10, 11 ; t11, t12
573 %endif
574
575     ; m11=t0, m10=t1, m9=t2, m8=t3, m14=t4, m12=t5, m15=t6, m13=t7
576     ; m5=t8, m3=t9, m7=t10, m1=t11, m6=t12, m0=t13, m4=t14, m2=t15
577
578     SUMSUB_BA            w, 12, 14, 10      ; t4,  t5
579     SUMSUB_BA            w, 15, 13, 10      ; t7,  t6
580     SUMSUB_BA            w,  3,  5, 10      ; t8,  t9
581     SUMSUB_BA            w,  7,  1, 10      ; t11, t10
582     SUMSUB_BA            w,  0,  6, 10      ; t12, t13
583     SUMSUB_BA            w,  4,  2, 10      ; t15, t14
584
585     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
586     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
587
588     SUMSUB_BA            w, 14, 13, 10
589     pmulhrsw           m13, [pw_11585x2]                              ; t5
590     pmulhrsw           m14, [pw_11585x2]                              ; t6
591     VP9_UNPACK_MULSUB_2W_4X   2,   5, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
592     VP9_UNPACK_MULSUB_2W_4X   6,   1, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
593 %endif
594
595     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m13=t5, m14=t6, m15=t7
596     ; m3=t8, m2=t9, m6=t10, m7=t11, m0=t12, m1=t13, m5=t14, m4=t15
597
598     SUMSUB_BA            w,  7,  3, 10      ; t8,  t11
599     SUMSUB_BA            w,  6,  2, 10      ; t9,  t10
600     SUMSUB_BA            w,  0,  4, 10      ; t15, t12
601     SUMSUB_BA            w,  1,  5, 10      ; t14. t13
602
603     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
604     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
605
606     SUMSUB_BA            w,  2,  5, 10
607     SUMSUB_BA            w,  3,  4, 10
608     pmulhrsw            m5, [pw_11585x2]    ; t10
609     pmulhrsw            m4, [pw_11585x2]    ; t11
610     pmulhrsw            m3, [pw_11585x2]    ; t12
611     pmulhrsw            m2, [pw_11585x2]    ; t13
612
613     ; backup first register
614     mova              [%4], m7
615
616     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
617     ; m7=t8, m6=t9, m5=t10, m4=t11, m3=t12, m2=t13, m1=t14, m0=t15
618
619     ; from load/start
620 %if %2 <= 4
621     mova               m11, [%1+ 0*%3]      ; IN(0)
622     pmulhrsw           m11, [pw_11585x2]    ; t0-t3
623
624     psubw               m8, m11, m15
625     paddw              m15, m11
626     psubw               m9, m11, m14
627     paddw              m14, m11
628     psubw              m10, m11, m13
629     paddw              m13, m11
630 %else
631     mova               m10, [%1+ 0*%3]      ; IN(0)
632 %if %2 <= 8
633     pmulhrsw           m10, [pw_11585x2]    ; t0 and t1
634     psubw              m11, m10, m8
635     paddw               m8, m10
636 %else
637     mova               m11, [%1+ 8*%3]      ; IN(8)
638
639     ; from 3 stages back
640     SUMSUB_BA            w, 11, 10, 7
641     pmulhrsw           m11, [pw_11585x2]    ; t0
642     pmulhrsw           m10, [pw_11585x2]    ; t1
643
644     ; from 2 stages back
645     SUMSUB_BA            w,  8, 11, 7       ; t0,  t3
646 %endif
647     SUMSUB_BA            w,  9, 10, 7       ; t1,  t2
648
649     ; from 1 stage back
650     SUMSUB_BA            w, 15,  8, 7       ; t0,  t7
651     SUMSUB_BA            w, 14,  9, 7       ; t1,  t6
652     SUMSUB_BA            w, 13, 10, 7       ; t2,  t5
653 %endif
654     SUMSUB_BA            w, 12, 11, 7       ; t3,  t4
655
656     SUMSUB_BA            w,  0, 15, 7       ; t0, t15
657     SUMSUB_BA            w,  1, 14, 7       ; t1, t14
658     SUMSUB_BA            w,  2, 13, 7       ; t2, t13
659     SUMSUB_BA            w,  3, 12, 7       ; t3, t12
660     SUMSUB_BA            w,  4, 11, 7       ; t4, t11
661     SUMSUB_BA            w,  5, 10, 7       ; t5, t10
662 %endmacro
663
664 %macro VP9_IDCT16_1D 2-3 16 ; src, pass, nnzc
665     VP9_IDCT16_1D_START %1, %3, 32, rsp+32
666
667 %if %2 == 1
668     ; backup a different register
669     mova          [rsp+16], m15
670     mova                m7, [rsp+32]
671
672     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
673     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
674
675     TRANSPOSE8x8W        0, 1, 2, 3, 4, 5, 6, 7, 15
676     mova         [rsp+  0], m0
677     mova         [rsp+ 32], m1
678     mova         [rsp+ 64], m2
679     mova         [rsp+ 96], m3
680     mova         [rsp+128], m4
681     mova         [rsp+160], m5
682     mova         [rsp+192], m6
683     mova         [rsp+224], m7
684
685     mova               m15, [rsp+16]
686     TRANSPOSE8x8W        8, 9, 10, 11, 12, 13, 14, 15, 0
687     mova         [rsp+ 16], m8
688     mova         [rsp+ 48], m9
689     mova         [rsp+ 80], m10
690     mova         [rsp+112], m11
691     mova         [rsp+144], m12
692     mova         [rsp+176], m13
693     mova         [rsp+208], m14
694     mova         [rsp+240], m15
695 %else ; %2 == 2
696     ; backup more registers
697     mova          [rsp+64], m8
698     mova          [rsp+96], m9
699
700     pxor                m7, m7
701     pmulhrsw            m0, [pw_512]
702     pmulhrsw            m1, [pw_512]
703     VP9_STORE_2X         0,  1,  8,  9,  7
704     lea               dstq, [dstq+strideq*2]
705     pmulhrsw            m2, [pw_512]
706     pmulhrsw            m3, [pw_512]
707     VP9_STORE_2X         2,  3,  8,  9,  7
708     lea               dstq, [dstq+strideq*2]
709     pmulhrsw            m4, [pw_512]
710     pmulhrsw            m5, [pw_512]
711     VP9_STORE_2X         4,  5,  8,  9,  7
712     lea               dstq, [dstq+strideq*2]
713
714     ; restore from cache
715     SWAP                 0, 7               ; move zero from m7 to m0
716     mova                m7, [rsp+32]
717     mova                m8, [rsp+64]
718     mova                m9, [rsp+96]
719
720     SUMSUB_BA            w,  6,  9, 1       ; t6, t9
721     SUMSUB_BA            w,  7,  8, 1       ; t7, t8
722
723     pmulhrsw            m6, [pw_512]
724     pmulhrsw            m7, [pw_512]
725     VP9_STORE_2X         6,  7,  1,  2,  0
726     lea               dstq, [dstq+strideq*2]
727     pmulhrsw            m8, [pw_512]
728     pmulhrsw            m9, [pw_512]
729     VP9_STORE_2X         8,  9,  1,  2,  0
730     lea               dstq, [dstq+strideq*2]
731     pmulhrsw           m10, [pw_512]
732     pmulhrsw           m11, [pw_512]
733     VP9_STORE_2X        10, 11,  1,  2,  0
734     lea               dstq, [dstq+strideq*2]
735     pmulhrsw           m12, [pw_512]
736     pmulhrsw           m13, [pw_512]
737     VP9_STORE_2X        12, 13,  1,  2,  0
738     lea               dstq, [dstq+strideq*2]
739     pmulhrsw           m14, [pw_512]
740     pmulhrsw           m15, [pw_512]
741     VP9_STORE_2X        14, 15,  1,  2,  0
742 %endif ; %2 == 1/2
743 %endmacro
744
745 %macro VP9_STORE_2XFULL 6-7 strideq; dc, tmp1, tmp2, tmp3, tmp4, zero, stride
746     mova               m%3, [dstq]
747     mova               m%5, [dstq+%7]
748     punpcklbw          m%2, m%3, m%6
749     punpckhbw          m%3, m%6
750     punpcklbw          m%4, m%5, m%6
751     punpckhbw          m%5, m%6
752     paddw              m%2, m%1
753     paddw              m%3, m%1
754     paddw              m%4, m%1
755     paddw              m%5, m%1
756     packuswb           m%2, m%3
757     packuswb           m%4, m%5
758     mova            [dstq], m%2
759     mova         [dstq+%7], m%4
760 %endmacro
761
762 %macro VP9_IDCT_IDCT_16x16_ADD_XMM 1
763 INIT_XMM %1
764 cglobal vp9_idct_idct_16x16_add, 4, 5, 16, 512, dst, stride, block, eob
765     ; 2x2=eob=3, 4x4=eob=10
766     cmp eobd, 38
767     jg .idctfull
768     cmp eobd, 1 ; faster path for when only DC is set
769     jne .idct8x8
770
771     ; dc-only
772     movd                m0, [blockq]
773     mova                m1, [pw_11585x2]
774     pmulhrsw            m0, m1
775     pmulhrsw            m0, m1
776     SPLATW              m0, m0, q0000
777     pmulhrsw            m0, [pw_512]
778     pxor                m5, m5
779     movd          [blockq], m5
780 %rep 7
781     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
782     lea               dstq, [dstq+2*strideq]
783 %endrep
784     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
785     RET
786
787 .idct8x8:
788     DEFINE_ARGS dst, stride, block, cnt, dst_bak
789     VP9_IDCT16_1D   blockq, 1, 8
790
791     mov               cntd, 2
792     mov           dst_bakq, dstq
793 .loop2_8x8:
794     VP9_IDCT16_1D      rsp, 2, 8
795     lea               dstq, [dst_bakq+8]
796     add                rsp, 16
797     dec               cntd
798     jg .loop2_8x8
799     sub                rsp, 32
800
801     ; at the end of the loop, m0 should still be zero
802     ; use that to zero out block coefficients
803     ZERO_BLOCK      blockq, 32, 8, m0
804     RET
805
806 .idctfull:
807     DEFINE_ARGS dst, stride, block, cnt, dst_bak
808     mov               cntd, 2
809 .loop1_full:
810     VP9_IDCT16_1D   blockq, 1
811     add             blockq, 16
812     add                rsp, 256
813     dec               cntd
814     jg .loop1_full
815     sub             blockq, 32
816     sub                rsp, 512
817
818     mov               cntd, 2
819     mov           dst_bakq, dstq
820 .loop2_full:
821     VP9_IDCT16_1D      rsp, 2
822     lea               dstq, [dst_bakq+8]
823     add                rsp, 16
824     dec               cntd
825     jg .loop2_full
826     sub                rsp, 32
827
828     ; at the end of the loop, m0 should still be zero
829     ; use that to zero out block coefficients
830     ZERO_BLOCK      blockq, 32, 16, m0
831     RET
832 %endmacro
833
834 VP9_IDCT_IDCT_16x16_ADD_XMM ssse3
835 VP9_IDCT_IDCT_16x16_ADD_XMM avx
836
837 ;---------------------------------------------------------------------------------------------
838 ; void vp9_iadst_iadst_16x16_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
839 ;---------------------------------------------------------------------------------------------
840
841 %macro VP9_IADST16_1D 2 ; src, pass
842 %assign %%str 16*%2
843     mova                m0, [%1+ 0*32]  ; in0
844     mova                m1, [%1+15*32]  ; in15
845     mova                m8, [%1+ 7*32]  ; in7
846     mova                m9, [%1+ 8*32]  ; in8
847
848     VP9_UNPACK_MULSUB_2D_4X  1,  0,  2,  3, 16364,   804    ; m1/2=t1[d], m0/3=t0[d]
849     VP9_UNPACK_MULSUB_2D_4X  8,  9, 11, 10, 11003, 12140    ; m8/11=t9[d], m9/10=t8[d]
850     VP9_RND_SH_SUMSUB_BA     9,  0, 10,  3,  4, [pd_8192]   ; m9=t0[w], m0=t8[w]
851     VP9_RND_SH_SUMSUB_BA     8,  1, 11,  2,  4, [pd_8192]   ; m8=t1[w], m1=t9[w]
852
853     mova               m11, [%1+ 2*32]  ; in2
854     mova               m10, [%1+13*32]  ; in13
855     mova                m3, [%1+ 5*32]  ; in5
856     mova                m2, [%1+10*32]  ; in10
857
858     VP9_UNPACK_MULSUB_2D_4X 10, 11,  6,  7, 15893,  3981    ; m10/6=t3[d], m11/7=t2[d]
859     VP9_UNPACK_MULSUB_2D_4X  3,  2,  4,  5,  8423, 14053    ; m3/4=t11[d], m2/5=t10[d]
860     VP9_RND_SH_SUMSUB_BA     2, 11,  5,  7, 12, [pd_8192]   ; m2=t2[w], m11=t10[w]
861     VP9_RND_SH_SUMSUB_BA     3, 10,  4,  6, 12, [pd_8192]   ; m3=t3[w], m10=t11[w]
862
863     mova    [rsp+ 0*%%str], m9          ; make some scratch space (t0:m9->r0)
864     mova                m4, [%1+ 4*32]  ; in4
865     mova                m5, [%1+11*32]  ; in11
866     mova               m12, [%1+ 3*32]  ; in3
867     mova               m13, [%1+12*32]  ; in12
868
869     VP9_UNPACK_MULSUB_2D_4X  5,  4,  7,  6, 14811,  7005    ; m5/7=t5[d], m4/6=t4[d]
870     VP9_UNPACK_MULSUB_2D_4X 12, 13, 14, 15,  5520, 15426    ; m12/14=t13[d], m13/15=t12[d]
871     VP9_RND_SH_SUMSUB_BA    13,  4, 15,  6,  9, [pd_8192]   ; m13=t4[w], m4=t12[w]
872     VP9_RND_SH_SUMSUB_BA    12,  5, 14,  7,  9, [pd_8192]   ; m12=t5[w], m5=t13[w]
873
874     mova    [rsp+ 2*%%str], m8          ; t1:m9->r2
875     mova    [rsp+ 3*%%str], m2          ; t2:m2->r3
876     mova    [rsp+ 4*%%str], m3          ; t3:m3->r4
877     mova    [rsp+ 5*%%str], m13         ; t4:m13->r5
878     mova                m2, [%1+ 6*32]  ; in6
879     mova                m3, [%1+ 9*32]  ; in9
880     mova                m8, [%1+ 1*32]  ; in1
881     mova                m9, [%1+14*32]  ; in14
882
883     VP9_UNPACK_MULSUB_2D_4X  3,  2,  7,  6, 13160,  9760    ; m3/7=t7[d], m2/6=t6[d]
884     VP9_UNPACK_MULSUB_2D_4X  8,  9, 13, 14,  2404, 16207    ; m8/13=t15[d], m9/14=t14[d]
885     VP9_RND_SH_SUMSUB_BA     9,  2, 14,  6, 15, [pd_8192]   ; m9=t6[w], m2=t14[w]
886     VP9_RND_SH_SUMSUB_BA     8,  3, 13,  7, 15, [pd_8192]   ; m8=t7[w], m3=t15[w]
887
888     ; r0=t0, r2=t1, r3=t2, r4=t3, r5=t4, m12=t5, m9=t6, m8=t7
889     ; m0=t8, m1=t9, m11=t10, m10=t11, m4=t12, m5=t13, m2=t14, m3=t15
890
891     ; handle t8-15 first
892     VP9_UNPACK_MULSUB_2D_4X  0,  1,  6,  7, 16069,  3196    ; m1/7=t8[d], m0/6=t9[d]
893     VP9_UNPACK_MULSUB_2D_4X  5,  4, 13, 14,  3196, 16069    ; m5/13=t12[d], m4/14=t13[d]
894     VP9_RND_SH_SUMSUB_BA     5,  1, 13,  7, 15, [pd_8192]   ; m5=t8[w], m1=t12[w]
895     VP9_RND_SH_SUMSUB_BA     4,  0, 14,  6, 15, [pd_8192]   ; m4=t9[w], m0=t13[w]
896
897     VP9_UNPACK_MULSUB_2D_4X 11, 10,  6,  7,  9102, 13623    ; m11/6=t11[d], m10/7=t10[d]
898     VP9_UNPACK_MULSUB_2D_4X  3,  2, 13, 14, 13623,  9102    ; m3/13=t14[d], m2/14=t15[d]
899     VP9_RND_SH_SUMSUB_BA     3, 10, 13,  7, 15, [pd_8192]   ; m3=t10[w], m10=t14[w]
900     VP9_RND_SH_SUMSUB_BA     2, 11, 14,  6, 15, [pd_8192]   ; m2=t11[w], m11=t15[w]
901
902     ; m5=t8, m4=t9, m3=t10, m2=t11, m1=t12, m0=t13, m10=t14, m11=t15
903
904     VP9_UNPACK_MULSUB_2D_4X  1,  0,  6,  7, 15137,  6270    ; m1/6=t13[d], m0/7=t12[d]
905     VP9_UNPACK_MULSUB_2D_4X 11, 10, 13, 14,  6270, 15137    ; m11/13=t14[d], m10/14=t15[d]
906     VP9_RND_SH_SUMSUB_BA    11,  0, 13,  7, 15, [pd_8192]   ; m11=out2[w], m0=t14[w]
907     VP9_RND_SH_SUMSUB_BA    10,  1, 14,  6, 15, [pd_8192]
908     psignw                 m10, [pw_m1]                     ; m10=out13[w], m1=t15[w]
909
910     SUMSUB_BA                w,  3,  5, 15
911     psignw                  m3, [pw_m1]                     ; m3=out1[w], m5=t10[w]
912     SUMSUB_BA                w,  2,  4, 15                  ; m2=out14[w], m4=t11[w]
913
914     SUMSUB_BA                w,  5,  4, 15
915     pmulhrsw                m5, [pw_11585x2]                ; m5=out6[w]
916     pmulhrsw                m4, [pw_11585x2]                ; m4=out9[w]
917     SUMSUB_BA                w,  1,  0, 15
918     pmulhrsw                m1, [pw_m11585x2]               ; m1=out5[w]
919     pmulhrsw                m0, [pw_11585x2]                ; m0=out10[w]
920
921     ; m3=out1, m11=out2, m1=out5, m5=out6, m4=out9, m0=out10, m10=out13, m2=out14
922
923     mova                    m6, [rsp+ 0*%%str]
924     mova                    m7, [rsp+ 2*%%str]
925     mova                   m13, [rsp+ 3*%%str]
926     mova                   m14, [rsp+ 4*%%str]
927     mova                   m15, [rsp+ 5*%%str]
928     mova        [rsp+ 8*%%str], m5
929     mova        [rsp+ 9*%%str], m4
930     mova        [rsp+10*%%str], m0
931     mova        [rsp+11*%%str], m10
932     mova        [rsp+12*%%str], m2
933
934     ; m6=t0, m7=t1, m13=t2, m14=t3, m15=t4, m12=t5, m9=t6, m8=t7
935     ; m3=out1, m11=out2, m1=out5, r8=out6, r9=out9, r10=out10, r11=out13, r12=out14
936
937     SUMSUB_BA                w, 15,  6,  0                  ; m15=t0[w], m6=t4[w]
938     SUMSUB_BA                w, 12,  7,  0                  ; m12=t1[w], m7=t5[w]
939     SUMSUB_BA                w,  9, 13,  0                  ; m9=t2[w], m13=t6[w]
940     SUMSUB_BA                w,  8, 14,  0                  ; m8=t3[w], m14=t7[w]
941
942     VP9_UNPACK_MULSUB_2D_4X  6,  7,  0,  2, 15137,  6270    ; m6/0=t5[d], m7/2=t4[d]
943     VP9_UNPACK_MULSUB_2D_4X 14, 13,  4,  5,  6270, 15137    ; m14/4=t6[d], m13/5=t7[d]
944     VP9_RND_SH_SUMSUB_BA    14,  7,  4,  2, 10, [pd_8192]
945     psignw                 m14, [pw_m1]                     ; m14=out3[w], m7=t6[w]
946     VP9_RND_SH_SUMSUB_BA    13,  6,  5,  0, 10, [pd_8192]   ; m13=out12[w], m6=t7[w]
947     SUMSUB_BA                w,  9, 15, 10                  ; m9=out0[w], m15=t2[w]
948     SUMSUB_BA                w,  8, 12, 10
949     psignw                  m8, [pw_m1]                     ; m8=out15[w], m12=t3[w]
950
951     SUMSUB_BA                w, 12, 15, 10
952     pmulhrsw               m12, [pw_m11585x2]               ; m12=out7[w]
953     pmulhrsw               m15, [pw_11585x2]                ; m15=out8[w]
954     SUMSUB_BA                w,  7,  6, 10
955     pmulhrsw                m7, [pw_11585x2]                ; m7=out4[w]
956     pmulhrsw                m6, [pw_11585x2]                ; m6=out11[w]
957
958     ; m9=out0, m14=out3, m7=out4, m12=out7, m15=out8, m6=out11, m13=out12, m8=out15
959     ; m3=out1, m11=out2, m1=out5, r8=out6, r9=out9, r10=out10, r11=out13, r12=out14
960
961 %if %2 == 1
962     mova                    m0, [rsp+ 8*%%str]
963     TRANSPOSE8x8W            9, 3, 11, 14, 7, 1, 0, 12, 2
964     mova           [rsp+ 0*16], m9
965     mova           [rsp+ 2*16], m3
966     mova           [rsp+ 4*16], m11
967     mova           [rsp+ 6*16], m14
968     mova                    m9, [rsp+ 9*%%str]
969     mova                    m3, [rsp+10*%%str]
970     mova                   m11, [rsp+11*%%str]
971     mova                   m14, [rsp+12*%%str]
972     mova           [rsp+ 8*16], m7
973     mova           [rsp+10*16], m1
974     mova           [rsp+12*16], m0
975     mova           [rsp+14*16], m12
976
977     TRANSPOSE8x8W           15, 9, 3, 6, 13, 11, 14, 8, 2
978     mova           [rsp+ 1*16], m15
979     mova           [rsp+ 3*16], m9
980     mova           [rsp+ 5*16], m3
981     mova           [rsp+ 7*16], m6
982     mova           [rsp+ 9*16], m13
983     mova           [rsp+11*16], m11
984     mova           [rsp+13*16], m14
985     mova           [rsp+15*16], m8
986 %else
987     mova                    m5, [rsp+ 8*%%str]
988     pxor                    m0, m0
989
990     pmulhrsw                m9, [pw_512]
991     pmulhrsw                m3, [pw_512]
992     VP9_STORE_2X             9,  3, 2, 4, 0
993     lea                   dstq, [dstq+strideq*2]
994     pmulhrsw               m11, [pw_512]
995     pmulhrsw               m14, [pw_512]
996     VP9_STORE_2X            11, 14, 2, 4, 0
997     lea                   dstq, [dstq+strideq*2]
998     pmulhrsw                m7, [pw_512]
999     pmulhrsw                m1, [pw_512]
1000     VP9_STORE_2X             7,  1, 2, 4, 0
1001     lea                   dstq, [dstq+strideq*2]
1002     pmulhrsw                m5, [pw_512]
1003     pmulhrsw               m12, [pw_512]
1004     VP9_STORE_2X             5, 12, 2, 4, 0
1005     lea                   dstq, [dstq+strideq*2]
1006
1007     mova                    m9, [rsp+ 9*%%str]
1008     mova                    m3, [rsp+10*%%str]
1009     mova                   m11, [rsp+11*%%str]
1010     mova                   m14, [rsp+12*%%str]
1011
1012     pmulhrsw               m15, [pw_512]
1013     pmulhrsw                m9, [pw_512]
1014     VP9_STORE_2X            15,  9, 2, 4, 0
1015     lea                   dstq, [dstq+strideq*2]
1016     pmulhrsw                m3, [pw_512]
1017     pmulhrsw                m6, [pw_512]
1018     VP9_STORE_2X             3,  6, 2, 4, 0
1019     lea                   dstq, [dstq+strideq*2]
1020     pmulhrsw               m13, [pw_512]
1021     pmulhrsw               m11, [pw_512]
1022     VP9_STORE_2X            13, 11, 2, 4, 0
1023     lea                   dstq, [dstq+strideq*2]
1024     pmulhrsw               m14, [pw_512]
1025     pmulhrsw                m8, [pw_512]
1026     VP9_STORE_2X            14,  8, 2, 4, 0
1027 %endif
1028 %endmacro
1029
1030 %macro IADST16_FN 5
1031 INIT_XMM %5
1032 cglobal vp9_%1_%3_16x16_add, 3, 5, 16, 512, dst, stride, block, eob
1033     ; potential eob checks go here
1034
1035     DEFINE_ARGS dst, stride, block, cnt, dst_bak
1036     mov               cntd, 2
1037 .loop1_full:
1038     VP9_%2_1D       blockq, 1
1039     add             blockq, 16
1040     add                rsp, 256
1041     dec               cntd
1042     jg .loop1_full
1043     sub             blockq, 32
1044     sub                rsp, 512
1045
1046     mov               cntd, 2
1047     mov           dst_bakq, dstq
1048 .loop2_full:
1049     VP9_%4_1D          rsp, 2
1050     lea               dstq, [dst_bakq+8]
1051     add                rsp, 16
1052     dec               cntd
1053     jg .loop2_full
1054     sub                rsp, 32
1055
1056     ; at the end of the loop, m0 should still be zero
1057     ; use that to zero out block coefficients
1058     ZERO_BLOCK      blockq, 32, 16, m0
1059     RET
1060 %endmacro
1061
1062 IADST16_FN idct,  IDCT16,  iadst, IADST16, ssse3
1063 IADST16_FN idct,  IDCT16,  iadst, IADST16, avx
1064 IADST16_FN iadst, IADST16, idct,  IDCT16,  ssse3
1065 IADST16_FN iadst, IADST16, idct,  IDCT16,  avx
1066 IADST16_FN iadst, IADST16, iadst, IADST16, ssse3
1067 IADST16_FN iadst, IADST16, iadst, IADST16, avx
1068
1069 ;---------------------------------------------------------------------------------------------
1070 ; void vp9_idct_idct_32x32_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
1071 ;---------------------------------------------------------------------------------------------
1072
1073 %macro VP9_IDCT32_1D 2-3 32 ; src, pass, nnzc
1074 %assign %%str 16*%2*%2
1075     ; first do t0-15, this can be done identical to idct16x16
1076     VP9_IDCT16_1D_START %1, %3/2, 64*2, rsp+ 4*%%str
1077
1078     ; backup a different register
1079     mova     [rsp+30*%%str], m15    ; t15
1080     mova                m7, [rsp+ 4*%%str]
1081
1082     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
1083     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
1084
1085     ; store everything on stack to make space available for t16-31
1086     ; we store interleaved with the output of the second half (t16-31)
1087     ; so we don't need to allocate extra stack space
1088     mova     [rsp+ 0*%%str], m0     ; t0
1089     mova     [rsp+ 4*%%str], m1     ; t1
1090     mova     [rsp+ 8*%%str], m2     ; t2
1091     mova     [rsp+12*%%str], m3     ; t3
1092     mova     [rsp+16*%%str], m4     ; t4
1093     mova     [rsp+20*%%str], m5     ; t5
1094     mova     [rsp+24*%%str], m6     ; t6
1095     mova     [rsp+28*%%str], m7     ; t7
1096     mova     [rsp+ 2*%%str], m8     ; t8
1097     mova     [rsp+ 6*%%str], m9     ; t9
1098     mova     [rsp+10*%%str], m10    ; t10
1099     mova     [rsp+14*%%str], m11    ; t11
1100     mova     [rsp+18*%%str], m12    ; t12
1101     mova     [rsp+22*%%str], m13    ; t13
1102     mova     [rsp+26*%%str], m14    ; t14
1103
1104     ; then, secondly, do t16-31
1105 %if %3 <= 8
1106     mova                 m4, [%1+ 1*64]
1107     mova                 m3, [%1+ 3*64]
1108     mova                 m0, [%1+ 5*64]
1109     mova                 m7, [%1+ 7*64]
1110
1111     pmulhrsw            m11,  m4, [pw_16364x2] ;t31
1112     pmulhrsw             m4, [pw_804x2] ;t16
1113     pmulhrsw             m8,  m7, [pw_m5520x2] ;t19
1114     pmulhrsw             m7, [pw_15426x2] ;t28
1115     pmulhrsw            m15,  m0, [pw_15893x2] ;t27
1116     pmulhrsw             m0, [pw_3981x2] ;t20
1117     pmulhrsw            m12,  m3, [pw_m2404x2] ;t23
1118     pmulhrsw             m3, [pw_16207x2] ;t24
1119
1120     ; m4=t16/17, m8=t18/19, m0=t20/21, m12=t22/23,
1121     ; m3=t24/25, m15=t26/27, m7=t28/29, m11=t30/31
1122
1123     VP9_UNPACK_MULSUB_2W_4X   5, 10, 11,  4, 16069,  3196, [pd_8192], 6,  9 ; t17, t30
1124     VP9_UNPACK_MULSUB_2W_4X   9,  6,  7,  8, 3196, m16069, [pd_8192], 1, 14 ; t18, t29
1125     ; from 1 stage forward
1126     SUMSUB_BA                 w,  8,  4,  1
1127     ; temporary storage
1128     mova     [rsp+17*%%str], m8             ; t16
1129     mova     [rsp+21*%%str], m4             ; t19
1130     VP9_UNPACK_MULSUB_2W_4X   1, 14, 15,  0,  9102, 13623, [pd_8192], 4,  8 ; t21, t26
1131     VP9_UNPACK_MULSUB_2W_4X  13,  2,  3, 12, 13623, m9102, [pd_8192], 4,  8 ; t22, t25
1132
1133     ; m4=t16, m5=t17, m9=t18, m8=t19, m0=t20, m1=t21, m13=t22, m12=t23,
1134     ; m3=t24, m2=t25, m14=t26, m15=t27, m7=t28, m6=t29, m10=t30, m11=t31
1135 %else
1136     mova                m10, [%1+ 1*64]
1137     mova                m13, [%1+ 3*64]
1138     mova                m14, [%1+ 5*64]
1139     mova                 m9, [%1+ 7*64]
1140     mova                 m8, [%1+ 9*64]
1141     mova                m15, [%1+11*64]
1142     mova                m12, [%1+13*64]
1143     mova                m11, [%1+15*64]
1144 %if %3 <= 16
1145     pmulhrsw             m5, m10, [pw_16364x2]
1146     pmulhrsw            m10, [pw_804x2]
1147     pmulhrsw             m4, m11, [pw_m11003x2]
1148     pmulhrsw            m11, [pw_12140x2]
1149     pmulhrsw             m7,  m8, [pw_14811x2]
1150     pmulhrsw             m8, [pw_7005x2]
1151     pmulhrsw             m6,  m9, [pw_m5520x2]
1152     pmulhrsw             m9, [pw_15426x2]
1153     pmulhrsw             m1, m14, [pw_15893x2]
1154     pmulhrsw            m14, [pw_3981x2]
1155     pmulhrsw             m0, m15, [pw_m8423x2]
1156     pmulhrsw            m15, [pw_14053x2]
1157 %else
1158     mova                 m4, [%1+17*64]
1159     mova                 m0, [%1+21*64]
1160     mova                 m7, [%1+23*64]
1161     mova                 m6, [%1+25*64]
1162     mova                 m1, [%1+27*64]
1163     mova                 m5, [%1+31*64]
1164
1165     ; m10=in1, m4=in17, m8=in9, m6=in25, m14=in5, m0=in21, m12=in13, m2=in29,
1166     ; m13=in3, m3=in19, m15=in11, m1=in27, m9=in7, m7=in23, m11=in15, m5=in31
1167
1168     VP9_UNPACK_MULSUB_2W_4X  10,  5, 16364,   804, [pd_8192], 2, 3 ; t16, t31
1169     VP9_UNPACK_MULSUB_2W_4X   4, 11, 11003, 12140, [pd_8192], 2, 3 ; t17, t30
1170     VP9_UNPACK_MULSUB_2W_4X   8,  7, 14811,  7005, [pd_8192], 2, 3 ; t18, t29
1171     VP9_UNPACK_MULSUB_2W_4X   6,  9,  5520, 15426, [pd_8192], 2, 3 ; t19, t28
1172     VP9_UNPACK_MULSUB_2W_4X  14,  1, 15893,  3981, [pd_8192], 2, 3 ; t20, t27
1173     VP9_UNPACK_MULSUB_2W_4X   0, 15,  8423, 14053, [pd_8192], 2, 3 ; t21, t26
1174 %endif
1175
1176     ; from 1 stage forward
1177     SUMSUB_BA             w,  4, 10,  2
1178     SUMSUB_BA             w,  8,  6,  2
1179     ; from 2 stages forward
1180     SUMSUB_BA             w,  8,  4,  2
1181     ; temporary storage
1182     mova     [rsp+17*%%str], m8             ; t16
1183     mova     [rsp+21*%%str], m4             ; t19
1184 %if %3 <= 16
1185     pmulhrsw             m3, m12, [pw_13160x2]
1186     pmulhrsw            m12, [pw_9760x2]
1187     pmulhrsw             m2, m13, [pw_m2404x2]
1188     pmulhrsw            m13, [pw_16207x2]
1189 %else
1190     mova                 m2, [%1+29*64]
1191     mova                 m3, [%1+19*64]
1192     VP9_UNPACK_MULSUB_2W_4X  12,  3, 13160,  9760, [pd_8192], 4, 8 ; t22, t25
1193     VP9_UNPACK_MULSUB_2W_4X   2, 13,  2404, 16207, [pd_8192], 4, 8 ; t23, t24
1194 %endif
1195
1196     ; m10=t16, m4=t17, m8=t18, m6=t19, m14=t20, m0=t21, m12=t22, m2=t23,
1197     ; m13=t24, m3=t25, m15=t26, m1=t27, m9=t28, m7=t29, m11=t30, m5=t31
1198
1199     SUMSUB_BA             w,  0, 14,  4
1200     SUMSUB_BA             w, 12,  2,  4
1201     SUMSUB_BA             w,  3, 13,  4
1202     SUMSUB_BA             w, 15,  1,  4
1203     SUMSUB_BA             w,  7,  9,  4
1204     SUMSUB_BA             w, 11,  5,  4
1205
1206     ; m4=t16, m10=t17, m6=t18, m8=t19, m0=t20, m14=t21, m2=t22, m12=t23,
1207     ; m3=t24, m13=t25, m1=t26, m15=t27, m7=t28, m9=t29, m5=t30, m11=t31
1208
1209     VP9_UNPACK_MULSUB_2W_4X   5, 10, 16069,  3196, [pd_8192], 4, 8 ; t17, t30
1210     VP9_UNPACK_MULSUB_2W_4X   9,  6, 3196, m16069, [pd_8192], 4, 8 ; t18, t29
1211     VP9_UNPACK_MULSUB_2W_4X   1, 14,  9102, 13623, [pd_8192], 4, 8 ; t21, t26
1212     VP9_UNPACK_MULSUB_2W_4X  13,  2, 13623, m9102, [pd_8192], 4, 8 ; t22, t25
1213 %endif
1214
1215     ; m4=t16, m5=t17, m9=t18, m8=t19, m0=t20, m1=t21, m13=t22, m12=t23,
1216     ; m3=t24, m2=t25, m14=t26, m15=t27, m7=t28, m6=t29, m10=t30, m11=t31
1217
1218     SUMSUB_BA             w,  9,  5,  4
1219     SUMSUB_BA             w,  1, 13,  4
1220     SUMSUB_BA             w,  0, 12,  4
1221     SUMSUB_BA             w, 15,  3,  4
1222     SUMSUB_BA             w, 14,  2,  4
1223     SUMSUB_BA             w,  6, 10,  4
1224     SUMSUB_BA             w,  7, 11,  4
1225
1226     ; m8[s]=t16, m9=t17, m5=t18, m4[s]=t19, m12=t20, m13=t21, m1=t22, m0=t23,
1227     ; m15=t24, m14=t25, m2=t26, m3=t27, m11=t28, m10=t29, m6=t30, m7=t31
1228
1229     mova                 m8, [rsp+17*%%str] ; t16
1230     ; from 2 stages forward
1231     SUMSUB_BA             w,  0,  8,  4
1232     SUMSUB_BA             w, 15,  7,  4
1233     ; from 3 stages forward
1234     SUMSUB_BA             w,  8,  7,  4
1235     pmulhrsw             m7, [pw_11585x2]
1236     pmulhrsw             m8, [pw_11585x2]
1237     ; store t16/t23
1238     mova     [rsp+ 1*%%str], m0     ; t16
1239     mova     [rsp+29*%%str], m7     ; t23
1240
1241     mova                 m4, [rsp+21*%%str] ; t19
1242     VP9_UNPACK_MULSUB_2W_4X  10,  5, 15137,  6270, [pd_8192], 0, 7 ; t18, t29
1243     VP9_UNPACK_MULSUB_2W_4X  11,  4, 15137,  6270, [pd_8192], 0, 7 ; t19, t28
1244     VP9_UNPACK_MULSUB_2W_4X   3, 12, 6270, m15137, [pd_8192], 0, 7 ; t20, t27
1245     VP9_UNPACK_MULSUB_2W_4X   2, 13, 6270, m15137, [pd_8192], 0, 7 ; t21, t26
1246
1247     ; m8=t16, m9=t17, m10=t18, m11=t19, m3=t20, m2=t21, m1=t22, m0=t23,
1248     ; m15=t24, m14=t25, m13=t26, m12=t27, m4=t28, m5=t29, m6=t30, m7=t31
1249
1250     SUMSUB_BA             w,  1,  9,  0
1251     SUMSUB_BA             w,  2, 10,  0
1252     SUMSUB_BA             w,  3, 11,  0
1253     SUMSUB_BA             w, 12,  4,  0
1254     SUMSUB_BA             w, 13,  5,  0
1255     SUMSUB_BA             w, 14,  6,  0
1256
1257     ; m0=t16, m1=t17, m2=t18, m3=t19, m11=t20, m10=t21, m9=t22, m8=t23,
1258     ; m7=t24, m6=t25, m5=t26, m4=t27, m12=t28, m13=t29, m14=t30, m15=t31
1259
1260     SUMSUB_BA             w,  9,  6,  0
1261     SUMSUB_BA             w, 10,  5,  0
1262     SUMSUB_BA             w, 11,  4,  0
1263
1264     pmulhrsw             m6, [pw_11585x2]
1265     pmulhrsw             m9, [pw_11585x2]
1266     pmulhrsw             m5, [pw_11585x2]
1267     pmulhrsw            m10, [pw_11585x2]
1268     pmulhrsw             m4, [pw_11585x2]
1269     pmulhrsw            m11, [pw_11585x2]
1270
1271     ; m0=t16, m1=t17, m2=t18, m3=t19, m4=t20, m5=t21, m6=t22, m7=t23,
1272     ; m8=t24, m9=t25, m10=t26, m11=t27, m12=t28, m13=t29, m14=t30, m15=t31
1273
1274     ; store t17-19 (and t20-22 for pass 1) - keep t24-31 in registers for
1275     ; final sumsub in pass 1, or keep t20-22 and t24-31 in registers for
1276     ; final sumsub of pass 2
1277     mova     [rsp+ 5*%%str], m1     ; t17
1278     mova     [rsp+ 9*%%str], m2     ; t18
1279     mova     [rsp+13*%%str], m3     ; t19
1280
1281     ; then do final pass to sumsub+store the two halves
1282 %if %2 == 1
1283     mova     [rsp+17*%%str], m4     ; t20
1284     mova     [rsp+21*%%str], m5     ; t21
1285     mova     [rsp+25*%%str], m6     ; t22
1286
1287     mova                 m0, [rsp+ 0*%%str] ; t0
1288     mova                 m1, [rsp+ 4*%%str] ; t1
1289     mova                 m2, [rsp+ 8*%%str] ; t2
1290     mova                 m3, [rsp+12*%%str] ; t3
1291     mova                 m4, [rsp+16*%%str] ; t4
1292     mova                 m5, [rsp+20*%%str] ; t5
1293     mova                 m6, [rsp+24*%%str] ; t6
1294
1295     SUMSUB_BA             w, 15,  0, 7
1296     mova     [rsp+ 3*%%str], m0             ; t15
1297     mova                 m7, [rsp+28*%%str] ; t7
1298     SUMSUB_BA             w, 14,  1, 0
1299     SUMSUB_BA             w, 13,  2, 0
1300     SUMSUB_BA             w, 12,  3, 0
1301     SUMSUB_BA             w, 11,  4, 0
1302     SUMSUB_BA             w, 10,  5, 0
1303     SUMSUB_BA             w,  9,  6, 0
1304     SUMSUB_BA             w,  8,  7, 0
1305
1306     TRANSPOSE8x8W        15, 14, 13, 12, 11, 10, 9, 8, 0
1307     mova     [rsp+ 0*%%str], m15
1308     mova     [rsp+ 4*%%str], m14
1309     mova     [rsp+ 8*%%str], m13
1310     mova     [rsp+12*%%str], m12
1311     mova     [rsp+16*%%str], m11
1312     mova     [rsp+20*%%str], m10
1313     mova     [rsp+24*%%str], m9
1314     mova     [rsp+28*%%str], m8
1315
1316     mova                  m0, [rsp+ 3*%%str] ; t15
1317     TRANSPOSE8x8W          7, 6, 5, 4, 3, 2, 1, 0, 8
1318     mova     [rsp+ 3*%%str], m7
1319     mova     [rsp+ 7*%%str], m6
1320     mova     [rsp+11*%%str], m5
1321     mova     [rsp+15*%%str], m4
1322     mova     [rsp+19*%%str], m3
1323     mova     [rsp+23*%%str], m2
1324     mova     [rsp+27*%%str], m1
1325     mova     [rsp+31*%%str], m0
1326
1327     mova                m15, [rsp+ 2*%%str] ; t8
1328     mova                m14, [rsp+ 6*%%str] ; t9
1329     mova                m13, [rsp+10*%%str] ; t10
1330     mova                m12, [rsp+14*%%str] ; t11
1331     mova                m11, [rsp+18*%%str] ; t12
1332     mova                m10, [rsp+22*%%str] ; t13
1333     mova                 m9, [rsp+26*%%str] ; t14
1334     mova                 m8, [rsp+30*%%str] ; t15
1335     mova                 m7, [rsp+ 1*%%str] ; t16
1336     mova                 m6, [rsp+ 5*%%str] ; t17
1337     mova                 m5, [rsp+ 9*%%str] ; t18
1338     mova                 m4, [rsp+13*%%str] ; t19
1339     mova                 m3, [rsp+17*%%str] ; t20
1340     mova                 m2, [rsp+21*%%str] ; t21
1341     mova                 m1, [rsp+25*%%str] ; t22
1342
1343     SUMSUB_BA             w,  7,  8, 0
1344     mova     [rsp+ 2*%%str], m8
1345     mova                 m0, [rsp+29*%%str] ; t23
1346     SUMSUB_BA             w,  6,  9, 8
1347     SUMSUB_BA             w,  5, 10, 8
1348     SUMSUB_BA             w,  4, 11, 8
1349     SUMSUB_BA             w,  3, 12, 8
1350     SUMSUB_BA             w,  2, 13, 8
1351     SUMSUB_BA             w,  1, 14, 8
1352     SUMSUB_BA             w,  0, 15, 8
1353
1354     TRANSPOSE8x8W         0, 1, 2, 3, 4, 5, 6, 7, 8
1355     mova     [rsp+ 1*%%str], m0
1356     mova     [rsp+ 5*%%str], m1
1357     mova     [rsp+ 9*%%str], m2
1358     mova     [rsp+13*%%str], m3
1359     mova     [rsp+17*%%str], m4
1360     mova     [rsp+21*%%str], m5
1361     mova     [rsp+25*%%str], m6
1362     mova     [rsp+29*%%str], m7
1363
1364     mova                 m8, [rsp+ 2*%%str]
1365     TRANSPOSE8x8W         8, 9, 10, 11, 12, 13, 14, 15, 0
1366     mova     [rsp+ 2*%%str], m8
1367     mova     [rsp+ 6*%%str], m9
1368     mova     [rsp+10*%%str], m10
1369     mova     [rsp+14*%%str], m11
1370     mova     [rsp+18*%%str], m12
1371     mova     [rsp+22*%%str], m13
1372     mova     [rsp+26*%%str], m14
1373     mova     [rsp+30*%%str], m15
1374 %else
1375     ; t0-7 is in [rsp+{0,4,8,12,16,20,24,28}*%%str]
1376     ; t8-15 is in [rsp+{2,6,10,14,18,22,26,30}*%%str]
1377     ; t16-19 and t23 is in [rsp+{1,5,9,13,29}*%%str]
1378     ; t20-22 is in m4-6
1379     ; t24-31 is in m8-15
1380     pxor                m7, m7
1381
1382 %macro %%STORE_2X2 7-8 1 ; src[1-4], tmp[1-2], zero, inc_dst_ptrs
1383     SUMSUB_BA            w, %4, %1, %5
1384     SUMSUB_BA            w, %3, %2, %5
1385     pmulhrsw           m%4, [pw_512]
1386     pmulhrsw           m%3, [pw_512]
1387     VP9_STORE_2X        %4, %3, %5, %6, %7
1388 %if %8 == 1
1389     add               dstq, stride2q
1390 %endif
1391     pmulhrsw           m%2, [pw_512]
1392     pmulhrsw           m%1, [pw_512]
1393     VP9_STORE_2X        %2, %1, %5, %6, %7, dst_endq
1394 %if %8 == 1
1395     sub           dst_endq, stride2q
1396 %endif
1397 %endmacro
1398
1399     ; store t0-1 and t30-31
1400     mova                m0, [rsp+ 0*%%str]
1401     mova                m1, [rsp+ 4*%%str]
1402     %%STORE_2X2          0,  1, 14, 15, 2, 3, 7
1403
1404     ; store t2-3 and t28-29
1405     mova                m0, [rsp+ 8*%%str]
1406     mova                m1, [rsp+12*%%str]
1407     %%STORE_2X2          0,  1, 12, 13, 2, 3, 7
1408
1409     ; store t4-5 and t26-27
1410     mova                m0, [rsp+16*%%str]
1411     mova                m1, [rsp+20*%%str]
1412     %%STORE_2X2          0,  1, 10, 11, 2, 3, 7
1413
1414     ; store t6-7 and t24-25
1415     mova                m0, [rsp+24*%%str]
1416     mova                m1, [rsp+28*%%str]
1417     %%STORE_2X2          0,  1,  8,  9, 2, 3, 7
1418
1419     ; store t8-9 and t22-23
1420     mova                m0, [rsp+ 2*%%str]
1421     mova                m1, [rsp+ 6*%%str]
1422     mova                m8, [rsp+29*%%str]
1423     %%STORE_2X2          0,  1,  6,  8, 2, 3, 7
1424
1425     ; store t10-11 and t20-21
1426     mova                m0, [rsp+10*%%str]
1427     mova                m1, [rsp+14*%%str]
1428     %%STORE_2X2          0,  1,  4,  5, 2, 3, 7
1429
1430     ; store t12-13 and t18-19
1431     mova                m0, [rsp+18*%%str]
1432     mova                m1, [rsp+22*%%str]
1433     mova                m5, [rsp+13*%%str]
1434     mova                m4, [rsp+ 9*%%str]
1435     %%STORE_2X2          0,  1,  4,  5, 2, 3, 7
1436
1437     ; store t14-17
1438     mova                m0, [rsp+26*%%str]
1439     mova                m1, [rsp+30*%%str]
1440     mova                m5, [rsp+ 5*%%str]
1441     mova                m4, [rsp+ 1*%%str]
1442     %%STORE_2X2          0,  1,  4,  5, 2, 3, 7, 0
1443 %endif
1444 %endmacro
1445
1446 %macro VP9_IDCT_IDCT_32x32_ADD_XMM 1
1447 INIT_XMM %1
1448 cglobal vp9_idct_idct_32x32_add, 4, 8, 16, 2048, dst, stride, block, eob
1449     cmp eobd, 135
1450     jg .idctfull
1451     cmp eobd, 34
1452     jg .idct16x16
1453     cmp eobd, 1
1454     jg .idct8x8
1455
1456     ; dc-only case
1457     movd                m0, [blockq]
1458     mova                m1, [pw_11585x2]
1459     pmulhrsw            m0, m1
1460     pmulhrsw            m0, m1
1461     SPLATW              m0, m0, q0000
1462     pmulhrsw            m0, [pw_512]
1463     pxor                m5, m5
1464     movd          [blockq], m5
1465     DEFINE_ARGS        dst, stride, block, cnt
1466 %rep 31
1467     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1468     add               dstq, strideq
1469 %endrep
1470     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1471     RET
1472
1473     DEFINE_ARGS dst_bak, stride, block, cnt, dst, stride30, dst_end, stride2
1474 .idct8x8:
1475     VP9_IDCT32_1D   blockq, 1, 8
1476
1477     mov          stride30q, strideq         ; stride
1478     lea           stride2q, [strideq*2]     ; stride*2
1479     shl          stride30q, 5               ; stride*32
1480     mov               cntd, 4
1481     sub          stride30q, stride2q        ; stride*30
1482 .loop2_8x8:
1483     mov               dstq, dst_bakq
1484     lea           dst_endq, [dst_bakq+stride30q]
1485     VP9_IDCT32_1D      rsp, 2, 8
1486     add           dst_bakq, 8
1487     add                rsp, 16
1488     dec               cntd
1489     jg .loop2_8x8
1490     sub                rsp, 64
1491
1492     ; at the end of the loop, m7 should still be zero
1493     ; use that to zero out block coefficients
1494     ZERO_BLOCK      blockq, 64,  8, m7
1495     RET
1496
1497 .idct16x16:
1498     mov               cntd, 2
1499 .loop1_16x16:
1500     VP9_IDCT32_1D   blockq, 1, 16
1501     add             blockq, 16
1502     add                rsp, 512
1503     dec               cntd
1504     jg .loop1_16x16
1505     sub             blockq, 32
1506     sub                rsp, 1024
1507
1508     mov          stride30q, strideq         ; stride
1509     lea           stride2q, [strideq*2]     ; stride*2
1510     shl          stride30q, 5               ; stride*32
1511     mov               cntd, 4
1512     sub          stride30q, stride2q        ; stride*30
1513 .loop2_16x16:
1514     mov               dstq, dst_bakq
1515     lea           dst_endq, [dst_bakq+stride30q]
1516     VP9_IDCT32_1D      rsp, 2, 16
1517     add           dst_bakq, 8
1518     add                rsp, 16
1519     dec               cntd
1520     jg .loop2_16x16
1521     sub                rsp, 64
1522
1523     ; at the end of the loop, m7 should still be zero
1524     ; use that to zero out block coefficients
1525     ZERO_BLOCK      blockq, 64, 16, m7
1526     RET
1527
1528 .idctfull:
1529     mov               cntd, 4
1530 .loop1_full:
1531     VP9_IDCT32_1D   blockq, 1
1532     add             blockq, 16
1533     add                rsp, 512
1534     dec               cntd
1535     jg .loop1_full
1536     sub             blockq, 64
1537     sub                rsp, 2048
1538
1539     mov          stride30q, strideq         ; stride
1540     lea           stride2q, [strideq*2]     ; stride*2
1541     shl          stride30q, 5               ; stride*32
1542     mov               cntd, 4
1543     sub          stride30q, stride2q        ; stride*30
1544 .loop2_full:
1545     mov               dstq, dst_bakq
1546     lea           dst_endq, [dst_bakq+stride30q]
1547     VP9_IDCT32_1D      rsp, 2
1548     add           dst_bakq, 8
1549     add                rsp, 16
1550     dec               cntd
1551     jg .loop2_full
1552     sub                rsp, 64
1553
1554     ; at the end of the loop, m7 should still be zero
1555     ; use that to zero out block coefficients
1556     ZERO_BLOCK      blockq, 64, 32, m7
1557     RET
1558 %endmacro
1559
1560 VP9_IDCT_IDCT_32x32_ADD_XMM ssse3
1561 VP9_IDCT_IDCT_32x32_ADD_XMM avx
1562
1563 %endif ; x86-64