dfc877e8e5672475d18362e9a236369f885a58e1
[ffmpeg.git] / libavcodec / x86 / vp9itxfm.asm
1 ;******************************************************************************
2 ;* VP9 IDCT SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013 Clément Bœsch <u pkh me>
5 ;* Copyright (C) 2013 Ronald S. Bultje <rsbultje gmail com>
6 ;*
7 ;* This file is part of FFmpeg.
8 ;*
9 ;* FFmpeg is free software; you can redistribute it and/or
10 ;* modify it under the terms of the GNU Lesser General Public
11 ;* License as published by the Free Software Foundation; either
12 ;* version 2.1 of the License, or (at your option) any later version.
13 ;*
14 ;* FFmpeg is distributed in the hope that it will be useful,
15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;* Lesser General Public License for more details.
18 ;*
19 ;* You should have received a copy of the GNU Lesser General Public
20 ;* License along with FFmpeg; if not, write to the Free Software
21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
22 ;******************************************************************************
23
24 %include "libavutil/x86/x86util.asm"
25
26 SECTION_RODATA
27
28 pw_11585x2:  times 8 dw 23170
29 pw_m11585x2: times 8 dw -23170
30
31 %macro VP9_IDCT_COEFFS 2-3 0
32 pw_%1x2:    times 8 dw  %1*2
33 pw_m%1x2:   times 8 dw -%1*2
34 pw_%2x2:    times 8 dw  %2*2
35 pw_m%2x2:   times 8 dw -%2*2
36 pw_m%1_%2:  times 4 dw -%1,  %2
37 pw_%2_%1:   times 4 dw  %2,  %1
38 pw_m%2_m%1: times 4 dw -%2, -%1
39 %if %3 == 1
40 pw_m%2_%1:  times 4 dw -%2,  %1
41 pw_%1_%2:   times 4 dw  %1,  %2
42 %endif
43 %endmacro
44
45 VP9_IDCT_COEFFS 15137,  6270, 1
46 VP9_IDCT_COEFFS 16069,  3196, 1
47 VP9_IDCT_COEFFS  9102, 13623, 1
48 VP9_IDCT_COEFFS 16305,  1606
49 VP9_IDCT_COEFFS 10394, 12665
50 VP9_IDCT_COEFFS 14449,  7723
51 VP9_IDCT_COEFFS  4756, 15679
52 VP9_IDCT_COEFFS 16364,   804
53 VP9_IDCT_COEFFS 11003, 12140
54 VP9_IDCT_COEFFS 14811,  7005
55 VP9_IDCT_COEFFS  5520, 15426
56 VP9_IDCT_COEFFS 15893,  3981
57 VP9_IDCT_COEFFS  8423, 14053
58 VP9_IDCT_COEFFS 13160,  9760
59 VP9_IDCT_COEFFS  2404, 16207
60
61 pd_8192: times 4 dd 8192
62 pw_2048: times 8 dw 2048
63 pw_1024: times 8 dw 1024
64 pw_512:  times 8 dw 512
65 pw_m1:   times 8 dw -1
66
67 SECTION .text
68
69 ; (a*x + b*y + round) >> shift
70 %macro VP9_MULSUB_2W_2X 5 ; dst1, dst2/src, round, coefs1, coefs2
71     pmaddwd            m%1, m%2, %4
72     pmaddwd            m%2,  %5
73     paddd              m%1,  %3
74     paddd              m%2,  %3
75     psrad              m%1,  14
76     psrad              m%2,  14
77 %endmacro
78
79 %macro VP9_MULSUB_2W_4X 7 ; dst1, dst2, coef1, coef2, rnd, tmp1/src, tmp2
80     VP9_MULSUB_2W_2X    %7,  %6,  %5, [pw_m%3_%4], [pw_%4_%3]
81     VP9_MULSUB_2W_2X    %1,  %2,  %5, [pw_m%3_%4], [pw_%4_%3]
82     packssdw           m%1, m%7
83     packssdw           m%2, m%6
84 %endmacro
85
86 %macro VP9_UNPACK_MULSUB_2W_4X 7-9 ; dst1, dst2, (src1, src2,) coef1, coef2, rnd, tmp1, tmp2
87 %if %0 == 7
88     punpckhwd          m%6, m%2, m%1
89     punpcklwd          m%2, m%1
90     VP9_MULSUB_2W_4X   %1, %2, %3, %4, %5, %6, %7
91 %else
92     punpckhwd          m%8, m%4, m%3
93     punpcklwd          m%2, m%4, m%3
94     VP9_MULSUB_2W_4X   %1, %2, %5, %6, %7, %8, %9
95 %endif
96 %endmacro
97
98 %macro VP9_STORE_2X 5-6 dstq ; reg1, reg2, tmp1, tmp2, zero, dst
99     movh               m%3, [%6]
100     movh               m%4, [%6+strideq]
101     punpcklbw          m%3, m%5
102     punpcklbw          m%4, m%5
103     paddw              m%3, m%1
104     paddw              m%4, m%2
105     packuswb           m%3, m%5
106     packuswb           m%4, m%5
107     movh              [%6], m%3
108     movh      [%6+strideq], m%4
109 %endmacro
110
111 ;-------------------------------------------------------------------------------------------
112 ; void vp9_idct_idct_4x4_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
113 ;-------------------------------------------------------------------------------------------
114
115 %macro VP9_IDCT4_1D_FINALIZE 0
116     SUMSUB_BA            w, 3, 2, 4                         ; m3=t3+t0, m2=-t3+t0
117     SUMSUB_BA            w, 1, 0, 4                         ; m1=t2+t1, m0=-t2+t1
118     SWAP                 0, 3, 2                            ; 3102 -> 0123
119 %endmacro
120
121 %macro VP9_IDCT4_1D 0
122     SUMSUB_BA            w, 2, 0, 4                         ; m2=IN(0)+IN(2) m0=IN(0)-IN(2)
123     pmulhrsw            m2, m6                              ; m2=t0
124     pmulhrsw            m0, m6                              ; m0=t1
125     VP9_UNPACK_MULSUB_2W_4X 1, 3, 15137, 6270, m7, 4, 5     ; m1=t2, m3=t3
126     VP9_IDCT4_1D_FINALIZE
127 %endmacro
128
129 ; 2x2 top left corner
130 %macro VP9_IDCT4_2x2_1D 0
131     pmulhrsw            m0, m5                              ; m0=t1
132     mova                m2, m0                              ; m2=t0
133     mova                m3, m1
134     pmulhrsw            m1, m6                              ; m1=t2
135     pmulhrsw            m3, m7                              ; m3=t3
136     VP9_IDCT4_1D_FINALIZE
137 %endmacro
138
139 %macro VP9_IDCT4_WRITEOUT 0
140     mova                m5, [pw_2048]
141     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
142     pmulhrsw            m1, m5
143     VP9_STORE_2X         0,  1,  6,  7,  4
144     lea               dstq, [dstq+2*strideq]
145     pmulhrsw            m2, m5
146     pmulhrsw            m3, m5
147     VP9_STORE_2X         2,  3,  6,  7,  4
148 %endmacro
149
150 INIT_MMX ssse3
151 cglobal vp9_idct_idct_4x4_add, 4,4,0, dst, stride, block, eob
152
153     cmp eobd, 4 ; 2x2 or smaller
154     jg .idctfull
155
156     cmp eobd, 1 ; faster path for when only DC is set
157     jne .idct2x2
158
159     movd                m0, [blockq]
160     mova                m5, [pw_11585x2]
161     pmulhrsw            m0, m5
162     pmulhrsw            m0, m5
163     pshufw              m0, m0, 0
164     pxor                m4, m4
165     movh          [blockq], m4
166     pmulhrsw            m0, [pw_2048]       ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
167     VP9_STORE_2X         0,  0,  6,  7,  4
168     lea               dstq, [dstq+2*strideq]
169     VP9_STORE_2X         0,  0,  6,  7,  4
170     RET
171
172 ; faster path for when only top left 2x2 block is set
173 .idct2x2:
174     movd                m0, [blockq+0]
175     movd                m1, [blockq+8]
176     mova                m5, [pw_11585x2]
177     mova                m6, [pw_6270x2]
178     mova                m7, [pw_15137x2]
179     VP9_IDCT4_2x2_1D
180     TRANSPOSE4x4W  0, 1, 2, 3, 4
181     VP9_IDCT4_2x2_1D
182     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
183     movh       [blockq+ 0], m4
184     movh       [blockq+ 8], m4
185     VP9_IDCT4_WRITEOUT
186     RET
187
188 .idctfull: ; generic full 4x4 idct/idct
189     mova                m0, [blockq+ 0]
190     mova                m1, [blockq+ 8]
191     mova                m2, [blockq+16]
192     mova                m3, [blockq+24]
193     mova                m6, [pw_11585x2]
194     mova                m7, [pd_8192]       ; rounding
195     VP9_IDCT4_1D
196     TRANSPOSE4x4W  0, 1, 2, 3, 4
197     VP9_IDCT4_1D
198     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
199     mova       [blockq+ 0], m4
200     mova       [blockq+ 8], m4
201     mova       [blockq+16], m4
202     mova       [blockq+24], m4
203     VP9_IDCT4_WRITEOUT
204     RET
205
206 %if ARCH_X86_64 ; TODO: 32-bit? (32-bit limited to 8 xmm reg, we use more)
207
208 ;-------------------------------------------------------------------------------------------
209 ; void vp9_idct_idct_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
210 ;-------------------------------------------------------------------------------------------
211
212 %macro VP9_IDCT8_1D_FINALIZE 0
213     SUMSUB_BA            w,  3, 10, 4                       ;  m3=t0+t7, m10=t0-t7
214     SUMSUB_BA            w,  1,  2, 4                       ;  m1=t1+t6,  m2=t1-t6
215     SUMSUB_BA            w, 11,  0, 4                       ; m11=t2+t5,  m0=t2-t5
216     SUMSUB_BA            w,  9,  8, 4                       ;  m9=t3+t4,  m8=t3-t4
217     SWAP                11, 10, 2
218     SWAP                 3,  9, 0
219 %endmacro
220
221 %macro VP9_IDCT8_1D 0
222     SUMSUB_BA            w, 8, 0, 4                         ; m8=IN(0)+IN(4) m0=IN(0)-IN(4)
223     pmulhrsw            m8, m12                             ; m8=t0a
224     pmulhrsw            m0, m12                             ; m0=t1a
225     VP9_UNPACK_MULSUB_2W_4X 2, 10, 15137,  6270, m7, 4, 5   ; m2=t2a, m10=t3a
226     VP9_UNPACK_MULSUB_2W_4X 1, 11, 16069,  3196, m7, 4, 5   ; m1=t4a, m11=t7a
227     VP9_UNPACK_MULSUB_2W_4X 9,  3,  9102, 13623, m7, 4, 5   ; m9=t5a,  m3=t6a
228     SUMSUB_BA            w, 10,  8, 4                       ; m10=t0a+t3a (t0),  m8=t0a-t3a (t3)
229     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
230     SUMSUB_BA            w,  9,  1, 4                       ;  m9=t4a+t5a (t4),  m1=t4a-t5a (t5a)
231     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
232     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
233     pmulhrsw            m1, m12                             ; m1=t6
234     pmulhrsw           m11, m12                             ; m11=t5
235     VP9_IDCT8_1D_FINALIZE
236 %endmacro
237
238 %macro VP9_IDCT8_4x4_1D 0
239     pmulhrsw            m0, m12                             ; m0=t1a/t0a
240     pmulhrsw           m10, m2, [pw_15137x2]                ; m10=t3a
241     pmulhrsw            m2, [pw_6270x2]                     ; m2=t2a
242     pmulhrsw           m11, m1, [pw_16069x2]                ; m11=t7a
243     pmulhrsw            m1, [pw_3196x2]                     ; m1=t4a
244     pmulhrsw            m9, m3, [pw_9102x2]                 ; m9=-t5a
245     pmulhrsw            m3, [pw_13623x2]                    ; m3=t6a
246     psubw               m8, m0, m10                         ; m8=t0a-t3a (t3)
247     paddw              m10, m0                              ; m10=t0a+t3a (t0)
248     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
249     SUMSUB_BA            w,  9,  1, 4                       ;  m1=t4a+t5a (t4),  m9=t4a-t5a (t5a)
250     SWAP                 1,  9
251     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
252     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
253     pmulhrsw            m1, m12                             ; m1=t6
254     pmulhrsw           m11, m12                             ; m11=t5
255     VP9_IDCT8_1D_FINALIZE
256 %endmacro
257
258 ; TODO: a lot of t* copies can probably be removed and merged with
259 ; following SUMSUBs from VP9_IDCT8_1D_FINALIZE with AVX
260 %macro VP9_IDCT8_2x2_1D 0
261     pmulhrsw            m0, m12                             ;  m0=t0
262     mova                m3, m1
263     pmulhrsw            m1, m6                              ;  m1=t4
264     pmulhrsw            m3, m7                              ;  m3=t7
265     mova                m2, m0                              ;  m2=t1
266     mova               m10, m0                              ; m10=t2
267     mova                m8, m0                              ;  m8=t3
268     mova               m11, m3                              ; t5 = t7a ...
269     mova                m9, m3                              ; t6 = t7a ...
270     psubw              m11, m1                              ; t5 = t7a - t4a
271     paddw               m9, m1                              ; t6 = t7a + t4a
272     pmulhrsw           m11, m12                             ; m11=t5
273     pmulhrsw            m9, m12                             ;  m9=t6
274     SWAP                 0, 10
275     SWAP                 9,  1
276     VP9_IDCT8_1D_FINALIZE
277 %endmacro
278
279 %macro VP9_IDCT8_WRITEOUT 0
280     mova                m5, [pw_1024]
281     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
282     pmulhrsw            m1, m5
283     VP9_STORE_2X         0,  1,  6,  7,  4
284     lea               dstq, [dstq+2*strideq]
285     pmulhrsw            m2, m5
286     pmulhrsw            m3, m5
287     VP9_STORE_2X         2,  3,  6,  7,  4
288     lea               dstq, [dstq+2*strideq]
289     pmulhrsw            m8, m5
290     pmulhrsw            m9, m5
291     VP9_STORE_2X         8,  9,  6,  7,  4
292     lea               dstq, [dstq+2*strideq]
293     pmulhrsw           m10, m5
294     pmulhrsw           m11, m5
295     VP9_STORE_2X        10, 11,  6,  7,  4
296 %endmacro
297
298 %macro VP9_IDCT_IDCT_8x8_ADD_XMM 1
299 INIT_XMM %1
300 cglobal vp9_idct_idct_8x8_add, 4,4,13, dst, stride, block, eob
301
302     mova               m12, [pw_11585x2]    ; often used
303
304     cmp eobd, 12 ; top left half or less
305     jg .idctfull
306
307     cmp eobd, 3  ; top left corner or less
308     jg .idcthalf
309
310     cmp eobd, 1 ; faster path for when only DC is set
311     jne .idcttopleftcorner
312
313     movd                m0, [blockq]
314     pmulhrsw            m0, m12
315     pmulhrsw            m0, m12
316     SPLATW              m0, m0, 0
317     pxor                m4, m4
318     movd          [blockq], m4
319     mova                m5, [pw_1024]
320     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
321     VP9_STORE_2X         0,  0,  6,  7,  4
322     lea               dstq, [dstq+2*strideq]
323     VP9_STORE_2X         0,  0,  6,  7,  4
324     lea               dstq, [dstq+2*strideq]
325     VP9_STORE_2X         0,  0,  6,  7,  4
326     lea               dstq, [dstq+2*strideq]
327     VP9_STORE_2X         0,  0,  6,  7,  4
328     RET
329
330 ; faster path for when only left corner is set (3 input: DC, right to DC, below
331 ; to DC). Note: also working with a 2x2 block
332 .idcttopleftcorner:
333     movd                m0, [blockq+0]
334     movd                m1, [blockq+16]
335     mova                m6, [pw_3196x2]
336     mova                m7, [pw_16069x2]
337     VP9_IDCT8_2x2_1D
338     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
339     VP9_IDCT8_2x2_1D
340     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
341     movd       [blockq+ 0], m4
342     movd       [blockq+16], m4
343     VP9_IDCT8_WRITEOUT
344     RET
345
346 .idcthalf:
347     movh                m0, [blockq + 0]
348     movh                m1, [blockq +16]
349     movh                m2, [blockq +32]
350     movh                m3, [blockq +48]
351     VP9_IDCT8_4x4_1D
352     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
353     VP9_IDCT8_4x4_1D
354     pxor                m4, m4
355     movh       [blockq+ 0], m4
356     movh       [blockq+16], m4
357     movh       [blockq+32], m4
358     movh       [blockq+48], m4
359     VP9_IDCT8_WRITEOUT
360     RET
361
362 .idctfull: ; generic full 8x8 idct/idct
363     mova                m0, [blockq+  0]    ; IN(0)
364     mova                m1, [blockq+ 16]    ; IN(1)
365     mova                m2, [blockq+ 32]    ; IN(2)
366     mova                m3, [blockq+ 48]    ; IN(3)
367     mova                m8, [blockq+ 64]    ; IN(4)
368     mova                m9, [blockq+ 80]    ; IN(5)
369     mova               m10, [blockq+ 96]    ; IN(6)
370     mova               m11, [blockq+112]    ; IN(7)
371     mova                m7, [pd_8192]       ; rounding
372     VP9_IDCT8_1D
373     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
374     VP9_IDCT8_1D
375     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
376     mova      [blockq+  0], m4
377     mova      [blockq+ 16], m4
378     mova      [blockq+ 32], m4
379     mova      [blockq+ 48], m4
380     mova      [blockq+ 64], m4
381     mova      [blockq+ 80], m4
382     mova      [blockq+ 96], m4
383     mova      [blockq+112], m4
384     VP9_IDCT8_WRITEOUT
385     RET
386 %endmacro
387
388 VP9_IDCT_IDCT_8x8_ADD_XMM ssse3
389 VP9_IDCT_IDCT_8x8_ADD_XMM avx
390
391 ;---------------------------------------------------------------------------------------------
392 ; void vp9_idct_idct_16x16_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
393 ;---------------------------------------------------------------------------------------------
394
395 ; at the end of this macro, m7 is stored in stack_scratch
396 ; everything else (t0-6 and t8-15) is stored in m0-6 and m8-15
397 ; the following sumsubs have not been done yet:
398 ;    SUMSUB_BA            w,  6,  9, 15      ; t6, t9
399 ;    SUMSUB_BA            w,  7,  8, 15      ; t7, t8
400 %macro VP9_IDCT16_1D_START 4 ; src, nnzc, stride, stack_scratch
401 %if %2 <= 4
402     mova                m3, [%1+ 1*%3]      ; IN(1)
403     mova               m12, [%1+ 2*%3]      ; IN(2)
404     mova                m0, [%1+ 3*%3]      ; IN(3)
405
406     pmulhrsw           m15, m12, [pw_16069x2]       ; t6-7
407     pmulhrsw           m12, [pw_3196x2]             ; t4-5
408     pmulhrsw            m4, m3,  [pw_16305x2]       ; t14-15
409     pmulhrsw            m3, [pw_1606x2]             ; t8-9
410     pmulhrsw            m7, m0,  [pw_m4756x2]       ; t10-11
411     pmulhrsw            m0, [pw_15679x2]            ; t12-13
412
413     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
414     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
415
416     paddw              m14, m15, m12
417     psubw              m13, m15, m12
418     pmulhrsw           m13, [pw_11585x2]            ; t5
419     pmulhrsw           m14, [pw_11585x2]            ; t6
420
421     VP9_UNPACK_MULSUB_2W_4X 2, 5, 4, 3, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
422     VP9_UNPACK_MULSUB_2W_4X 6, 1, 0, 7, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
423
424     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
425     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
426 %else
427     mova                m5, [%1+ 1*%3]     ; IN(1)
428     mova               m14, [%1+ 2*%3]     ; IN(2)
429     mova                m6, [%1+ 3*%3]     ; IN(3)
430     mova                m9, [%1+ 4*%3]     ; IN(4)
431     mova                m7, [%1+ 5*%3]     ; IN(5)
432     mova               m15, [%1+ 6*%3]     ; IN(6)
433     mova                m4, [%1+ 7*%3]     ; IN(7)
434 %if %2 <= 8
435     pmulhrsw            m8, m9,  [pw_15137x2]       ; t3
436     pmulhrsw            m9, [pw_6270x2]             ; t2
437     pmulhrsw           m13, m14, [pw_16069x2]       ; t7
438     pmulhrsw           m14, [pw_3196x2]             ; t4
439     pmulhrsw           m12, m15, [pw_m9102x2]       ; t5
440     pmulhrsw           m15, [pw_13623x2]            ; t6
441     pmulhrsw            m2, m5,  [pw_16305x2]       ; t15
442     pmulhrsw            m5, [pw_1606x2]             ; t8
443     pmulhrsw            m3, m4,  [pw_m10394x2]      ; t9
444     pmulhrsw            m4, [pw_12665x2]            ; t14
445     pmulhrsw            m0, m7,  [pw_14449x2]       ; t13
446     pmulhrsw            m7, [pw_7723x2]             ; t10
447     pmulhrsw            m1, m6,  [pw_m4756x2]       ; t11
448     pmulhrsw            m6, [pw_15679x2]            ; t12
449 %else
450     mova                m3, [%1+ 9*%3]     ; IN(9)
451     mova               m12, [%1+10*%3]     ; IN(10)
452     mova                m0, [%1+11*%3]     ; IN(11)
453     mova                m8, [%1+12*%3]     ; IN(12)
454     mova                m1, [%1+13*%3]     ; IN(13)
455     mova               m13, [%1+14*%3]     ; IN(14)
456     mova                m2, [%1+15*%3]     ; IN(15)
457
458     ; m10=in0, m5=in1, m14=in2, m6=in3, m9=in4, m7=in5, m15=in6, m4=in7
459     ; m11=in8, m3=in9, m12=in10 m0=in11, m8=in12, m1=in13, m13=in14, m2=in15
460
461     VP9_UNPACK_MULSUB_2W_4X   9,   8, 15137,  6270, [pd_8192], 10, 11 ; t2,  t3
462     VP9_UNPACK_MULSUB_2W_4X  14,  13, 16069,  3196, [pd_8192], 10, 11 ; t4,  t7
463     VP9_UNPACK_MULSUB_2W_4X  12,  15,  9102, 13623, [pd_8192], 10, 11 ; t5,  t6
464     VP9_UNPACK_MULSUB_2W_4X   5,   2, 16305,  1606, [pd_8192], 10, 11 ; t8,  t15
465     VP9_UNPACK_MULSUB_2W_4X   3,   4, 10394, 12665, [pd_8192], 10, 11 ; t9,  t14
466     VP9_UNPACK_MULSUB_2W_4X   7,   0, 14449,  7723, [pd_8192], 10, 11 ; t10, t13
467     VP9_UNPACK_MULSUB_2W_4X   1,   6,  4756, 15679, [pd_8192], 10, 11 ; t11, t12
468 %endif
469
470     ; m11=t0, m10=t1, m9=t2, m8=t3, m14=t4, m12=t5, m15=t6, m13=t7
471     ; m5=t8, m3=t9, m7=t10, m1=t11, m6=t12, m0=t13, m4=t14, m2=t15
472
473     SUMSUB_BA            w, 12, 14, 10      ; t4,  t5
474     SUMSUB_BA            w, 15, 13, 10      ; t7,  t6
475     SUMSUB_BA            w,  3,  5, 10      ; t8,  t9
476     SUMSUB_BA            w,  7,  1, 10      ; t11, t10
477     SUMSUB_BA            w,  0,  6, 10      ; t12, t13
478     SUMSUB_BA            w,  4,  2, 10      ; t15, t14
479
480     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
481     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
482
483     SUMSUB_BA            w, 14, 13, 10
484     pmulhrsw           m13, [pw_11585x2]                              ; t5
485     pmulhrsw           m14, [pw_11585x2]                              ; t6
486     VP9_UNPACK_MULSUB_2W_4X   2,   5, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
487     VP9_UNPACK_MULSUB_2W_4X   6,   1, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
488 %endif
489
490     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m13=t5, m14=t6, m15=t7
491     ; m3=t8, m2=t9, m6=t10, m7=t11, m0=t12, m1=t13, m5=t14, m4=t15
492
493     SUMSUB_BA            w,  7,  3, 10      ; t8,  t11
494     SUMSUB_BA            w,  6,  2, 10      ; t9,  t10
495     SUMSUB_BA            w,  0,  4, 10      ; t15, t12
496     SUMSUB_BA            w,  1,  5, 10      ; t14. t13
497
498     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
499     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
500
501     SUMSUB_BA            w,  2,  5, 10
502     SUMSUB_BA            w,  3,  4, 10
503     pmulhrsw            m5, [pw_11585x2]    ; t10
504     pmulhrsw            m4, [pw_11585x2]    ; t11
505     pmulhrsw            m3, [pw_11585x2]    ; t12
506     pmulhrsw            m2, [pw_11585x2]    ; t13
507
508     ; backup first register
509     mova              [%4], m7
510
511     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
512     ; m7=t8, m6=t9, m5=t10, m4=t11, m3=t12, m2=t13, m1=t14, m0=t15
513
514     ; from load/start
515 %if %2 <= 4
516     mova               m11, [%1+ 0*%3]      ; IN(0)
517     pmulhrsw           m11, [pw_11585x2]    ; t0-t3
518
519     psubw               m8, m11, m15
520     paddw              m15, m11
521     psubw               m9, m11, m14
522     paddw              m14, m11
523     psubw              m10, m11, m13
524     paddw              m13, m11
525 %else
526     mova               m10, [%1+ 0*%3]      ; IN(0)
527 %if %2 <= 8
528     pmulhrsw           m10, [pw_11585x2]    ; t0 and t1
529     psubw              m11, m10, m8
530     paddw               m8, m10
531 %else
532     mova               m11, [%1+ 8*%3]      ; IN(8)
533
534     ; from 3 stages back
535     SUMSUB_BA            w, 11, 10, 7
536     pmulhrsw           m11, [pw_11585x2]    ; t0
537     pmulhrsw           m10, [pw_11585x2]    ; t1
538
539     ; from 2 stages back
540     SUMSUB_BA            w,  8, 11, 7       ; t0,  t3
541 %endif
542     SUMSUB_BA            w,  9, 10, 7       ; t1,  t2
543
544     ; from 1 stage back
545     SUMSUB_BA            w, 15,  8, 7       ; t0,  t7
546     SUMSUB_BA            w, 14,  9, 7       ; t1,  t6
547     SUMSUB_BA            w, 13, 10, 7       ; t2,  t5
548 %endif
549     SUMSUB_BA            w, 12, 11, 7       ; t3,  t4
550
551     SUMSUB_BA            w,  0, 15, 7       ; t0, t15
552     SUMSUB_BA            w,  1, 14, 7       ; t1, t14
553     SUMSUB_BA            w,  2, 13, 7       ; t2, t13
554     SUMSUB_BA            w,  3, 12, 7       ; t3, t12
555     SUMSUB_BA            w,  4, 11, 7       ; t4, t11
556     SUMSUB_BA            w,  5, 10, 7       ; t5, t10
557 %endmacro
558
559 %macro VP9_IDCT16_1D 2-3 16 ; src, pass, nnzc
560     VP9_IDCT16_1D_START %1, %3, 32, rsp+32
561
562 %if %2 == 1
563     ; backup a different register
564     mova          [rsp+16], m15
565     mova                m7, [rsp+32]
566
567     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
568     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
569
570     TRANSPOSE8x8W        0, 1, 2, 3, 4, 5, 6, 7, 15
571     mova         [rsp+  0], m0
572     mova         [rsp+ 32], m1
573     mova         [rsp+ 64], m2
574     mova         [rsp+ 96], m3
575     mova         [rsp+128], m4
576     mova         [rsp+160], m5
577     mova         [rsp+192], m6
578     mova         [rsp+224], m7
579
580     mova               m15, [rsp+16]
581     TRANSPOSE8x8W        8, 9, 10, 11, 12, 13, 14, 15, 0
582     mova         [rsp+ 16], m8
583     mova         [rsp+ 48], m9
584     mova         [rsp+ 80], m10
585     mova         [rsp+112], m11
586     mova         [rsp+144], m12
587     mova         [rsp+176], m13
588     mova         [rsp+208], m14
589     mova         [rsp+240], m15
590 %else ; %2 == 2
591     ; backup more registers
592     mova          [rsp+64], m8
593     mova          [rsp+96], m9
594
595     pxor                m7, m7
596     pmulhrsw            m0, [pw_512]
597     pmulhrsw            m1, [pw_512]
598     VP9_STORE_2X         0,  1,  8,  9,  7
599     lea               dstq, [dstq+strideq*2]
600     pmulhrsw            m2, [pw_512]
601     pmulhrsw            m3, [pw_512]
602     VP9_STORE_2X         2,  3,  8,  9,  7
603     lea               dstq, [dstq+strideq*2]
604     pmulhrsw            m4, [pw_512]
605     pmulhrsw            m5, [pw_512]
606     VP9_STORE_2X         4,  5,  8,  9,  7
607     lea               dstq, [dstq+strideq*2]
608
609     ; restore from cache
610     SWAP                 0, 7               ; move zero from m7 to m0
611     mova                m7, [rsp+32]
612     mova                m8, [rsp+64]
613     mova                m9, [rsp+96]
614
615     SUMSUB_BA            w,  6,  9, 1       ; t6, t9
616     SUMSUB_BA            w,  7,  8, 1       ; t7, t8
617
618     pmulhrsw            m6, [pw_512]
619     pmulhrsw            m7, [pw_512]
620     VP9_STORE_2X         6,  7,  1,  2,  0
621     lea               dstq, [dstq+strideq*2]
622     pmulhrsw            m8, [pw_512]
623     pmulhrsw            m9, [pw_512]
624     VP9_STORE_2X         8,  9,  1,  2,  0
625     lea               dstq, [dstq+strideq*2]
626     pmulhrsw           m10, [pw_512]
627     pmulhrsw           m11, [pw_512]
628     VP9_STORE_2X        10, 11,  1,  2,  0
629     lea               dstq, [dstq+strideq*2]
630     pmulhrsw           m12, [pw_512]
631     pmulhrsw           m13, [pw_512]
632     VP9_STORE_2X        12, 13,  1,  2,  0
633     lea               dstq, [dstq+strideq*2]
634     pmulhrsw           m14, [pw_512]
635     pmulhrsw           m15, [pw_512]
636     VP9_STORE_2X        14, 15,  1,  2,  0
637 %endif ; %2 == 1/2
638 %endmacro
639
640 %macro ZERO_BLOCK 4 ; mem, stride, nnzcpl, zero_reg
641 %assign %%y 0
642 %rep %3
643 %assign %%x 0
644 %rep %3*2/mmsize
645     mova      [%1+%%y+%%x], %4
646 %assign %%x (%%x+mmsize)
647 %endrep
648 %assign %%y (%%y+%2)
649 %endrep
650 %endmacro
651
652 %macro VP9_STORE_2XFULL 6-7 strideq; dc, tmp1, tmp2, tmp3, tmp4, zero, stride
653     mova               m%3, [dstq]
654     mova               m%5, [dstq+%7]
655     punpcklbw          m%2, m%3, m%6
656     punpckhbw          m%3, m%6
657     punpcklbw          m%4, m%5, m%6
658     punpckhbw          m%5, m%6
659     paddw              m%2, m%1
660     paddw              m%3, m%1
661     paddw              m%4, m%1
662     paddw              m%5, m%1
663     packuswb           m%2, m%3
664     packuswb           m%4, m%5
665     mova            [dstq], m%2
666     mova         [dstq+%7], m%4
667 %endmacro
668
669 %macro VP9_IDCT_IDCT_16x16_ADD_XMM 1
670 INIT_XMM %1
671 cglobal vp9_idct_idct_16x16_add, 4, 5, 16, 512, dst, stride, block, eob
672     ; 2x2=eob=3, 4x4=eob=10
673     cmp eobd, 38
674     jg .idctfull
675     cmp eobd, 1 ; faster path for when only DC is set
676     jne .idct8x8
677
678     ; dc-only
679     movd                m0, [blockq]
680     mova                m1, [pw_11585x2]
681     pmulhrsw            m0, m1
682     pmulhrsw            m0, m1
683     SPLATW              m0, m0, q0000
684     pmulhrsw            m0, [pw_512]
685     pxor                m5, m5
686     movd          [blockq], m5
687 %rep 7
688     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
689     lea               dstq, [dstq+2*strideq]
690 %endrep
691     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
692     RET
693
694 .idct8x8:
695     DEFINE_ARGS dst, stride, block, cnt, dst_bak
696     VP9_IDCT16_1D   blockq, 1, 8
697
698     mov               cntd, 2
699     mov           dst_bakq, dstq
700 .loop2_8x8:
701     VP9_IDCT16_1D      rsp, 2, 8
702     lea               dstq, [dst_bakq+8]
703     add                rsp, 16
704     dec               cntd
705     jg .loop2_8x8
706     sub                rsp, 32
707
708     ; at the end of the loop, m0 should still be zero
709     ; use that to zero out block coefficients
710     ZERO_BLOCK      blockq, 32, 8, m0
711     RET
712
713 .idctfull:
714     DEFINE_ARGS dst, stride, block, cnt, dst_bak
715     mov               cntd, 2
716 .loop1_full:
717     VP9_IDCT16_1D   blockq, 1
718     add             blockq, 16
719     add                rsp, 256
720     dec               cntd
721     jg .loop1_full
722     sub             blockq, 32
723     sub                rsp, 512
724
725     mov               cntd, 2
726     mov           dst_bakq, dstq
727 .loop2_full:
728     VP9_IDCT16_1D      rsp, 2
729     lea               dstq, [dst_bakq+8]
730     add                rsp, 16
731     dec               cntd
732     jg .loop2_full
733     sub                rsp, 32
734
735     ; at the end of the loop, m0 should still be zero
736     ; use that to zero out block coefficients
737     ZERO_BLOCK      blockq, 32, 16, m0
738     RET
739 %endmacro
740
741 VP9_IDCT_IDCT_16x16_ADD_XMM ssse3
742 VP9_IDCT_IDCT_16x16_ADD_XMM avx
743
744 ;---------------------------------------------------------------------------------------------
745 ; void vp9_iadst_iadst_16x16_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
746 ;---------------------------------------------------------------------------------------------
747
748 %macro VP9_UNPACK_MULSUB_2D_4X 6 ; dst1 [src1], dst2 [src2], dst3, dst4, mul1, mul2
749     punpckhwd          m%4, m%2, m%1
750     punpcklwd          m%2, m%1
751     pmaddwd            m%3, m%4, [pw_m%5_%6]
752     pmaddwd            m%4, [pw_%6_%5]
753     pmaddwd            m%1, m%2, [pw_m%5_%6]
754     pmaddwd            m%2, [pw_%6_%5]
755 %endmacro
756
757 %macro VP9_RND_SH_SUMSUB_BA 6 ; dst1 [src1], dst2 [src2], src3, src4, tmp, round
758     SUMSUB_BA            d, %1, %2, %5
759     SUMSUB_BA            d, %3, %4, %5
760     paddd              m%1, %6
761     paddd              m%2, %6
762     paddd              m%3, %6
763     paddd              m%4, %6
764     psrad              m%1, 14
765     psrad              m%2, 14
766     psrad              m%3, 14
767     psrad              m%4, 14
768     packssdw           m%1, m%3
769     packssdw           m%2, m%4
770 %endmacro
771
772 %macro VP9_IADST16_1D 2 ; src, pass
773 %assign %%str 16*%2
774     mova                m0, [%1+ 0*32]  ; in0
775     mova                m1, [%1+15*32]  ; in15
776     mova                m8, [%1+ 7*32]  ; in7
777     mova                m9, [%1+ 8*32]  ; in8
778
779     VP9_UNPACK_MULSUB_2D_4X  1,  0,  2,  3, 16364,   804    ; m1/2=t1[d], m0/3=t0[d]
780     VP9_UNPACK_MULSUB_2D_4X  8,  9, 11, 10, 11003, 12140    ; m8/11=t9[d], m9/10=t8[d]
781     VP9_RND_SH_SUMSUB_BA     9,  0, 10,  3,  4, [pd_8192]   ; m9=t0[w], m0=t8[w]
782     VP9_RND_SH_SUMSUB_BA     8,  1, 11,  2,  4, [pd_8192]   ; m8=t1[w], m1=t9[w]
783
784     mova               m11, [%1+ 2*32]  ; in2
785     mova               m10, [%1+13*32]  ; in13
786     mova                m3, [%1+ 5*32]  ; in5
787     mova                m2, [%1+10*32]  ; in10
788
789     VP9_UNPACK_MULSUB_2D_4X 10, 11,  6,  7, 15893,  3981    ; m10/6=t3[d], m11/7=t2[d]
790     VP9_UNPACK_MULSUB_2D_4X  3,  2,  4,  5,  8423, 14053    ; m3/4=t11[d], m2/5=t10[d]
791     VP9_RND_SH_SUMSUB_BA     2, 11,  5,  7, 12, [pd_8192]   ; m2=t2[w], m11=t10[w]
792     VP9_RND_SH_SUMSUB_BA     3, 10,  4,  6, 12, [pd_8192]   ; m3=t3[w], m10=t11[w]
793
794     mova    [rsp+ 0*%%str], m9          ; make some scratch space (t0:m9->r0)
795     mova                m4, [%1+ 4*32]  ; in4
796     mova                m5, [%1+11*32]  ; in11
797     mova               m12, [%1+ 3*32]  ; in3
798     mova               m13, [%1+12*32]  ; in12
799
800     VP9_UNPACK_MULSUB_2D_4X  5,  4,  7,  6, 14811,  7005    ; m5/7=t5[d], m4/6=t4[d]
801     VP9_UNPACK_MULSUB_2D_4X 12, 13, 14, 15,  5520, 15426    ; m12/14=t13[d], m13/15=t12[d]
802     VP9_RND_SH_SUMSUB_BA    13,  4, 15,  6,  9, [pd_8192]   ; m13=t4[w], m4=t12[w]
803     VP9_RND_SH_SUMSUB_BA    12,  5, 14,  7,  9, [pd_8192]   ; m12=t5[w], m5=t13[w]
804
805     mova    [rsp+ 2*%%str], m8          ; t1:m9->r2
806     mova    [rsp+ 3*%%str], m2          ; t2:m2->r3
807     mova    [rsp+ 4*%%str], m3          ; t3:m3->r4
808     mova    [rsp+ 5*%%str], m13         ; t4:m13->r5
809     mova                m2, [%1+ 6*32]  ; in6
810     mova                m3, [%1+ 9*32]  ; in9
811     mova                m8, [%1+ 1*32]  ; in1
812     mova                m9, [%1+14*32]  ; in14
813
814     VP9_UNPACK_MULSUB_2D_4X  3,  2,  7,  6, 13160,  9760    ; m3/7=t7[d], m2/6=t6[d]
815     VP9_UNPACK_MULSUB_2D_4X  8,  9, 13, 14,  2404, 16207    ; m8/13=t15[d], m9/14=t14[d]
816     VP9_RND_SH_SUMSUB_BA     9,  2, 14,  6, 15, [pd_8192]   ; m9=t6[w], m2=t14[w]
817     VP9_RND_SH_SUMSUB_BA     8,  3, 13,  7, 15, [pd_8192]   ; m8=t7[w], m3=t15[w]
818
819     ; r0=t0, r2=t1, r3=t2, r4=t3, r5=t4, m12=t5, m9=t6, m8=t7
820     ; m0=t8, m1=t9, m11=t10, m10=t11, m4=t12, m5=t13, m2=t14, m3=t15
821
822     ; handle t8-15 first
823     VP9_UNPACK_MULSUB_2D_4X  0,  1,  6,  7, 16069,  3196    ; m1/7=t8[d], m0/6=t9[d]
824     VP9_UNPACK_MULSUB_2D_4X  5,  4, 13, 14,  3196, 16069    ; m5/13=t12[d], m4/14=t13[d]
825     VP9_RND_SH_SUMSUB_BA     5,  1, 13,  7, 15, [pd_8192]   ; m5=t8[w], m1=t12[w]
826     VP9_RND_SH_SUMSUB_BA     4,  0, 14,  6, 15, [pd_8192]   ; m4=t9[w], m0=t13[w]
827
828     VP9_UNPACK_MULSUB_2D_4X 11, 10,  6,  7,  9102, 13623    ; m11/6=t11[d], m10/7=t10[d]
829     VP9_UNPACK_MULSUB_2D_4X  3,  2, 13, 14, 13623,  9102    ; m3/13=t14[d], m2/14=t15[d]
830     VP9_RND_SH_SUMSUB_BA     3, 10, 13,  7, 15, [pd_8192]   ; m3=t10[w], m10=t14[w]
831     VP9_RND_SH_SUMSUB_BA     2, 11, 14,  6, 15, [pd_8192]   ; m2=t11[w], m11=t15[w]
832
833     ; m5=t8, m4=t9, m3=t10, m2=t11, m1=t12, m0=t13, m10=t14, m11=t15
834
835     VP9_UNPACK_MULSUB_2D_4X  1,  0,  6,  7, 15137,  6270    ; m1/6=t13[d], m0/7=t12[d]
836     VP9_UNPACK_MULSUB_2D_4X 11, 10, 13, 14,  6270, 15137    ; m11/13=t14[d], m10/14=t15[d]
837     VP9_RND_SH_SUMSUB_BA    11,  0, 13,  7, 15, [pd_8192]   ; m11=out2[w], m0=t14[w]
838     VP9_RND_SH_SUMSUB_BA    10,  1, 14,  6, 15, [pd_8192]
839     psignw                 m10, [pw_m1]                     ; m10=out13[w], m1=t15[w]
840
841     SUMSUB_BA                w,  3,  5, 15
842     psignw                  m3, [pw_m1]                     ; m3=out1[w], m5=t10[w]
843     SUMSUB_BA                w,  2,  4, 15                  ; m2=out14[w], m4=t11[w]
844
845     SUMSUB_BA                w,  5,  4, 15
846     pmulhrsw                m5, [pw_11585x2]                ; m5=out6[w]
847     pmulhrsw                m4, [pw_11585x2]                ; m4=out9[w]
848     SUMSUB_BA                w,  1,  0, 15
849     pmulhrsw                m1, [pw_m11585x2]               ; m1=out5[w]
850     pmulhrsw                m0, [pw_11585x2]                ; m0=out10[w]
851
852     ; m3=out1, m11=out2, m1=out5, m5=out6, m4=out9, m0=out10, m10=out13, m2=out14
853
854     mova                    m6, [rsp+ 0*%%str]
855     mova                    m7, [rsp+ 2*%%str]
856     mova                   m13, [rsp+ 3*%%str]
857     mova                   m14, [rsp+ 4*%%str]
858     mova                   m15, [rsp+ 5*%%str]
859     mova        [rsp+ 8*%%str], m5
860     mova        [rsp+ 9*%%str], m4
861     mova        [rsp+10*%%str], m0
862     mova        [rsp+11*%%str], m10
863     mova        [rsp+12*%%str], m2
864
865     ; m6=t0, m7=t1, m13=t2, m14=t3, m15=t4, m12=t5, m9=t6, m8=t7
866     ; m3=out1, m11=out2, m1=out5, r8=out6, r9=out9, r10=out10, r11=out13, r12=out14
867
868     SUMSUB_BA                w, 15,  6,  0                  ; m15=t0[w], m6=t4[w]
869     SUMSUB_BA                w, 12,  7,  0                  ; m12=t1[w], m7=t5[w]
870     SUMSUB_BA                w,  9, 13,  0                  ; m9=t2[w], m13=t6[w]
871     SUMSUB_BA                w,  8, 14,  0                  ; m8=t3[w], m14=t7[w]
872
873     VP9_UNPACK_MULSUB_2D_4X  6,  7,  0,  2, 15137,  6270    ; m6/0=t5[d], m7/2=t4[d]
874     VP9_UNPACK_MULSUB_2D_4X 14, 13,  4,  5,  6270, 15137    ; m14/4=t6[d], m13/5=t7[d]
875     VP9_RND_SH_SUMSUB_BA    14,  7,  4,  2, 10, [pd_8192]
876     psignw                 m14, [pw_m1]                     ; m14=out3[w], m7=t6[w]
877     VP9_RND_SH_SUMSUB_BA    13,  6,  5,  0, 10, [pd_8192]   ; m13=out12[w], m6=t7[w]
878     SUMSUB_BA                w,  9, 15, 10                  ; m9=out0[w], m15=t2[w]
879     SUMSUB_BA                w,  8, 12, 10
880     psignw                  m8, [pw_m1]                     ; m8=out15[w], m12=t3[w]
881
882     SUMSUB_BA                w, 12, 15, 10
883     pmulhrsw               m12, [pw_m11585x2]               ; m12=out7[w]
884     pmulhrsw               m15, [pw_11585x2]                ; m15=out8[w]
885     SUMSUB_BA                w,  7,  6, 10
886     pmulhrsw                m7, [pw_11585x2]                ; m7=out4[w]
887     pmulhrsw                m6, [pw_11585x2]                ; m6=out11[w]
888
889     ; m9=out0, m14=out3, m7=out4, m12=out7, m15=out8, m6=out11, m13=out12, m8=out15
890     ; m3=out1, m11=out2, m1=out5, r8=out6, r9=out9, r10=out10, r11=out13, r12=out14
891
892 %if %2 == 1
893     mova                    m0, [rsp+ 8*%%str]
894     TRANSPOSE8x8W            9, 3, 11, 14, 7, 1, 0, 12, 2
895     mova           [rsp+ 0*16], m9
896     mova           [rsp+ 2*16], m3
897     mova           [rsp+ 4*16], m11
898     mova           [rsp+ 6*16], m14
899     mova                    m9, [rsp+ 9*%%str]
900     mova                    m3, [rsp+10*%%str]
901     mova                   m11, [rsp+11*%%str]
902     mova                   m14, [rsp+12*%%str]
903     mova           [rsp+ 8*16], m7
904     mova           [rsp+10*16], m1
905     mova           [rsp+12*16], m0
906     mova           [rsp+14*16], m12
907
908     TRANSPOSE8x8W           15, 9, 3, 6, 13, 11, 14, 8, 2
909     mova           [rsp+ 1*16], m15
910     mova           [rsp+ 3*16], m9
911     mova           [rsp+ 5*16], m3
912     mova           [rsp+ 7*16], m6
913     mova           [rsp+ 9*16], m13
914     mova           [rsp+11*16], m11
915     mova           [rsp+13*16], m14
916     mova           [rsp+15*16], m8
917 %else
918     mova                    m5, [rsp+ 8*%%str]
919     pxor                    m0, m0
920
921     pmulhrsw                m9, [pw_512]
922     pmulhrsw                m3, [pw_512]
923     VP9_STORE_2X             9,  3, 2, 4, 0
924     lea                   dstq, [dstq+strideq*2]
925     pmulhrsw               m11, [pw_512]
926     pmulhrsw               m14, [pw_512]
927     VP9_STORE_2X            11, 14, 2, 4, 0
928     lea                   dstq, [dstq+strideq*2]
929     pmulhrsw                m7, [pw_512]
930     pmulhrsw                m1, [pw_512]
931     VP9_STORE_2X             7,  1, 2, 4, 0
932     lea                   dstq, [dstq+strideq*2]
933     pmulhrsw                m5, [pw_512]
934     pmulhrsw               m12, [pw_512]
935     VP9_STORE_2X             5, 12, 2, 4, 0
936     lea                   dstq, [dstq+strideq*2]
937
938     mova                    m9, [rsp+ 9*%%str]
939     mova                    m3, [rsp+10*%%str]
940     mova                   m11, [rsp+11*%%str]
941     mova                   m14, [rsp+12*%%str]
942
943     pmulhrsw               m15, [pw_512]
944     pmulhrsw                m9, [pw_512]
945     VP9_STORE_2X            15,  9, 2, 4, 0
946     lea                   dstq, [dstq+strideq*2]
947     pmulhrsw                m3, [pw_512]
948     pmulhrsw                m6, [pw_512]
949     VP9_STORE_2X             3,  6, 2, 4, 0
950     lea                   dstq, [dstq+strideq*2]
951     pmulhrsw               m13, [pw_512]
952     pmulhrsw               m11, [pw_512]
953     VP9_STORE_2X            13, 11, 2, 4, 0
954     lea                   dstq, [dstq+strideq*2]
955     pmulhrsw               m14, [pw_512]
956     pmulhrsw                m8, [pw_512]
957     VP9_STORE_2X            14,  8, 2, 4, 0
958 %endif
959 %endmacro
960
961 %macro IADST16_FN 5
962 INIT_XMM %5
963 cglobal vp9_%1_%3_16x16_add, 3, 5, 16, 512, dst, stride, block, eob
964     ; potential eob checks go here
965
966     DEFINE_ARGS dst, stride, block, cnt, dst_bak
967     mov               cntd, 2
968 .loop1_full:
969     VP9_%2_1D       blockq, 1
970     add             blockq, 16
971     add                rsp, 256
972     dec               cntd
973     jg .loop1_full
974     sub             blockq, 32
975     sub                rsp, 512
976
977     mov               cntd, 2
978     mov           dst_bakq, dstq
979 .loop2_full:
980     VP9_%4_1D          rsp, 2
981     lea               dstq, [dst_bakq+8]
982     add                rsp, 16
983     dec               cntd
984     jg .loop2_full
985     sub                rsp, 32
986
987     ; at the end of the loop, m0 should still be zero
988     ; use that to zero out block coefficients
989     ZERO_BLOCK      blockq, 32, 16, m0
990     RET
991 %endmacro
992
993 IADST16_FN idct,  IDCT16,  iadst, IADST16, ssse3
994 IADST16_FN idct,  IDCT16,  iadst, IADST16, avx
995 IADST16_FN iadst, IADST16, idct,  IDCT16,  ssse3
996 IADST16_FN iadst, IADST16, idct,  IDCT16,  avx
997 IADST16_FN iadst, IADST16, iadst, IADST16, ssse3
998 IADST16_FN iadst, IADST16, iadst, IADST16, avx
999
1000 ;---------------------------------------------------------------------------------------------
1001 ; void vp9_idct_idct_32x32_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
1002 ;---------------------------------------------------------------------------------------------
1003
1004 %macro VP9_IDCT32_1D 2-3 32 ; src, pass, nnzc
1005 %assign %%str 16*%2*%2
1006     ; first do t0-15, this can be done identical to idct16x16
1007     VP9_IDCT16_1D_START %1, %3/2, 64*2, rsp+ 4*%%str
1008
1009     ; backup a different register
1010     mova     [rsp+30*%%str], m15    ; t15
1011     mova                m7, [rsp+ 4*%%str]
1012
1013     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
1014     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
1015
1016     ; store everything on stack to make space available for t16-31
1017     ; we store interleaved with the output of the second half (t16-31)
1018     ; so we don't need to allocate extra stack space
1019     mova     [rsp+ 0*%%str], m0     ; t0
1020     mova     [rsp+ 4*%%str], m1     ; t1
1021     mova     [rsp+ 8*%%str], m2     ; t2
1022     mova     [rsp+12*%%str], m3     ; t3
1023     mova     [rsp+16*%%str], m4     ; t4
1024     mova     [rsp+20*%%str], m5     ; t5
1025     mova     [rsp+24*%%str], m6     ; t6
1026     mova     [rsp+28*%%str], m7     ; t7
1027     mova     [rsp+ 2*%%str], m8     ; t8
1028     mova     [rsp+ 6*%%str], m9     ; t9
1029     mova     [rsp+10*%%str], m10    ; t10
1030     mova     [rsp+14*%%str], m11    ; t11
1031     mova     [rsp+18*%%str], m12    ; t12
1032     mova     [rsp+22*%%str], m13    ; t13
1033     mova     [rsp+26*%%str], m14    ; t14
1034
1035     ; then, secondly, do t16-31
1036 %if %3 <= 8
1037     mova                 m4, [%1+ 1*64]
1038     mova                 m3, [%1+ 3*64]
1039     mova                 m0, [%1+ 5*64]
1040     mova                 m7, [%1+ 7*64]
1041
1042     pmulhrsw            m11,  m4, [pw_16364x2] ;t31
1043     pmulhrsw             m4, [pw_804x2] ;t16
1044     pmulhrsw             m8,  m7, [pw_m5520x2] ;t19
1045     pmulhrsw             m7, [pw_15426x2] ;t28
1046     pmulhrsw            m15,  m0, [pw_15893x2] ;t27
1047     pmulhrsw             m0, [pw_3981x2] ;t20
1048     pmulhrsw            m12,  m3, [pw_m2404x2] ;t23
1049     pmulhrsw             m3, [pw_16207x2] ;t24
1050
1051     ; m4=t16/17, m8=t18/19, m0=t20/21, m12=t22/23,
1052     ; m3=t24/25, m15=t26/27, m7=t28/29, m11=t30/31
1053
1054     VP9_UNPACK_MULSUB_2W_4X   5, 10, 11,  4, 16069,  3196, [pd_8192], 6,  9 ; t17, t30
1055     VP9_UNPACK_MULSUB_2W_4X   9,  6,  7,  8, 3196, m16069, [pd_8192], 1, 14 ; t18, t29
1056     ; from 1 stage forward
1057     SUMSUB_BA                 w,  8,  4,  1
1058     ; temporary storage
1059     mova     [rsp+17*%%str], m8             ; t16
1060     mova     [rsp+21*%%str], m4             ; t19
1061     VP9_UNPACK_MULSUB_2W_4X   1, 14, 15,  0,  9102, 13623, [pd_8192], 4,  8 ; t21, t26
1062     VP9_UNPACK_MULSUB_2W_4X  13,  2,  3, 12, 13623, m9102, [pd_8192], 4,  8 ; t22, t25
1063
1064     ; m4=t16, m5=t17, m9=t18, m8=t19, m0=t20, m1=t21, m13=t22, m12=t23,
1065     ; m3=t24, m2=t25, m14=t26, m15=t27, m7=t28, m6=t29, m10=t30, m11=t31
1066 %else
1067     mova                m10, [%1+ 1*64]
1068     mova                m13, [%1+ 3*64]
1069     mova                m14, [%1+ 5*64]
1070     mova                 m9, [%1+ 7*64]
1071     mova                 m8, [%1+ 9*64]
1072     mova                m15, [%1+11*64]
1073     mova                m12, [%1+13*64]
1074     mova                m11, [%1+15*64]
1075 %if %3 <= 16
1076     pmulhrsw             m5, m10, [pw_16364x2]
1077     pmulhrsw            m10, [pw_804x2]
1078     pmulhrsw             m4, m11, [pw_m11003x2]
1079     pmulhrsw            m11, [pw_12140x2]
1080     pmulhrsw             m7,  m8, [pw_14811x2]
1081     pmulhrsw             m8, [pw_7005x2]
1082     pmulhrsw             m6,  m9, [pw_m5520x2]
1083     pmulhrsw             m9, [pw_15426x2]
1084     pmulhrsw             m1, m14, [pw_15893x2]
1085     pmulhrsw            m14, [pw_3981x2]
1086     pmulhrsw             m0, m15, [pw_m8423x2]
1087     pmulhrsw            m15, [pw_14053x2]
1088 %else
1089     mova                 m4, [%1+17*64]
1090     mova                 m0, [%1+21*64]
1091     mova                 m7, [%1+23*64]
1092     mova                 m6, [%1+25*64]
1093     mova                 m1, [%1+27*64]
1094     mova                 m5, [%1+31*64]
1095
1096     ; m10=in1, m4=in17, m8=in9, m6=in25, m14=in5, m0=in21, m12=in13, m2=in29,
1097     ; m13=in3, m3=in19, m15=in11, m1=in27, m9=in7, m7=in23, m11=in15, m5=in31
1098
1099     VP9_UNPACK_MULSUB_2W_4X  10,  5, 16364,   804, [pd_8192], 2, 3 ; t16, t31
1100     VP9_UNPACK_MULSUB_2W_4X   4, 11, 11003, 12140, [pd_8192], 2, 3 ; t17, t30
1101     VP9_UNPACK_MULSUB_2W_4X   8,  7, 14811,  7005, [pd_8192], 2, 3 ; t18, t29
1102     VP9_UNPACK_MULSUB_2W_4X   6,  9,  5520, 15426, [pd_8192], 2, 3 ; t19, t28
1103     VP9_UNPACK_MULSUB_2W_4X  14,  1, 15893,  3981, [pd_8192], 2, 3 ; t20, t27
1104     VP9_UNPACK_MULSUB_2W_4X   0, 15,  8423, 14053, [pd_8192], 2, 3 ; t21, t26
1105 %endif
1106
1107     ; from 1 stage forward
1108     SUMSUB_BA             w,  4, 10,  2
1109     SUMSUB_BA             w,  8,  6,  2
1110     ; from 2 stages forward
1111     SUMSUB_BA             w,  8,  4,  2
1112     ; temporary storage
1113     mova     [rsp+17*%%str], m8             ; t16
1114     mova     [rsp+21*%%str], m4             ; t19
1115 %if %3 <= 16
1116     pmulhrsw             m3, m12, [pw_13160x2]
1117     pmulhrsw            m12, [pw_9760x2]
1118     pmulhrsw             m2, m13, [pw_m2404x2]
1119     pmulhrsw            m13, [pw_16207x2]
1120 %else
1121     mova                 m2, [%1+29*64]
1122     mova                 m3, [%1+19*64]
1123     VP9_UNPACK_MULSUB_2W_4X  12,  3, 13160,  9760, [pd_8192], 4, 8 ; t22, t25
1124     VP9_UNPACK_MULSUB_2W_4X   2, 13,  2404, 16207, [pd_8192], 4, 8 ; t23, t24
1125 %endif
1126
1127     ; m10=t16, m4=t17, m8=t18, m6=t19, m14=t20, m0=t21, m12=t22, m2=t23,
1128     ; m13=t24, m3=t25, m15=t26, m1=t27, m9=t28, m7=t29, m11=t30, m5=t31
1129
1130     SUMSUB_BA             w,  0, 14,  4
1131     SUMSUB_BA             w, 12,  2,  4
1132     SUMSUB_BA             w,  3, 13,  4
1133     SUMSUB_BA             w, 15,  1,  4
1134     SUMSUB_BA             w,  7,  9,  4
1135     SUMSUB_BA             w, 11,  5,  4
1136
1137     ; m4=t16, m10=t17, m6=t18, m8=t19, m0=t20, m14=t21, m2=t22, m12=t23,
1138     ; m3=t24, m13=t25, m1=t26, m15=t27, m7=t28, m9=t29, m5=t30, m11=t31
1139
1140     VP9_UNPACK_MULSUB_2W_4X   5, 10, 16069,  3196, [pd_8192], 4, 8 ; t17, t30
1141     VP9_UNPACK_MULSUB_2W_4X   9,  6, 3196, m16069, [pd_8192], 4, 8 ; t18, t29
1142     VP9_UNPACK_MULSUB_2W_4X   1, 14,  9102, 13623, [pd_8192], 4, 8 ; t21, t26
1143     VP9_UNPACK_MULSUB_2W_4X  13,  2, 13623, m9102, [pd_8192], 4, 8 ; t22, t25
1144 %endif
1145
1146     ; m4=t16, m5=t17, m9=t18, m8=t19, m0=t20, m1=t21, m13=t22, m12=t23,
1147     ; m3=t24, m2=t25, m14=t26, m15=t27, m7=t28, m6=t29, m10=t30, m11=t31
1148
1149     SUMSUB_BA             w,  9,  5,  4
1150     SUMSUB_BA             w,  1, 13,  4
1151     SUMSUB_BA             w,  0, 12,  4
1152     SUMSUB_BA             w, 15,  3,  4
1153     SUMSUB_BA             w, 14,  2,  4
1154     SUMSUB_BA             w,  6, 10,  4
1155     SUMSUB_BA             w,  7, 11,  4
1156
1157     ; m8[s]=t16, m9=t17, m5=t18, m4[s]=t19, m12=t20, m13=t21, m1=t22, m0=t23,
1158     ; m15=t24, m14=t25, m2=t26, m3=t27, m11=t28, m10=t29, m6=t30, m7=t31
1159
1160     mova                 m8, [rsp+17*%%str] ; t16
1161     ; from 2 stages forward
1162     SUMSUB_BA             w,  0,  8,  4
1163     SUMSUB_BA             w, 15,  7,  4
1164     ; from 3 stages forward
1165     SUMSUB_BA             w,  8,  7,  4
1166     pmulhrsw             m7, [pw_11585x2]
1167     pmulhrsw             m8, [pw_11585x2]
1168     ; store t16/t23
1169     mova     [rsp+ 1*%%str], m0     ; t16
1170     mova     [rsp+29*%%str], m7     ; t23
1171
1172     mova                 m4, [rsp+21*%%str] ; t19
1173     VP9_UNPACK_MULSUB_2W_4X  10,  5, 15137,  6270, [pd_8192], 0, 7 ; t18, t29
1174     VP9_UNPACK_MULSUB_2W_4X  11,  4, 15137,  6270, [pd_8192], 0, 7 ; t19, t28
1175     VP9_UNPACK_MULSUB_2W_4X   3, 12, 6270, m15137, [pd_8192], 0, 7 ; t20, t27
1176     VP9_UNPACK_MULSUB_2W_4X   2, 13, 6270, m15137, [pd_8192], 0, 7 ; t21, t26
1177
1178     ; m8=t16, m9=t17, m10=t18, m11=t19, m3=t20, m2=t21, m1=t22, m0=t23,
1179     ; m15=t24, m14=t25, m13=t26, m12=t27, m4=t28, m5=t29, m6=t30, m7=t31
1180
1181     SUMSUB_BA             w,  1,  9,  0
1182     SUMSUB_BA             w,  2, 10,  0
1183     SUMSUB_BA             w,  3, 11,  0
1184     SUMSUB_BA             w, 12,  4,  0
1185     SUMSUB_BA             w, 13,  5,  0
1186     SUMSUB_BA             w, 14,  6,  0
1187
1188     ; m0=t16, m1=t17, m2=t18, m3=t19, m11=t20, m10=t21, m9=t22, m8=t23,
1189     ; m7=t24, m6=t25, m5=t26, m4=t27, m12=t28, m13=t29, m14=t30, m15=t31
1190
1191     SUMSUB_BA             w,  9,  6,  0
1192     SUMSUB_BA             w, 10,  5,  0
1193     SUMSUB_BA             w, 11,  4,  0
1194
1195     pmulhrsw             m6, [pw_11585x2]
1196     pmulhrsw             m9, [pw_11585x2]
1197     pmulhrsw             m5, [pw_11585x2]
1198     pmulhrsw            m10, [pw_11585x2]
1199     pmulhrsw             m4, [pw_11585x2]
1200     pmulhrsw            m11, [pw_11585x2]
1201
1202     ; m0=t16, m1=t17, m2=t18, m3=t19, m4=t20, m5=t21, m6=t22, m7=t23,
1203     ; m8=t24, m9=t25, m10=t26, m11=t27, m12=t28, m13=t29, m14=t30, m15=t31
1204
1205     ; store t17-19 (and t20-22 for pass 1) - keep t24-31 in registers for
1206     ; final sumsub in pass 1, or keep t20-22 and t24-31 in registers for
1207     ; final sumsub of pass 2
1208     mova     [rsp+ 5*%%str], m1     ; t17
1209     mova     [rsp+ 9*%%str], m2     ; t18
1210     mova     [rsp+13*%%str], m3     ; t19
1211
1212     ; then do final pass to sumsub+store the two halves
1213 %if %2 == 1
1214     mova     [rsp+17*%%str], m4     ; t20
1215     mova     [rsp+21*%%str], m5     ; t21
1216     mova     [rsp+25*%%str], m6     ; t22
1217
1218     mova                 m0, [rsp+ 0*%%str] ; t0
1219     mova                 m1, [rsp+ 4*%%str] ; t1
1220     mova                 m2, [rsp+ 8*%%str] ; t2
1221     mova                 m3, [rsp+12*%%str] ; t3
1222     mova                 m4, [rsp+16*%%str] ; t4
1223     mova                 m5, [rsp+20*%%str] ; t5
1224     mova                 m6, [rsp+24*%%str] ; t6
1225
1226     SUMSUB_BA             w, 15,  0, 7
1227     mova     [rsp+ 3*%%str], m0             ; t15
1228     mova                 m7, [rsp+28*%%str] ; t7
1229     SUMSUB_BA             w, 14,  1, 0
1230     SUMSUB_BA             w, 13,  2, 0
1231     SUMSUB_BA             w, 12,  3, 0
1232     SUMSUB_BA             w, 11,  4, 0
1233     SUMSUB_BA             w, 10,  5, 0
1234     SUMSUB_BA             w,  9,  6, 0
1235     SUMSUB_BA             w,  8,  7, 0
1236
1237     TRANSPOSE8x8W        15, 14, 13, 12, 11, 10, 9, 8, 0
1238     mova     [rsp+ 0*%%str], m15
1239     mova     [rsp+ 4*%%str], m14
1240     mova     [rsp+ 8*%%str], m13
1241     mova     [rsp+12*%%str], m12
1242     mova     [rsp+16*%%str], m11
1243     mova     [rsp+20*%%str], m10
1244     mova     [rsp+24*%%str], m9
1245     mova     [rsp+28*%%str], m8
1246
1247     mova                  m0, [rsp+ 3*%%str] ; t15
1248     TRANSPOSE8x8W          7, 6, 5, 4, 3, 2, 1, 0, 8
1249     mova     [rsp+ 3*%%str], m7
1250     mova     [rsp+ 7*%%str], m6
1251     mova     [rsp+11*%%str], m5
1252     mova     [rsp+15*%%str], m4
1253     mova     [rsp+19*%%str], m3
1254     mova     [rsp+23*%%str], m2
1255     mova     [rsp+27*%%str], m1
1256     mova     [rsp+31*%%str], m0
1257
1258     mova                m15, [rsp+ 2*%%str] ; t8
1259     mova                m14, [rsp+ 6*%%str] ; t9
1260     mova                m13, [rsp+10*%%str] ; t10
1261     mova                m12, [rsp+14*%%str] ; t11
1262     mova                m11, [rsp+18*%%str] ; t12
1263     mova                m10, [rsp+22*%%str] ; t13
1264     mova                 m9, [rsp+26*%%str] ; t14
1265     mova                 m8, [rsp+30*%%str] ; t15
1266     mova                 m7, [rsp+ 1*%%str] ; t16
1267     mova                 m6, [rsp+ 5*%%str] ; t17
1268     mova                 m5, [rsp+ 9*%%str] ; t18
1269     mova                 m4, [rsp+13*%%str] ; t19
1270     mova                 m3, [rsp+17*%%str] ; t20
1271     mova                 m2, [rsp+21*%%str] ; t21
1272     mova                 m1, [rsp+25*%%str] ; t22
1273
1274     SUMSUB_BA             w,  7,  8, 0
1275     mova     [rsp+ 2*%%str], m8
1276     mova                 m0, [rsp+29*%%str] ; t23
1277     SUMSUB_BA             w,  6,  9, 8
1278     SUMSUB_BA             w,  5, 10, 8
1279     SUMSUB_BA             w,  4, 11, 8
1280     SUMSUB_BA             w,  3, 12, 8
1281     SUMSUB_BA             w,  2, 13, 8
1282     SUMSUB_BA             w,  1, 14, 8
1283     SUMSUB_BA             w,  0, 15, 8
1284
1285     TRANSPOSE8x8W         0, 1, 2, 3, 4, 5, 6, 7, 8
1286     mova     [rsp+ 1*%%str], m0
1287     mova     [rsp+ 5*%%str], m1
1288     mova     [rsp+ 9*%%str], m2
1289     mova     [rsp+13*%%str], m3
1290     mova     [rsp+17*%%str], m4
1291     mova     [rsp+21*%%str], m5
1292     mova     [rsp+25*%%str], m6
1293     mova     [rsp+29*%%str], m7
1294
1295     mova                 m8, [rsp+ 2*%%str]
1296     TRANSPOSE8x8W         8, 9, 10, 11, 12, 13, 14, 15, 0
1297     mova     [rsp+ 2*%%str], m8
1298     mova     [rsp+ 6*%%str], m9
1299     mova     [rsp+10*%%str], m10
1300     mova     [rsp+14*%%str], m11
1301     mova     [rsp+18*%%str], m12
1302     mova     [rsp+22*%%str], m13
1303     mova     [rsp+26*%%str], m14
1304     mova     [rsp+30*%%str], m15
1305 %else
1306     ; t0-7 is in [rsp+{0,4,8,12,16,20,24,28}*%%str]
1307     ; t8-15 is in [rsp+{2,6,10,14,18,22,26,30}*%%str]
1308     ; t16-19 and t23 is in [rsp+{1,5,9,13,29}*%%str]
1309     ; t20-22 is in m4-6
1310     ; t24-31 is in m8-15
1311     pxor                m7, m7
1312
1313 %macro %%STORE_2X2 7-8 1 ; src[1-4], tmp[1-2], zero, inc_dst_ptrs
1314     SUMSUB_BA            w, %4, %1, %5
1315     SUMSUB_BA            w, %3, %2, %5
1316     pmulhrsw           m%4, [pw_512]
1317     pmulhrsw           m%3, [pw_512]
1318     VP9_STORE_2X        %4, %3, %5, %6, %7
1319 %if %8 == 1
1320     add               dstq, stride2q
1321 %endif
1322     pmulhrsw           m%2, [pw_512]
1323     pmulhrsw           m%1, [pw_512]
1324     VP9_STORE_2X        %2, %1, %5, %6, %7, dst_endq
1325 %if %8 == 1
1326     sub           dst_endq, stride2q
1327 %endif
1328 %endmacro
1329
1330     ; store t0-1 and t30-31
1331     mova                m0, [rsp+ 0*%%str]
1332     mova                m1, [rsp+ 4*%%str]
1333     %%STORE_2X2          0,  1, 14, 15, 2, 3, 7
1334
1335     ; store t2-3 and t28-29
1336     mova                m0, [rsp+ 8*%%str]
1337     mova                m1, [rsp+12*%%str]
1338     %%STORE_2X2          0,  1, 12, 13, 2, 3, 7
1339
1340     ; store t4-5 and t26-27
1341     mova                m0, [rsp+16*%%str]
1342     mova                m1, [rsp+20*%%str]
1343     %%STORE_2X2          0,  1, 10, 11, 2, 3, 7
1344
1345     ; store t6-7 and t24-25
1346     mova                m0, [rsp+24*%%str]
1347     mova                m1, [rsp+28*%%str]
1348     %%STORE_2X2          0,  1,  8,  9, 2, 3, 7
1349
1350     ; store t8-9 and t22-23
1351     mova                m0, [rsp+ 2*%%str]
1352     mova                m1, [rsp+ 6*%%str]
1353     mova                m8, [rsp+29*%%str]
1354     %%STORE_2X2          0,  1,  6,  8, 2, 3, 7
1355
1356     ; store t10-11 and t20-21
1357     mova                m0, [rsp+10*%%str]
1358     mova                m1, [rsp+14*%%str]
1359     %%STORE_2X2          0,  1,  4,  5, 2, 3, 7
1360
1361     ; store t12-13 and t18-19
1362     mova                m0, [rsp+18*%%str]
1363     mova                m1, [rsp+22*%%str]
1364     mova                m5, [rsp+13*%%str]
1365     mova                m4, [rsp+ 9*%%str]
1366     %%STORE_2X2          0,  1,  4,  5, 2, 3, 7
1367
1368     ; store t14-17
1369     mova                m0, [rsp+26*%%str]
1370     mova                m1, [rsp+30*%%str]
1371     mova                m5, [rsp+ 5*%%str]
1372     mova                m4, [rsp+ 1*%%str]
1373     %%STORE_2X2          0,  1,  4,  5, 2, 3, 7, 0
1374 %endif
1375 %endmacro
1376
1377 %macro VP9_IDCT_IDCT_32x32_ADD_XMM 1
1378 INIT_XMM %1
1379 cglobal vp9_idct_idct_32x32_add, 4, 8, 16, 2048, dst, stride, block, eob
1380     cmp eobd, 135
1381     jg .idctfull
1382     cmp eobd, 34
1383     jg .idct16x16
1384     cmp eobd, 1
1385     jg .idct8x8
1386
1387     ; dc-only case
1388     movd                m0, [blockq]
1389     mova                m1, [pw_11585x2]
1390     pmulhrsw            m0, m1
1391     pmulhrsw            m0, m1
1392     SPLATW              m0, m0, q0000
1393     pmulhrsw            m0, [pw_512]
1394     pxor                m5, m5
1395     movd          [blockq], m5
1396     DEFINE_ARGS        dst, stride, block, cnt
1397 %rep 31
1398     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1399     add               dstq, strideq
1400 %endrep
1401     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1402     RET
1403
1404     DEFINE_ARGS dst_bak, stride, block, cnt, dst, stride30, dst_end, stride2
1405 .idct8x8:
1406     VP9_IDCT32_1D   blockq, 1, 8
1407
1408     mov          stride30q, strideq         ; stride
1409     lea           stride2q, [strideq*2]     ; stride*2
1410     shl          stride30q, 5               ; stride*32
1411     mov               cntd, 4
1412     sub          stride30q, stride2q        ; stride*30
1413 .loop2_8x8:
1414     mov               dstq, dst_bakq
1415     lea           dst_endq, [dst_bakq+stride30q]
1416     VP9_IDCT32_1D      rsp, 2, 8
1417     add           dst_bakq, 8
1418     add                rsp, 16
1419     dec               cntd
1420     jg .loop2_8x8
1421     sub                rsp, 64
1422
1423     ; at the end of the loop, m7 should still be zero
1424     ; use that to zero out block coefficients
1425     ZERO_BLOCK      blockq, 64,  8, m7
1426     RET
1427
1428 .idct16x16:
1429     mov               cntd, 2
1430 .loop1_16x16:
1431     VP9_IDCT32_1D   blockq, 1, 16
1432     add             blockq, 16
1433     add                rsp, 512
1434     dec               cntd
1435     jg .loop1_16x16
1436     sub             blockq, 32
1437     sub                rsp, 1024
1438
1439     mov          stride30q, strideq         ; stride
1440     lea           stride2q, [strideq*2]     ; stride*2
1441     shl          stride30q, 5               ; stride*32
1442     mov               cntd, 4
1443     sub          stride30q, stride2q        ; stride*30
1444 .loop2_16x16:
1445     mov               dstq, dst_bakq
1446     lea           dst_endq, [dst_bakq+stride30q]
1447     VP9_IDCT32_1D      rsp, 2, 16
1448     add           dst_bakq, 8
1449     add                rsp, 16
1450     dec               cntd
1451     jg .loop2_16x16
1452     sub                rsp, 64
1453
1454     ; at the end of the loop, m7 should still be zero
1455     ; use that to zero out block coefficients
1456     ZERO_BLOCK      blockq, 64, 16, m7
1457     RET
1458
1459 .idctfull:
1460     mov               cntd, 4
1461 .loop1_full:
1462     VP9_IDCT32_1D   blockq, 1
1463     add             blockq, 16
1464     add                rsp, 512
1465     dec               cntd
1466     jg .loop1_full
1467     sub             blockq, 64
1468     sub                rsp, 2048
1469
1470     mov          stride30q, strideq         ; stride
1471     lea           stride2q, [strideq*2]     ; stride*2
1472     shl          stride30q, 5               ; stride*32
1473     mov               cntd, 4
1474     sub          stride30q, stride2q        ; stride*30
1475 .loop2_full:
1476     mov               dstq, dst_bakq
1477     lea           dst_endq, [dst_bakq+stride30q]
1478     VP9_IDCT32_1D      rsp, 2
1479     add           dst_bakq, 8
1480     add                rsp, 16
1481     dec               cntd
1482     jg .loop2_full
1483     sub                rsp, 64
1484
1485     ; at the end of the loop, m7 should still be zero
1486     ; use that to zero out block coefficients
1487     ZERO_BLOCK      blockq, 64, 32, m7
1488     RET
1489 %endmacro
1490
1491 VP9_IDCT_IDCT_32x32_ADD_XMM ssse3
1492 VP9_IDCT_IDCT_32x32_ADD_XMM avx
1493
1494 %endif ; x86-64